Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

3 files changed, 88 insertions, 0 deletions

diff --git a/recipes-devtools/cst/cst_git.bb b/recipes-devtools/cst/cst_git.bb
new file mode 100644
index 00000000..08dbd561
--- /dev/null
+++ b/recipes-devtools/cst/cst_git.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "utility for security boot"
+SECTION = "cst"
+LICENSE = "BSD"
+
+# TODO: fix license - this file is not a license
+LIC_FILES_CHKSUM = "file://RELEASENOTES;beginline=8;endline=43;md5=5a7b22a2c96b5f94e0498c5f413aa8d3"
+
+DEPENDS += "openssl"
+
+inherit kernel-arch
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/cst.git;branch=master"
+SRCREV = "6f57c86c93cab0f4d0a40d83b685afa6932a6301"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${CC}"'
+
+PARALLEL_MAKE = ""
+
+do_install () {
+    oe_runmake install DESTDIR=${D} BIN_DEST_DIR=${bindir}
+}
+
+FILES_${PN}-dbg += "${bindir}/cst/.debug"
+BBCLASSEXTEND = "native nativesdk"
diff --git a/recipes-devtools/devregs/devregs_git.bb b/recipes-devtools/devregs/devregs_git.bb
new file mode 100644
index 00000000..3bac55a4
--- /dev/null
+++ b/recipes-devtools/devregs/devregs_git.bb
@@ -0,0 +1,13 @@
+DESCRIPTION = "i.MX Register tool"
+SECTION = "devel"
+LICENSE = "GPL-1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5003fa041d799dd5dd5f646b74e36924"
+
+SRCREV = "34ed402b92920864b89e0fd1e76bae3aa340baaa"
+SRC_URI = "git://github.com/boundarydevices/devregs.git;protocol=http"
+
+PV = "1.0+${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+inherit autotools
diff --git a/recipes-devtools/qemu/qemu-fsl_git.bb b/recipes-devtools/qemu/qemu-fsl_git.bb
new file mode 100644
index 00000000..94fb9b19
--- /dev/null
+++ b/recipes-devtools/qemu/qemu-fsl_git.bb
@@ -0,0 +1,49 @@
+require recipes-devtools/qemu/qemu.inc
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
+                    file://COPYING.LIB;endline=24;md5=c04def7ae38850e7d3ef548588159913"
+
+# This means QEMU v2.2.0 with FSL specific patches applied
+PV = "2.2.0+${SRCPV}"
+
+# NOTE: this recipe requires poky's qemu.inc which assumes version 2.3
+# where glx enable config option changed to --enable-opengl. For now we
+# restore it, but we should remove the following lines when upgrading
+# to qemu 2.3:
+PACKAGECONFIG[glx] = "--enable-glx,--disable-glx,mesa"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/qemu.git;branch=master"
+SRCREV = "00ac004143e9fe46944a1885b04268fcd3a95a3a"
+
+S = "${WORKDIR}/git"
+
+QEMU_TARGETS = "arm"
+
+inherit pkgconfig
+
+# Append build host pkg-config paths for native target since the host may provide sdl
+do_configure_prepend() {
+    export PKG_CONFIG=${STAGING_DIR_NATIVE}${bindir_native}/pkg-config
+}
+
+do_configure_append () {
+    if ! grep 'CONFIG_FDT=y' config-host.mak; then
+         echo "CONFIG_RDMA=y" >> config_host_mak
+    fi
+}
+
+# gets around qemu.inc trying to install powerpc_rom.bin
+do_install_prepend() {
+    touch ${WORKDIR}/powerpc_rom.bin
+}
+
+do_install_append() {
+    rm ${WORKDIR}/powerpc_rom.bin
+    # Prevent QA warnings about installed ${localstatedir}/run
+    if [ -d ${D}${localstatedir}/run ]; then rmdir ${D}${localstatedir}/run; fi
+}
+
+FILES_${PN} += "/usr/share/qemu/"
+
+# FIXME: Avoid WARNING due missing patch for native/nativesdk
+BBCLASSEXTEND = ""