linux-qoriq-rt/4.14: add recipes

*update to lsdk 1909 tag
include the following changes:
aa5285f449b1 - staging: fsl_ppfe/eth: Disable termination of CRC fwd.
c71a77a1f281 - mtd: fsl-quadspi: Introduce variable to fix different invalid master Id
6138f4aaec07 - arm64: dts: ls1028a: fix dwc pci over smmu
b7f6872fca15 - arm: dts: ls1021a: fix that FlexTimer cannot wakeup system in deep sleep
4c9bd9b8dea0 - Documentation: dt: binding: fsl: Add 'fsl,ippdexpcr1-alt-addr' property
72e88baa77f1 - soc: fsl: handle RCPM errata A-008646 on SoC LS1021A
8c1e5a5996a2 - enetc: Fix deadlock during PTP RX timestamping
ed206222df1f - felix: Remove unused include, fix compile warn
2e380e91c050 - ocelot: Warn if cpu side interfaces are not up
5bff7c69cf36 - ocelot: Fix NULL pointer on LAG slave removal
1e5b7fe43ff9 - ocelot: Don't handle netdev events for other netdevs
1b49a6c770ce - mmc: sdhci-of-esdhc: add erratum A011334 support in ls1028a 1.0 SoC
907205c7d550 - mmc: sdhci-of-esdhc: use 1/2 periperhal clock for ls1028a
b448c680bd36 - mmc: sdhci-of-esdhc: set the sd clock divisor value above 3
179f53614b70 - iommu/arm-smmu: Enable bypass transaction caching for ARM SMMU 500
b8a4bb166cfc - drm: mali-dp: Set encoder possible_clones
d3e41fadb963 - drm/arm/malidp: Enable/disable interrupts in runtime pm
1bf8672fca85 - drm/modeset-helper: Add simple modeset suspend/resume helpers
e3bf1aa5315a - drm/arm/malidp: Added the late system pm functions
d71d53fa06ba - felix: skip probing if device is disabled in DT
e71d52d39c78 - enetc: Handle USXGMII protocol
c8e7a8ebb222 - enetc: Fix 10G PCS PHY access
8e34b7334905 - drivers: net: phy: aquantia: enable USX AN for USXGMII protocol
efaabe0aecbd - drivers: net: phy: aquantia: fix system side protocol misconfiguration
f237e3b0c47e - irqchip/gic-v3-its: Fix command queue pointer comparison bug
2ee2bc14cc01 - irqchip/gic-v3-its: Add post-mortem info on command timeout
5454064dbdfd - arm64: defconfig: enable CONFIG_GPIO_MPC8XXX

Signed-off-by: Chunrong Guo <chunrong.guo@nxp.com>

1 files changed, 71 insertions, 0 deletions

diff --git a/recipes-kernel/linux/linux-qoriq-rt_4.14.bb b/recipes-kernel/linux/linux-qoriq-rt_4.14.bb
new file mode 100644
index 00000000..e880081a
--- /dev/null
+++ b/recipes-kernel/linux/linux-qoriq-rt_4.14.bb
@@ -0,0 +1,71 @@
+inherit kernel qoriq_build_64bit_kernel siteinfo
+inherit fsl-kernel-localversion
+
+SUMMARY = "Linux Kernel for NXP QorIQ platforms"
+SECTION = "kernel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/linux;nobranch=1 \
+    file://0001-Makfefile-add-cflags.patch \
+    file://0001-perf-tools-Add-Python-3-support.patch \
+"
+SRCREV = "aa5285f449b1b08bb9bd5fbc51e9dd0df2a2f95c"
+
+S = "${WORKDIR}/git"
+
+DEPENDS_append = " libgcc"
+# not put Images into /boot of rootfs, install kernel-image if needed
+RDEPENDS_${KERNEL_PACKAGE_NAME}-base = ""
+
+KERNEL_CC_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_LD_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+ZIMAGE_BASE_NAME = "zImage-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+ZIMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
+
+SCMVERSION ?= "y"
+LOCALVERSION = ""
+DELTA_KERNEL_DEFCONFIG ?= ""
+DELTA_KERNEL_DEFCONFIG_prepend_qoriq-arm64 = "lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_fsl-lsch2-32b = "multi_v7_lpae.config multi_v8.config lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_ls102xa = "multi_v7_lpae.config lsdk.config "
+
+do_merge_delta_config[dirs] = "${B}"
+
+do_merge_delta_config() {
+    # create config with make config
+    oe_runmake  -C ${S} O=${B} ${KERNEL_DEFCONFIG}
+    
+    # check if bigendian is enabled
+    if [ "${SITEINFO_ENDIANNESS}" = "be" ]; then
+        echo "CONFIG_CPU_BIG_ENDIAN=y" >> .config
+        echo "CONFIG_MTD_CFI_BE_BYTE_SWAP=y" >> .config
+    fi
+
+    # add config fragments
+    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
+        if [ -f ${S}/arch/${ARCH}/configs/${deltacfg} ]; then
+            oe_runmake  -C ${S} O=${B} ${deltacfg}
+        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
+        elif [ -f "${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
+        fi
+    done
+    cp .config ${WORKDIR}/defconfig
+}
+addtask merge_delta_config before do_preconfigure after do_patch
+
+# The link of dts folder is needed for 32b compile of aarch64 targets(e.g. ls1043ardb-32b)
+do_compile_prepend_fsl-lsch2-32b() {
+    ln -sfT ${STAGING_KERNEL_DIR}/arch/arm64/boot/dts/freescale ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+do_install_prepend_fsl-lsch2-32b() {
+    rm -f ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+FILES_${KERNEL_PACKAGE_NAME}-image += "/boot/zImage*"
+COMPATIBLE_MACHINE = "(qoriq)"