diff options
author | Valentin Jec <valentin.jec@nxp.com> | 2024-02-12 12:06:51 +0200 |
---|---|---|
committer | Valentin Jec <valentin.jec@nxp.com> | 2024-02-12 12:06:51 +0200 |
commit | 336628e6b0118c765df47632714f47b942a3ff18 (patch) | |
tree | ed8c77c76948bd13ab702749c5ade3dc87d1c505 /recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb | |
parent | 9dfbf6675adcf3dfbc1127a5ce55f135082318ae (diff) | |
download | meta-freescale-336628e6b0118c765df47632714f47b942a3ff18.tar.gz |
recipes-multimedia: Update for NXP release 6.1.55-2.2.0
Upgraded:
- gstreamer1.0-plugins-bad: 1.22.0 -> 1.22.5
- gstreamer1.0-plugins-base: 1.22.0 -> 1.22.5
- gstreamer1.0-plugins-good: 1.22.0 -> 1.22.5
- gstreamer1.0: 1.22.0 -> 1.22.5
- imx-codec: 4.8.1 -> 4.8.2
- imx-dsp: 2.1.5 -> 2.1.6
- imx-dsp-codec-ext: 2.1.5 -> 2.1.6
- imx-parser: 4.8.1 -> 4.8.2
Updated:
- imx-alsa-plugins_git.bb
- imx-gst1.0-plugin_git.bb
- imx-vpuwrap_git.bb
New feature:
- imx-opencl-converter_0.1.bb
Signed-off-by: Valentin Jec <valentin.jec@nxp.com>
Diffstat (limited to 'recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb')
-rw-r--r-- | recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb | 149 |
1 files changed, 149 insertions, 0 deletions
diff --git a/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb new file mode 100644 index 00000000..366314bd --- /dev/null +++ b/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.22.5.imx.bb | |||
@@ -0,0 +1,149 @@ | |||
1 | # This recipe is for the i.MX fork of gstreamer1.0-plugins-base. For ease of | ||
2 | # maintenance, the top section is a verbatim copy of an OE-core | ||
3 | # recipe. The second section customizes the recipe for i.MX. | ||
4 | |||
5 | ########### OE-core copy ################## | ||
6 | # Upstream hash: 937817e5164f8af8452aec03ae3c45cb23d63df9 | ||
7 | |||
8 | require gstreamer1.0-plugins-common.inc | ||
9 | |||
10 | SUMMARY = "'Base' GStreamer plugins and helper libraries" | ||
11 | HOMEPAGE = "https://gstreamer.freedesktop.org/" | ||
12 | BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-base/-/issues" | ||
13 | LICENSE = "LGPL-2.1-or-later" | ||
14 | LIC_FILES_CHKSUM = "file://COPYING;md5=69333daa044cb77e486cc36129f7a770" | ||
15 | |||
16 | SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \ | ||
17 | file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \ | ||
18 | file://0003-viv-fb-Make-sure-config.h-is-included.patch \ | ||
19 | file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch \ | ||
20 | " | ||
21 | SRC_URI[sha256sum] = "edd4338b45c26a9af28c0d35aab964a024c3884ba6f520d8428df04212c8c93a" | ||
22 | |||
23 | S = "${WORKDIR}/gst-plugins-base-${PV}" | ||
24 | |||
25 | DEPENDS += "iso-codes util-linux zlib" | ||
26 | |||
27 | inherit gobject-introspection | ||
28 | |||
29 | # opengl packageconfig factored out to make it easy for distros | ||
30 | # and BSP layers to choose OpenGL APIs/platforms/window systems | ||
31 | PACKAGECONFIG_X11 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl glx', '', d)}" | ||
32 | PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl ${PACKAGECONFIG_X11}', '', d)}" | ||
33 | |||
34 | PACKAGECONFIG ??= " \ | ||
35 | ${GSTREAMER_ORC} \ | ||
36 | ${PACKAGECONFIG_GL} \ | ||
37 | ${@bb.utils.filter('DISTRO_FEATURES', 'alsa x11', d)} \ | ||
38 | jpeg ogg pango png theora vorbis \ | ||
39 | ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland egl', '', d)} \ | ||
40 | " | ||
41 | |||
42 | OPENGL_APIS = 'opengl gles2' | ||
43 | OPENGL_PLATFORMS = 'egl glx' | ||
44 | |||
45 | X11DEPENDS = "virtual/libx11 libsm libxrender libxv" | ||
46 | X11ENABLEOPTS = "-Dx11=enabled -Dxvideo=enabled -Dxshm=enabled" | ||
47 | X11DISABLEOPTS = "-Dx11=disabled -Dxvideo=disabled -Dxshm=disabled" | ||
48 | |||
49 | PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib" | ||
50 | PACKAGECONFIG[cdparanoia] = "-Dcdparanoia=enabled,-Dcdparanoia=disabled,cdparanoia" | ||
51 | PACKAGECONFIG[graphene] = "-Dgl-graphene=enabled,-Dgl-graphene=disabled,graphene" | ||
52 | PACKAGECONFIG[jpeg] = "-Dgl-jpeg=enabled,-Dgl-jpeg=disabled,jpeg" | ||
53 | PACKAGECONFIG[ogg] = "-Dogg=enabled,-Dogg=disabled,libogg" | ||
54 | PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus" | ||
55 | PACKAGECONFIG[pango] = "-Dpango=enabled,-Dpango=disabled,pango" | ||
56 | PACKAGECONFIG[png] = "-Dgl-png=enabled,-Dgl-png=disabled,libpng" | ||
57 | # This enables Qt5 QML examples in -base. The Qt5 GStreamer | ||
58 | # qmlglsink and qmlglsrc plugins still exist in -good. | ||
59 | PACKAGECONFIG[qt5] = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native" | ||
60 | PACKAGECONFIG[theora] = "-Dtheora=enabled,-Dtheora=disabled,libtheora" | ||
61 | PACKAGECONFIG[tremor] = "-Dtremor=enabled,-Dtremor=disabled,tremor" | ||
62 | PACKAGECONFIG[visual] = "-Dlibvisual=enabled,-Dlibvisual=disabled,libvisual" | ||
63 | PACKAGECONFIG[vorbis] = "-Dvorbis=enabled,-Dvorbis=disabled,libvorbis" | ||
64 | PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}" | ||
65 | |||
66 | # OpenGL API packageconfigs | ||
67 | PACKAGECONFIG[opengl] = ",,virtual/libgl libglu" | ||
68 | PACKAGECONFIG[gles2] = ",,virtual/libgles2" | ||
69 | |||
70 | # OpenGL platform packageconfigs | ||
71 | PACKAGECONFIG[egl] = ",,virtual/egl" | ||
72 | PACKAGECONFIG[glx] = ",,virtual/libgl" | ||
73 | |||
74 | # OpenGL window systems (except for X11) | ||
75 | PACKAGECONFIG[gbm] = ",,virtual/libgbm libgudev libdrm" | ||
76 | PACKAGECONFIG[wayland] = ",,wayland-native wayland wayland-protocols libdrm" | ||
77 | PACKAGECONFIG[dispmanx] = ",,virtual/libomxil" | ||
78 | PACKAGECONFIG[viv-fb] = ",,virtual/libgles2 virtual/libg2d" | ||
79 | |||
80 | OPENGL_WINSYS = "${@bb.utils.filter('PACKAGECONFIG', 'x11 gbm wayland dispmanx egl viv-fb', d)}" | ||
81 | |||
82 | EXTRA_OEMESON += " \ | ||
83 | -Ddoc=disabled \ | ||
84 | ${@get_opengl_cmdline_list('gl_api', d.getVar('OPENGL_APIS'), d)} \ | ||
85 | ${@get_opengl_cmdline_list('gl_platform', d.getVar('OPENGL_PLATFORMS'), d)} \ | ||
86 | ${@get_opengl_cmdline_list('gl_winsys', d.getVar('OPENGL_WINSYS'), d)} \ | ||
87 | " | ||
88 | |||
89 | FILES:${PN}-dev += "${libdir}/gstreamer-1.0/include/gst/gl/gstglconfig.h" | ||
90 | FILES:${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict" | ||
91 | |||
92 | def get_opengl_cmdline_list(switch_name, options, d): | ||
93 | selected_options = [] | ||
94 | if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d): | ||
95 | for option in options.split(): | ||
96 | if bb.utils.contains('PACKAGECONFIG', option, True, False, d): | ||
97 | selected_options += [option] | ||
98 | if selected_options: | ||
99 | return '-D' + switch_name + '=' + ','.join(selected_options) | ||
100 | else: | ||
101 | return '' | ||
102 | |||
103 | CVE_PRODUCT += "gst-plugins-base" | ||
104 | |||
105 | ########### End of OE-core copy ########### | ||
106 | |||
107 | ########### i.MX overrides ################ | ||
108 | |||
109 | DEFAULT_PREFERENCE = "-1" | ||
110 | |||
111 | LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=69333daa044cb77e486cc36129f7a770" | ||
112 | |||
113 | SRC_URI:remove = " \ | ||
114 | https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \ | ||
115 | file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \ | ||
116 | file://0003-viv-fb-Make-sure-config.h-is-included.patch \ | ||
117 | file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch" | ||
118 | SRC_URI:prepend = "${GST1.0-PLUGINS-BASE_SRC};branch=${SRCBRANCH} " | ||
119 | SRC_URI:append = " file://0001-gstallocator-Fix-typcasts.patch" | ||
120 | GST1.0-PLUGINS-BASE_SRC ?= "gitsm://github.com/nxp-imx/gst-plugins-base.git;protocol=https" | ||
121 | SRCBRANCH = "MM_04.08.02_2310_L6.1.y" | ||
122 | SRCREV = "53a12f4e39773ca5b052eccbf0476d4ebd3ac08e" | ||
123 | |||
124 | S = "${WORKDIR}/git" | ||
125 | |||
126 | inherit use-imx-headers | ||
127 | |||
128 | # Prior to version 1.22.5, viv-fb is coupled with the Vivante direct texture feature. | ||
129 | # For this reason, in these older versions, viv-fb must be enabled always, even when | ||
130 | # building for SoCs like the i.MX8 that do not support the viv-fb windowing system. | ||
131 | # TODO: Once this .imx recipe is upgraded to 1.22.5 or newer, drop this line. | ||
132 | PACKAGECONFIG_GL:append = " viv-fb " | ||
133 | |||
134 | PACKAGECONFIG_REMOVE ?= "jpeg" | ||
135 | PACKAGECONFIG:remove = "${PACKAGECONFIG_REMOVE}" | ||
136 | PACKAGECONFIG:append:imxgpu2d = " g2d" | ||
137 | |||
138 | PACKAGECONFIG[g2d] = ",,virtual/libg2d" | ||
139 | PACKAGECONFIG[viv-fb] = ",,virtual/libgles2" | ||
140 | |||
141 | EXTRA_OEMESON += "-Dc_args="${CFLAGS} -I${STAGING_INCDIR_IMX}"" | ||
142 | |||
143 | # links with imx-gpu libs which are pre-built for glibc | ||
144 | # gcompat will address it during runtime | ||
145 | LDFLAGS:append:imxgpu:libc-musl = " -Wl,--allow-shlib-undefined" | ||
146 | |||
147 | COMPATIBLE_MACHINE = "(imx-nxp-bsp)" | ||
148 | |||
149 | ########### End of i.MX overrides ######### | ||