u-boot-fslc: upgrade to v2023.01+fslcbackport-1356-to-kirkstone

U-Boot fork has been updated to include new version v2023.01 from
upstream.

Following commits were ported from 2022.10+fslc revision:
----
- 598f87fbdb6 imx6qdl-sabresd: Pass mmc alias
- 1b64b05f407 imx: iMX6: Define disconnect_from_pc function
- 0335a01b6d5 MLK-21854-2 imx: uuu: Update autoboot to run uuu or fastboot
- 9a38462d252 pico-imx6ul, pico-imx7d: Explain how to use eMMC user partition
- 881d7241411 mx6sabre_common: Dynamically change the video output
- e427569fa3e mx6sabresd: Enable video interfaces in bootargs
----

Update U-Boot recipe versions and point to new revision.

Signed-off-by: Oleksandr Suvorov <oleksandr.suvorov@foundries.io>
(cherry picked from commit 65a85cfc9da2ec8872e3b431db84acc6f6ca6da9)

1 files changed, 32 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2023.01.bb b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2023.01.bb
new file mode 100644
index 00000000..a7dfd8aa
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-mxsboot_2023.01.bb
@@ -0,0 +1,32 @@
+require u-boot-fslc-common_${PV}.inc
+
+DESCRIPTION = "U-boot bootloader mxsboot tool"
+SECTION = "bootloader"
+
+DEPENDS = "swig-native bison-native gnutls-native dtc openssl"
+
+PROVIDES = "u-boot-mxsboot"
+
+EXTRA_OEMAKE:class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE:class-native = 'CC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+EXTRA_OEMAKE:class-nativesdk = 'CROSS_COMPILE="${HOST_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1 CONFIG_MX28=y'
+
+do_compile () {
+    oe_runmake -C ${S} O=${B} sandbox_defconfig
+
+    # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
+    # generating it requires bin2header tool, which for target build
+    # is built with target tools and thus cannot be executed on host.
+    sed -i "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" .config
+
+    oe_runmake -C ${S} O=${B} cross_tools NO_SDL=1
+}
+
+do_install () {
+    install -Dm 0755 tools/mxsboot ${D}${bindir}/uboot-mxsboot
+    ln -sf uboot-mxsboot ${D}${bindir}/mxsboot
+}
+
+COMPATIBLE_MACHINE:class-target = "(mxs-generic-bsp)"
+
+BBCLASSEXTEND = "native nativesdk"