jailhouse: add imx version

There is a general jailhouse recipe in other layers which causes a
version conflict. Introduce jailhouse-imx recipe to avoid conflict.

Signed-off-by: Oleksandr Suvorov <oleksandr.suvorov@foundries.io>

1 files changed, 0 insertions, 104 deletions

diff --git a/recipes-extended/jailhouse/jailhouse_git.bb b/recipes-extended/jailhouse/jailhouse_git.bb
deleted file mode 100644
index 2caca91c..00000000
--- a/recipes-extended/jailhouse/jailhouse_git.bb
+++ /dev/null
@@ -1,104 +0,0 @@
-SUMMARY = "Jailhouse, i.MX fork"
-HOMEPAGE = "https://github.com/siemens/jailhouse"
-SECTION = "jailhouse"
-LICENSE = "GPL-2.0-only"
-
-LIC_FILES_CHKSUM = "file://COPYING;md5=9fa7f895f96bde2d47fd5b7d95b6ba4d \
-                 file://tools/root-cell-config.c.tmpl;beginline=6;endline=33;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://include/jailhouse/hypercall.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://include/jailhouse/cell-config.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://include/arch/arm/asm/jailhouse_hypercall.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://include/arch/arm64/asm/jailhouse_hypercall.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://include/arch/x86/asm/jailhouse_hypercall.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-                 file://driver/jailhouse.h;beginline=9;endline=36;md5=2825581c1666c44a17955dc574cfbfb3 \
-"
-
-SRCBRANCH = "lf-6.1.22_2.0.0"
-SRCREV = "e090abc70bb395f705f85659ad92bdafbe407628"
-
-SRC_URI = "git://github.com/nxp-imx/imx-jailhouse.git;protocol=https;branch=${SRCBRANCH}"
-
-DEPENDS = " \
-    make-native \
-    python3-mako-native \
-    python3-mako \
-    dtc-native \
-"
-
-inherit module python3native bash-completion deploy setuptools3
-
-S = "${WORKDIR}/git"
-B = "${S}"
-
-JH_ARCH = "arm64"
-JH_DATADIR ?= "${datadir}/jailhouse"
-CELL_DIR ?= "${JH_DATADIR}/cells"
-CELLCONF_DIR ?= "${JH_DATADIR}/configs"
-INMATES_DIR ?= "${JH_DATADIR}/inmates"
-
-do_configure() {
-   if [ -d ${STAGING_DIR_HOST}/${CELLCONF_DIR} ];
-   then
-      cp "${STAGING_DIR_HOST}/${CELLCONF_DIR}/"*.c ${S}/configs/${ARCH}/
-   fi
-}
-
-do_compile:prepend() {
-    unset LDFLAGS
-    oe_runmake V=1 CC="${CC}" \
-        ARCH=${JH_ARCH} CROSS_COMPILE=${TARGET_PREFIX} \
-        KDIR=${STAGING_KERNEL_BUILDDIR}
-}
-
-do_install:prepend() {
-    oe_runmake \
-        PYTHON=python3 \
-        V=1 \
-        LDFLAGS="" \
-        CC="${CC}" \
-        ARCH=${JH_ARCH} \
-        CROSS_COMPILE=${TARGET_PREFIX} \
-        KDIR=${STAGING_KERNEL_BUILDDIR} \
-        INSTALL_MOD_PATH=${D}${root_prefix} \
-        firmwaredir=${nonarch_base_libdir}/firmware \
-        DESTDIR=${D} install
-
-    install -d ${D}${CELL_DIR}
-    install ${B}/configs/${JH_ARCH}/*.cell ${D}${CELL_DIR}/
-
-    install -d ${D}${INMATES_DIR}/tools/${JH_ARCH}
-    install ${B}/inmates/demos/${JH_ARCH}/*.bin ${D}${INMATES_DIR}
-
-    install -d ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-cell-linux ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-cell-stats ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-config-collect ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-config-create ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-gcov-extract ${D}${JH_DATADIR}/tools
-    install ${B}/tools/jailhouse-hardware-check ${D}${JH_DATADIR}/tools
-    install ${B}/inmates/tools/${JH_ARCH}/linux-loader.bin ${D}${INMATES_DIR}/tools/${JH_ARCH}
-}
-
-PACKAGE_BEFORE_PN = "pyjailhouse"
-
-FILES:${PN} += "${nonarch_base_libdir}/firmware ${libexecdir} ${sbindir} ${JH_DATADIR}"
-# Remove libdir/* appended by setuptools3-base.bbclass for module split to work correctly
-FILES:${PN}:remove = "${libdir}/*"
-FILES:pyjailhouse = "${PYTHON_SITEPACKAGES_DIR}"
-
-RDEPENDS:${PN} += " \
-    python3-curses \
-    python3-datetime \
-    python3-mmap \
-"
-
-RDEPENDS:pyjailhouse = " \
-    python3-core \
-    python3-ctypes \
-    python3-fcntl \
-    python3-shell \
-"
-
-INSANE_SKIP:${PN} = "ldflags"
-
-COMPATIBLE_MACHINE = "(mx8m-nxp-bsp|mx8ulp-nxp-bsp|mx93-nxp-bsp)"