1 files changed, 47 insertions, 0 deletions

diff --git a/recipes-kernel/linux/kernel-configure.inc b/recipes-kernel/linux/kernel-configure.inc
new file mode 100644
index 0000000..8c50a74
--- /dev/null
+++ b/recipes-kernel/linux/kernel-configure.inc
@@ -0,0 +1,47 @@
+
+SRC_URI += "file://cfg \
+            file://merge_config.sh "
+
+configure_kernel() {
+    # Add debug flavour config elements from fragments
+    # Listed in increasing priority order if conflicts are detected.
+    #
+
+    #
+    #combine features cfgs with defconfig
+    #
+    addon_features=""
+        if [ -n "${2}" ]; then
+        for feature in ${2}; do
+            addon_features="${addon_features} ${WORKDIR}/${feature}.cfg"
+        done
+    fi
+
+    # Some meta layers like meta-ti use defconfig file to point to a real
+    # default config file (use-kernel-config=config_filename) which is found
+    # under kernel path (${S}/arch/${archname}/configs/).
+    config=`cat ${1} | grep use-kernel-config | cut -d= -f2`
+    if [ "x${config}" != "x" ]
+    then
+        configfilepath=`find ${S}/arch/ -name ${config} -print | head -n 1`
+        if [ -f ${configfilepath} ]
+        then
+            cp ${configfilepath} ${1}
+        else
+            bbfatal "Specified config file:${config} was not found!"
+        fi
+    fi
+
+    O=${B} ${WORKDIR}/merge_config.sh -m ${1} ${addon_features}
+
+    mv -f ${B}/.config ${B}/.mconfig
+
+    #
+    #in linux kernel 2.6.33, kconfig does not support alldefconfig yet.
+    #
+    if [ "x${PV}" = "x2.6.33" ]; then
+        oe_runmake KCONFIG_ALLCONFIG=${B}/.mconfig O=${B} allnoconfig
+    else
+        oe_runmake KCONFIG_ALLCONFIG=${B}/.mconfig O=${B} alldefconfig
+    fi
+}