Move meta-fsl-arm content to layer root

The meta-fsl-arm is going to be used as the base for this layer. It
contains a clean history and allowing a more granullar set of changes.

This commit is just a rename of all contents of meta-fsl-arm
subdirectory to this layer's root, subsequent changes are based on top
of that.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

6 files changed, 558 insertions, 0 deletions

diff --git a/classes/fsl-dynamic-packagearch.bbclass b/classes/fsl-dynamic-packagearch.bbclass
new file mode 100644
index 00000000..fa542fce
--- /dev/null
+++ b/classes/fsl-dynamic-packagearch.bbclass
@@ -0,0 +1,65 @@
+# Automatically set PACKAGE_ARCH for MACHINE_SOCARCH
+#
+# This allow to easy reuse of binary packages among similar SoCs. The
+# usual use for this is to share SoC specific packages among different
+# boards.
+#
+# MACHINE_SOCARCH_FILTER list all packages associated with
+# MACHINE_SOCARCH and, when match, will set PACKAGE_ARCH as MACHINE_SOCARCH
+#
+# MACHINE_ARCH_FILTER list all packages associated with
+# MACHINE_ARCH and, when match, will set PACKAGE_ARCH as MACHINE_ARCH
+#
+# For example, in meta-fsl-arm, this is used to share GPU packages for
+# i.MX53 boards (as all them share the AMD GPU) and i.MX6 based boards
+# (as all them share Vivante GPU).
+#
+# To use the class, specify, for example:
+#
+# MACHINE_SOCARCH_SUFFIX_soc = "-soc"
+#
+# and the need filters, as:
+#
+# MACHINE_ARCH_FILTER = "virtual/kernel"
+# MACHINE_SOCARCH_FILTER_soc = "virtual/libgles1 ... virtual/libgl"
+#
+# Copyright 2013-2015 (C) O.S. Systems Software LTDA.
+
+python __anonymous () {
+    machine_arch_filter = set((d.getVar("MACHINE_ARCH_FILTER", True) or "").split())
+    machine_socarch_filter = set((d.getVar("MACHINE_SOCARCH_FILTER", True) or "").split())
+    if machine_socarch_filter or machine_arch_filter:
+        provides = set((d.getVar("PROVIDES", True) or "").split())
+        depends = set((d.getVar("DEPENDS", True) or "").split())
+        PN = d.getVar("PN", True)
+
+        package_arch = None
+        if list(machine_arch_filter & (provides | depends)):
+            package_arch = d.getVar("MACHINE_ARCH", True)
+        elif list(machine_socarch_filter & (provides | depends)):
+            package_arch = d.getVar("MACHINE_SOCARCH", True)
+            if not package_arch:
+                raise bb.parse.SkipPackage("You must set MACHINE_SOCARCH as MACHINE_SOCARCH_FILTER is set for this SoC.")
+
+            machine_socarch_suffix = d.getVar("MACHINE_SOCARCH_SUFFIX", True)
+            if not machine_socarch_suffix:
+                raise bb.parse.SkipPackage("You must set MACHINE_SOCARCH_SUFFIX as MACHINE_SOCARCH_FILTER is set for this SoC.")
+
+        if package_arch:
+            bb.debug(1, "Use '%s' as package archictecture for '%s'" % (package_arch, PN))
+            d.setVar("PACKAGE_ARCH", package_arch)
+
+    cur_package_archs = (d.getVar("PACKAGE_ARCHS", True) or "").split()
+    arch_extra_socarch = (d.getVar("ARM_EXTRA_SOCARCH", True) or "")
+    thumb_extra_socarch = (d.getVar("THUMB_EXTRA_SOCARCH", True) or "")
+    if not arch_extra_socarch in cur_package_archs:
+        d.appendVar("PACKAGE_EXTRA_ARCHS", " %s" % arch_extra_socarch)
+
+    if not thumb_extra_socarch in cur_package_archs:
+        d.appendVar("PACKAGE_EXTRA_ARCHS", " %s" % thumb_extra_socarch)
+}
+
+ARM_EXTRA_SOCARCH = "${ARMPKGARCH}${ARMPKGSFX_DSP}${ARMPKGSFX_EABI}${ARMPKGSFX_ENDIAN}${ARMPKGSFX_FPU}${MACHINE_SOCARCH_SUFFIX}"
+THUMB_EXTRA_SOCARCH = "${ARMPKGARCH}${ARM_THUMB_SUFFIX}${ARMPKGSFX_DSP}${ARMPKGSFX_EABI}${ARMPKGSFX_ENDIAN}${ARMPKGSFX_FPU}${MACHINE_SOCARCH_SUFFIX}"
+
+MACHINE_SOCARCH = "${@bb.utils.contains('ARM_INSTRUCTION_SET', 'thumb', '${THUMB_EXTRA_SOCARCH}', '${ARM_EXTRA_SOCARCH}', d)}"
diff --git a/classes/fsl-eula-unpack.bbclass b/classes/fsl-eula-unpack.bbclass
new file mode 100644
index 00000000..a9f16ef0
--- /dev/null
+++ b/classes/fsl-eula-unpack.bbclass
@@ -0,0 +1,67 @@
+# fsl-eula-unpack.bbclass provides the mechanism used for unpacking
+# the .bin file downloaded by HTTP and handle the EULA acceptance.
+#
+# To use it, the 'fsl-eula' parameter needs to be added to the
+# SRC_URI entry, e.g:
+#
+#  SRC_URI = "${FSL_MIRROR}/firmware-imx-${PV};fsl-eula=true"
+
+LIC_FILES_CHKSUM_append = " file://${FSL_EULA_FILE};md5=acdb807ac7275fe32f9f64992e111241"
+LIC_FILES_CHKSUM[vardepsexclude] += "FSL_EULA_FILE"
+
+python fsl_bin_do_unpack() {
+    src_uri = (d.getVar('SRC_URI', True) or "").split()
+    if len(src_uri) == 0:
+        return
+
+    localdata = bb.data.createCopy(d)
+    bb.data.update_data(localdata)
+
+    rootdir = localdata.getVar('WORKDIR', True)
+    fetcher = bb.fetch2.Fetch(src_uri, localdata)
+
+    for url in fetcher.ud.values():
+        save_cwd = os.getcwd()
+        # Check for supported fetchers
+        if url.type in ['http', 'https', 'ftp', 'file']:
+            if url.parm.get('fsl-eula', False):
+                # If download has failed, do nothing
+                if not os.path.exists(url.localpath):
+                    bb.debug(1, "Exiting as '%s' cannot be found" % url.basename)
+                    return
+
+                # Change to the working directory
+                bb.note("Handling file '%s' as a Freescale's EULA binary." % url.basename)
+                save_cwd = os.getcwd()
+                os.chdir(rootdir)
+
+                cmd = "sh %s --auto-accept --force" % (url.localpath)
+                bb.fetch2.runfetchcmd(cmd, d, quiet=True)
+
+    # Return to the previous directory
+    os.chdir(save_cwd)
+}
+
+python do_unpack() {
+    eula = d.getVar('ACCEPT_FSL_EULA', True)
+    eula_file = d.getVar('FSL_EULA_FILE', True)
+    pkg = d.getVar('PN', True)
+    if eula == None:
+        bb.fatal("To use '%s' you need to accept the Freescale EULA at '%s'. "
+                 "Please read it and in case you accept it, write: "
+                 "ACCEPT_FSL_EULA = \"1\" in your local.conf." % (pkg, eula_file))
+    elif eula == '0':
+        bb.fatal("To use '%s' you need to accept the Freescale EULA." % pkg)
+    else:
+        bb.note("Freescale EULA has been accepted for '%s'" % pkg)
+
+    # The binary unpack needs to be done first so 'S' is valid
+    bb.build.exec_func('fsl_bin_do_unpack', d)
+
+    try:
+        bb.build.exec_func('base_do_unpack', d)
+    except:
+        raise
+}
+
+do_unpack[vardepsexclude] += "FSL_EULA_FILE"
diff --git a/classes/fsl-kernel-localversion.bbclass b/classes/fsl-kernel-localversion.bbclass
new file mode 100644
index 00000000..1004e355
--- /dev/null
+++ b/classes/fsl-kernel-localversion.bbclass
@@ -0,0 +1,39 @@
+# Freescale Kernel LOCALVERSION extension
+#
+# This allow to easy reuse of code between different kernel recipes
+#
+# The following options are supported:
+#
+#  SCMVERSION        Puts the Git hash in kernel local version
+#  LOCALVERSION      Value used in LOCALVERSION (default to '+fslc')
+#
+# Copyright 2014, 2015 (C) O.S. Systems Software LTDA.
+
+SCMVERSION ??= "y"
+LOCALVERSION ??= "+fslc"
+
+kernel_conf_variable() {
+        CONF_SED_SCRIPT="$CONF_SED_SCRIPT /CONFIG_$1[ =]/d;"
+        if test "$2" = "n"
+        then
+                echo "# CONFIG_$1 is not set" >> ${B}/.config
+        else
+                echo "CONFIG_$1=$2" >> ${B}/.config
+        fi
+}
+
+do_configure_prepend() {
+        echo "" > ${B}/.config
+        CONF_SED_SCRIPT=""
+
+        kernel_conf_variable LOCALVERSION "\"${LOCALVERSION}\""
+        kernel_conf_variable LOCALVERSION_AUTO y
+
+        sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${B}/.config'
+
+        if [ "${SCMVERSION}" = "y" ]; then
+                # Add GIT revision to the local version
+                head=`git --git-dir=${S}/.git rev-parse --verify --short HEAD 2> /dev/null`
+                printf "%s%s" +g $head > ${S}/.scmversion
+        fi
+}
diff --git a/classes/fsl-u-boot-localversion.bbclass b/classes/fsl-u-boot-localversion.bbclass
new file mode 100644
index 00000000..f7e09714
--- /dev/null
+++ b/classes/fsl-u-boot-localversion.bbclass
@@ -0,0 +1,27 @@
+# Freescale U-Boot LOCALVERSION extension
+#
+# This allow to easy reuse of code between different U-Boot recipes
+#
+# The following options are supported:
+#
+#  SCMVERSION        Puts the Git hash in U-Boot local version
+#  LOCALVERSION      Value used in LOCALVERSION (default to '+fslc')
+#
+# Copyright 2014 (C) O.S. Systems Software LTDA.
+
+SCMVERSION ??= "y"
+LOCALVERSION ??= "+fslc"
+
+UBOOT_LOCALVERSION = "${LOCALVERSION}"
+
+do_compile_prepend() {
+        if [ "${SCMVERSION}" = "y" ]; then
+                # Add GIT revision to the local version
+                head=`git rev-parse --verify --short HEAD 2> /dev/null`
+                printf "%s%s%s" "${UBOOT_LOCALVERSION}" +g $head > ${S}/.scmversion
+                printf "%s%s%s" "${UBOOT_LOCALVERSION}" +g $head > ${B}/.scmversion
+    else
+                printf "%s" "${UBOOT_LOCALVERSION}" > ${S}/.scmversion
+                printf "%s" "${UBOOT_LOCALVERSION}" > ${B}/.scmversion
+        fi
+}
diff --git a/classes/image_types_fsl.bbclass b/classes/image_types_fsl.bbclass
new file mode 100644
index 00000000..b542549d
--- /dev/null
+++ b/classes/image_types_fsl.bbclass
@@ -0,0 +1,320 @@
+inherit image_types
+
+IMAGE_BOOTLOADER ?= "u-boot"
+
+# Handle u-boot suffixes
+UBOOT_SUFFIX ?= "bin"
+UBOOT_SUFFIX_SDCARD ?= "${UBOOT_SUFFIX}"
+
+#
+# Handles i.MX mxs bootstream generation
+#
+MXSBOOT_NAND_ARGS ?= ""
+
+# IMX Bootlets Linux bootstream
+IMAGE_DEPENDS_linux.sb = "elftosb-native:do_populate_sysroot \
+                          imx-bootlets:do_deploy \
+                          virtual/kernel:do_deploy"
+IMAGE_LINK_NAME_linux.sb = ""
+IMAGE_CMD_linux.sb () {
+        kernel_bin="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
+        kernel_dtb="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.dtb || true`"
+        linux_bd_file=imx-bootlets-linux.bd-${MACHINE}
+        if [ `basename $kernel_bin .bin` = `basename $kernel_dtb .dtb` ]; then
+                # When using device tree we build a zImage with the dtb
+                # appended on the end of the image
+                linux_bd_file=imx-bootlets-linux.bd-dtb-${MACHINE}
+                cat $kernel_bin $kernel_dtb \
+                    > $kernel_bin-dtb
+                rm -f ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin-dtb
+                ln -s $kernel_bin-dtb ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin-dtb
+        fi
+
+        # Ensure the file is generated
+        rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.linux.sb
+        (cd ${DEPLOY_DIR_IMAGE}; elftosb -z -c $linux_bd_file -o ${IMAGE_NAME}.linux.sb)
+
+        # Remove the appended file as it is only used here
+        rm -f ${DEPLOY_DIR_IMAGE}/$kernel_bin-dtb
+}
+
+# IMX Bootlets barebox bootstream
+IMAGE_DEPENDS_barebox.mxsboot-sdcard = "elftosb-native:do_populate_sysroot \
+                                        u-boot-mxsboot-native:do_populate_sysroot \
+                                        imx-bootlets:do_deploy \
+                                        barebox:do_deploy"
+IMAGE_CMD_barebox.mxsboot-sdcard () {
+        barebox_bd_file=imx-bootlets-barebox_ivt.bd-${MACHINE}
+
+        # Ensure the files are generated
+        (cd ${DEPLOY_DIR_IMAGE}; rm -f ${IMAGE_NAME}.barebox.sb ${IMAGE_NAME}.barebox.mxsboot-sdcard; \
+         elftosb -f mx28 -z -c $barebox_bd_file -o ${IMAGE_NAME}.barebox.sb; \
+         mxsboot sd ${IMAGE_NAME}.barebox.sb ${IMAGE_NAME}.barebox.mxsboot-sdcard)
+}
+
+# U-Boot mxsboot generation to SD-Card
+UBOOT_SUFFIX_SDCARD_mxs ?= "mxsboot-sdcard"
+IMAGE_DEPENDS_uboot.mxsboot-sdcard = "u-boot-mxsboot-native:do_populate_sysroot \
+                                      u-boot:do_deploy"
+IMAGE_CMD_uboot.mxsboot-sdcard = "mxsboot sd ${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.${UBOOT_SUFFIX} \
+                                             ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.uboot.mxsboot-sdcard"
+
+IMAGE_DEPENDS_uboot.mxsboot-nand = "u-boot-mxsboot-native:do_populate_sysroot \
+                                      u-boot:do_deploy"
+IMAGE_CMD_uboot.mxsboot-nand = "mxsboot ${MXSBOOT_NAND_ARGS} nand \
+                                             ${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.${UBOOT_SUFFIX} \
+                                             ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.uboot.mxsboot-nand"
+
+# Boot partition volume id
+BOOTDD_VOLUME_ID ?= "Boot ${MACHINE}"
+
+# Boot partition size [in KiB]
+BOOT_SPACE ?= "8192"
+
+# Barebox environment size [in KiB]
+BAREBOX_ENV_SPACE ?= "512"
+
+# Set alignment to 4MB [in KiB]
+IMAGE_ROOTFS_ALIGNMENT = "4096"
+
+IMAGE_DEPENDS_sdcard = "parted-native:do_populate_sysroot \
+                        dosfstools-native:do_populate_sysroot \
+                        mtools-native:do_populate_sysroot \
+                        virtual/kernel:do_deploy \
+                        ${@d.getVar('IMAGE_BOOTLOADER', True) and d.getVar('IMAGE_BOOTLOADER', True) + ':do_deploy' or ''}"
+
+SDCARD = "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.sdcard"
+
+SDCARD_GENERATION_COMMAND_mxs = "generate_mxs_sdcard"
+SDCARD_GENERATION_COMMAND_mx25 = "generate_imx_sdcard"
+SDCARD_GENERATION_COMMAND_mx5 = "generate_imx_sdcard"
+SDCARD_GENERATION_COMMAND_mx6 = "generate_imx_sdcard"
+SDCARD_GENERATION_COMMAND_vf = "generate_imx_sdcard"
+
+#
+# Create an image that can by written onto a SD card using dd for use
+# with i.MX SoC family
+#
+# External variables needed:
+#   ${SDCARD_ROOTFS}    - the rootfs image to incorporate
+#   ${IMAGE_BOOTLOADER} - bootloader to use {u-boot, barebox}
+#
+# The disk layout used is:
+#
+#    0                      -> IMAGE_ROOTFS_ALIGNMENT         - reserved to bootloader (not partitioned)
+#    IMAGE_ROOTFS_ALIGNMENT -> BOOT_SPACE                     - kernel and other data
+#    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
+#
+#                                                     Default Free space = 1.3x
+#                                                     Use IMAGE_OVERHEAD_FACTOR to add more space
+#                                                     <--------->
+#            4MiB               8MiB           SDIMG_ROOTFS                    4MiB
+# <-----------------------> <----------> <----------------------> <------------------------------>
+#  ------------------------ ------------ ------------------------ -------------------------------
+# | IMAGE_ROOTFS_ALIGNMENT | BOOT_SPACE | ROOTFS_SIZE            |     IMAGE_ROOTFS_ALIGNMENT    |
+#  ------------------------ ------------ ------------------------ -------------------------------
+# ^                        ^            ^                        ^                               ^
+# |                        |            |                        |                               |
+# 0                      4096     4MiB +  8MiB       4MiB +  8Mib + SDIMG_ROOTFS   4MiB +  8MiB + SDIMG_ROOTFS + 4MiB
+generate_imx_sdcard () {
+        # Create partition table
+        parted -s ${SDCARD} mklabel msdos
+        parted -s ${SDCARD} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED})
+        parted -s ${SDCARD} unit KiB mkpart primary $(expr  ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ $ROOTFS_SIZE)
+        parted ${SDCARD} print
+
+        # Burn bootloader
+        case "${IMAGE_BOOTLOADER}" in
+                imx-bootlets)
+                bberror "The imx-bootlets is not supported for i.MX based machines"
+                exit 1
+                ;;
+                u-boot)
+                if [ -n "${SPL_BINARY}" ]; then
+                        dd if=${DEPLOY_DIR_IMAGE}/${SPL_BINARY} of=${SDCARD} conv=notrunc seek=2 bs=512
+                        dd if=${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.${UBOOT_SUFFIX_SDCARD} of=${SDCARD} conv=notrunc seek=69 bs=1K
+                else
+                        dd if=${DEPLOY_DIR_IMAGE}/u-boot-${MACHINE}.${UBOOT_SUFFIX_SDCARD} of=${SDCARD} conv=notrunc seek=2 bs=512
+                fi
+                ;;
+                barebox)
+                dd if=${DEPLOY_DIR_IMAGE}/barebox-${MACHINE}.bin of=${SDCARD} conv=notrunc seek=1 skip=1 bs=512
+                dd if=${DEPLOY_DIR_IMAGE}/bareboxenv-${MACHINE}.bin of=${SDCARD} conv=notrunc seek=1 bs=512k
+                ;;
+                "")
+                ;;
+                *)
+                bberror "Unknown IMAGE_BOOTLOADER value"
+                exit 1
+                ;;
+        esac
+
+        # Create boot partition image
+        BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDCARD} unit b print \
+                          | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 1024 }')
+        rm -f ${WORKDIR}/boot.img
+        mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
+        mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin ::/${KERNEL_IMAGETYPE}
+
+        # Copy boot scripts
+        for item in ${BOOT_SCRIPTS}; do
+                src=`echo $item | awk -F':' '{ print $1 }'`
+                dst=`echo $item | awk -F':' '{ print $2 }'`
+
+                mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/$src ::/$dst
+        done
+
+        # Copy device tree file
+        if test -n "${KERNEL_DEVICETREE}"; then
+                for DTS_FILE in ${KERNEL_DEVICETREE}; do
+                        DTS_BASE_NAME=`basename ${DTS_FILE} | awk -F "." '{print $1}'`
+                        if [ -e "${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb" ]; then
+                                kernel_bin="`readlink ${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
+                                kernel_bin_for_dtb="`readlink ${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb | sed "s,$DTS_BASE_NAME,${MACHINE},g;s,\.dtb$,.bin,g"`"
+                                if [ $kernel_bin = $kernel_bin_for_dtb ]; then
+                                        mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb ::/${DTS_BASE_NAME}.dtb
+                                fi
+                        fi
+                done
+        fi
+
+        # Burn Partition
+        dd if=${WORKDIR}/boot.img of=${SDCARD} conv=notrunc,fsync seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
+        dd if=${SDCARD_ROOTFS} of=${SDCARD} conv=notrunc,fsync seek=1 bs=$(expr ${BOOT_SPACE_ALIGNED} \* 1024 + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
+}
+
+#
+# Create an image that can by written onto a SD card using dd for use
+# with i.MXS SoC family
+#
+# External variables needed:
+#   ${SDCARD_ROOTFS}    - the rootfs image to incorporate
+#   ${IMAGE_BOOTLOADER} - bootloader to use {imx-bootlets, u-boot}
+#
+generate_mxs_sdcard () {
+        # Create partition table
+        parted -s ${SDCARD} mklabel msdos
+
+        case "${IMAGE_BOOTLOADER}" in
+                imx-bootlets)
+                # The disk layout used is:
+                #
+                #    0                      -> 1024                           - Unused (not partitioned)
+                #    1024                   -> BOOT_SPACE                     - kernel and other data (bootstream)
+                #    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
+                #
+                #                                     Default Free space = 1.3x
+                #                                     Use IMAGE_OVERHEAD_FACTOR to add more space
+                #                                     <--------->
+                #    1024        8MiB          SDIMG_ROOTFS                    4MiB
+                # <-------> <----------> <----------------------> <------------------------------>
+                #  --------------------- ------------------------ -------------------------------
+                # | Unused | BOOT_SPACE | ROOTFS_SIZE            |     IMAGE_ROOTFS_ALIGNMENT    |
+                #  --------------------- ------------------------ -------------------------------
+                # ^        ^            ^                        ^                               ^
+                # |        |            |                        |                               |
+                # 0      1024      1024 + 8MiB       1024 + 8Mib + SDIMG_ROOTFS      1024 + 8MiB + SDIMG_ROOTFS + 4MiB
+                parted -s ${SDCARD} unit KiB mkpart primary 1024 $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED})
+                parted -s ${SDCARD} unit KiB mkpart primary $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ $ROOTFS_SIZE)
+
+                # Empty 4 blocks from boot partition
+                dd if=/dev/zero of=${SDCARD} conv=notrunc seek=2048 count=4
+
+                # Write the bootstream in (2048 + 4) blocks
+                dd if=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.linux.sb of=${SDCARD} conv=notrunc seek=2052
+                ;;
+                u-boot)
+                # The disk layout used is:
+                #
+                #    1M - 2M                  - reserved to bootloader and other data
+                #    2M - BOOT_SPACE          - kernel
+                #    BOOT_SPACE - SDCARD_SIZE - rootfs
+                #
+                # The disk layout used is:
+                #
+                #    1M                     -> 2M                             - reserved to bootloader and other data
+                #    2M                     -> BOOT_SPACE                     - kernel and other data
+                #    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
+                #
+                #                                                        Default Free space = 1.3x
+                #                                                        Use IMAGE_OVERHEAD_FACTOR to add more space
+                #                                                        <--------->
+                #            4MiB                8MiB             SDIMG_ROOTFS                    4MiB
+                # <-----------------------> <-------------> <----------------------> <------------------------------>
+                #  ---------------------------------------- ------------------------ -------------------------------
+                # |      |      |                          |ROOTFS_SIZE             |     IMAGE_ROOTFS_ALIGNMENT    |
+                #  ---------------------------------------- ------------------------ -------------------------------
+                # ^      ^      ^          ^               ^                        ^                               ^
+                # |      |      |          |               |                        |                               |
+                # 0     1M     2M         4M        4MiB + BOOTSPACE   4MiB + BOOTSPACE + SDIMG_ROOTFS   4MiB + BOOTSPACE + SDIMG_ROOTFS + 4MiB
+                #
+                parted -s ${SDCARD} unit KiB mkpart primary 1024 2048
+                parted -s ${SDCARD} unit KiB mkpart primary 2048 $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED})
+                parted -s ${SDCARD} unit KiB mkpart primary $(expr  ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ $ROOTFS_SIZE)
+
+                dd if=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.uboot.mxsboot-sdcard of=${SDCARD} conv=notrunc seek=1 bs=$(expr 1024 \* 1024)
+                BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDCARD} unit b print \
+                | awk '/ 2 / { print substr($4, 1, length($4 -1)) / 1024 }')
+
+                rm -f ${WORKDIR}/boot.img
+                mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
+                mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin ::/${KERNEL_IMAGETYPE}
+                if test -n "${KERNEL_DEVICETREE}"; then
+                        for DTS_FILE in ${KERNEL_DEVICETREE}; do
+                                DTS_BASE_NAME=`basename ${DTS_FILE} | awk -F "." '{print $1}'`
+                                if [ -e "${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb" ]; then
+                                        kernel_bin="`readlink ${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
+                                        kernel_bin_for_dtb="`readlink ${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb | sed "s,$DTS_BASE_NAME,${MACHINE},g;s,\.dtb$,.bin,g"`"
+                                        if [ $kernel_bin = $kernel_bin_for_dtb ]; then
+                                                mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb ::/${DTS_BASE_NAME}.dtb
+                                        fi
+                                fi
+                        done
+                fi
+
+                dd if=${WORKDIR}/boot.img of=${SDCARD} conv=notrunc seek=2 bs=$(expr 1024 \* 1024)
+                ;;
+                barebox)
+                # BAREBOX_ENV_SPACE is taken on BOOT_SPACE_ALIGNED but it doesn't really matter as long as the rootfs is aligned
+                parted -s ${SDCARD} unit KiB mkpart primary 1024 $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} - ${BAREBOX_ENV_SPACE})
+                parted -s ${SDCARD} unit KiB mkpart primary $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} - ${BAREBOX_ENV_SPACE}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED})
+                parted -s ${SDCARD} unit KiB mkpart primary $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ $ROOTFS_SIZE)
+
+                dd if=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.barebox.mxsboot-sdcard of=${SDCARD} conv=notrunc seek=1 bs=$(expr 1024 \* 1024)
+                dd if=${DEPLOY_DIR_IMAGE}/bareboxenv-${MACHINE}.bin of=${SDCARD} conv=notrunc seek=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} - ${BAREBOX_ENV_SPACE}) bs=1024
+                ;;
+                *)
+                bberror "Unknown IMAGE_BOOTLOADER value"
+                exit 1
+                ;;
+        esac
+
+        # Change partition type for mxs processor family
+        bbnote "Setting partition type to 0x53 as required for mxs' SoC family."
+        echo -n S | dd of=${SDCARD} bs=1 count=1 seek=450 conv=notrunc
+
+        parted ${SDCARD} print
+
+        dd if=${SDCARD_ROOTFS} of=${SDCARD} conv=notrunc,fsync seek=1 bs=$(expr ${BOOT_SPACE_ALIGNED} \* 1024 + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
+}
+
+IMAGE_CMD_sdcard () {
+        if [ -z "${SDCARD_ROOTFS}" ]; then
+                bberror "SDCARD_ROOTFS is undefined. To use sdcard image from Freescale's BSP it needs to be defined."
+                exit 1
+        fi
+
+        # Align boot partition and calculate total SD card image size
+        BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
+        BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
+        SDCARD_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $ROOTFS_SIZE + ${IMAGE_ROOTFS_ALIGNMENT})
+
+        # Initialize a sparse file
+        dd if=/dev/zero of=${SDCARD} bs=1 count=0 seek=$(expr 1024 \* ${SDCARD_SIZE})
+
+        ${SDCARD_GENERATION_COMMAND}
+}
+
+# The sdcard requires the rootfs filesystem to be built before using
+# it so we must make this dependency explicit.
+IMAGE_TYPEDEP_sdcard = "${@d.getVar('SDCARD_ROOTFS', 1).split('.')[-1]}"
diff --git a/classes/mfgtool-initramfs-image.bbclass b/classes/mfgtool-initramfs-image.bbclass
new file mode 100644
index 00000000..a9a2adf1
--- /dev/null
+++ b/classes/mfgtool-initramfs-image.bbclass
@@ -0,0 +1,40 @@
+# Generates a Manufacturing Tool Initramfs image
+#
+# This generates the initramfs used for the installation process. The
+# image provides the utilities which are used, in the target, during
+# the process and receive the commands from the MfgTool application.
+#
+# Copyright 2014 (C) O.S. Systems Software LTDA.
+
+DEPENDS += "u-boot-mfgtool linux-mfgtool"
+
+FEATURE_PACKAGES_mtd = "packagegroup-fsl-mfgtool-mtd"
+FEATURE_PACKAGES_extfs = "packagegroup-fsl-mfgtool-extfs"
+
+IMAGE_FSTYPES = "cpio.gz.u-boot"
+IMAGE_ROOTFS_SIZE ?= "8192"
+IMAGE_CLASSES = "image_types_uboot"
+
+# Filesystems enabled by default
+DEFAULT_FS_SUPPORT = " \
+    mtd \
+    extfs \
+"
+
+IMAGE_FEATURES = " \
+    ${DEFAULT_FS_SUPPORT} \
+    \
+    read-only-rootfs \
+"
+
+# Avoid installation of syslog
+BAD_RECOMMENDATIONS += "busybox-syslog"
+
+# Avoid static /dev
+USE_DEVFS = "1"
+
+inherit core-image
+
+CORE_IMAGE_BASE_INSTALL = " \
+    ${CORE_IMAGE_EXTRA_INSTALL} \
+"