swift: add setup package

Introduce swift setup package.  At boot time, this
package setups a simple swift cluster including:

* 3 zones
* each zone has 1 storage device which are based
  on loopback devices which the backing files size
  is controlled by variable SWIFT_BACKING_FILE_SIZE

The script /etc/swift/swift_setup.sh is also provided to ease
the task of setting up a complicated Swift cluster.  It reads a
cluster config file, which describes what storage devices are
included in what rings, and constructs the cluster.

For details of how to use swift_setup.sh and the format
of Swift cluster config file please refer to the
script's help:

    $ swift_setup.sh


Signed-off-by: Vu Tran <vu.tran@windriver.com>

1 files changed, 53 insertions, 2 deletions

diff --git a/meta-openstack/recipes-devtools/python/python-swift_git.bb b/meta-openstack/recipes-devtools/python/python-swift_git.bb
index 6ab147d..680dbc3 100644
--- a/meta-openstack/recipes-devtools/python/python-swift_git.bb
+++ b/meta-openstack/recipes-devtools/python/python-swift_git.bb
@@ -11,18 +11,29 @@ SRC_URI = "git://github.com/openstack/${SRCNAME}.git;branch=stable/havana \
            file://proxy-server.conf \
            file://dispersion.conf \
            file://test.conf \
+           file://swift.init \
+           file://swift_setup.sh \
+           file://cluster.conf \
 "
 
 SRCREV="2f3526c559fe53ce904b735a81dee6de46127176"
 PV="2013.2.2+git${SRCPV}"
 S = "${WORKDIR}/git"
 
-inherit setuptools python-dir hosts identity
+inherit setuptools python-dir update-rc.d hosts identity
+
+# The size of the backing file (in Gigabytes) of loopback devices
+# which are used for setting up Swift storage devices.  The value
+# of "0G" is for disabling loopback devices and using local
+# filesystem as Swift storage device.  In this case, the local
+# filesystem of must support xattrs. e.g ext4
+SWIFT_BACKING_FILE_SIZE ?= "2G"
 
 do_install_append() {
     SWIFT_CONF_DIR=${D}${sysconfdir}/swift
 
     install -d ${SWIFT_CONF_DIR}
+    install -d ${D}${sysconfdir}/init.d/
 
     install -m 600 ${S}/etc/swift.conf-sample ${SWIFT_CONF_DIR}/swift.conf
     install -m 600 ${WORKDIR}/proxy-server.conf ${SWIFT_CONF_DIR}/proxy-server.conf
@@ -31,6 +42,9 @@ do_install_append() {
     install -m 600 ${S}/etc/object-server.conf-sample ${SWIFT_CONF_DIR}/object-server.conf
     install -m 600 ${WORKDIR}/dispersion.conf ${SWIFT_CONF_DIR}/dispersion.conf
     install -m 600 ${WORKDIR}/test.conf ${SWIFT_CONF_DIR}/test.conf
+    install -m 755 ${WORKDIR}/swift.init ${D}${sysconfdir}/init.d/swift
+    install -m 700 ${WORKDIR}/swift_setup.sh ${SWIFT_CONF_DIR}/swift_setup.sh
+    install -m 600 ${WORKDIR}/cluster.conf ${SWIFT_CONF_DIR}/cluster.conf
 
     sed 's/^# bind_port =.*/bind_port = 6002/' -i ${SWIFT_CONF_DIR}/account-server.conf
     sed 's/^# user =.*/user = root/' -i ${SWIFT_CONF_DIR}/account-server.conf
@@ -71,7 +85,32 @@ do_install_append() {
     grep -rl '^from test' ${D}/${PYTHON_SITEPACKAGES_DIR}/${SRCNAME}/test | xargs sed 's/^from test/from swift\.test/g' -i
 }
 
-PACKAGES += "${SRCNAME}-tests ${SRCNAME}"
+pkg_postinst_${SRCNAME}-setup () {
+    if [ "x$D" != "x" ]; then
+        exit 1
+    fi
+
+    CLUSTER_CONF=/etc/swift/cluster.conf
+    SWIFT_SETUP='/bin/bash /etc/swift/swift_setup.sh'
+
+    for i in `seq 1 3`; do
+        BACKING_FILE=/etc/swift/swift_backing_$i
+        if [ "x${SWIFT_BACKING_FILE_SIZE}" != "x0G" ]; then
+            truncate -s ${SWIFT_BACKING_FILE_SIZE} $BACKING_FILE
+            sed "s:%SWIFT_BACKING_FILE_${i}%:$BACKING_FILE:g" -i $CLUSTER_CONF
+        else
+            sed "s:%SWIFT_BACKING_FILE_${i}%::g" -i $CLUSTER_CONF
+        fi
+    done
+
+    $SWIFT_SETUP createrings
+    $SWIFT_SETUP formatdevs
+    $SWIFT_SETUP mountdevs
+    $SWIFT_SETUP -i "${CONTROLLER_IP}" adddevs
+    $SWIFT_SETUP unmountdevs
+}
+
+PACKAGES += "${SRCNAME}-tests ${SRCNAME} ${SRCNAME}-setup"
 
 FILES_${PN} = "${libdir}/*\
 "
@@ -79,6 +118,11 @@ FILES_${PN} = "${libdir}/*\
 FILES_${SRCNAME}-tests = "${sysconfdir}/${SRCNAME}/test.conf \
 "
 
+FILES_${SRCNAME}-setup = "${sysconfdir}/init.d/swift \
+    ${sysconfdir}/${SRCNAME}/swift_setup.sh \
+    ${sysconfdir}/${SRCNAME}/cluster.conf \
+"
+
 FILES_${SRCNAME} = "${bindir}/* \
     ${sysconfdir}/${SRCNAME}/* \
 "
@@ -101,3 +145,10 @@ RDEPENDS_${PN} += " \
     "
 
 RDEPENDS_${SRCNAME} = "${PN}"
+
+RDEPENDS_${SRCNAME} = "${PN}"
+RDEPENDS_${SRCNAME}-setup = "${SRCNAME}"
+
+INITSCRIPT_PACKAGES = "${SRCNAME}-setup"
+INITSCRIPT_NAME_${SRCNAME}-setup = "swift"
+INITSCRIPT_PARAMS_${SRCNAME}-setup = "defaults"