1 files changed, 42 insertions, 0 deletions

diff --git a/dynamic-layers/openembedded-layer/recipes-devtools/bpftrace/bpftrace_0.16.0.bb b/dynamic-layers/openembedded-layer/recipes-devtools/bpftrace/bpftrace_0.16.0.bb
new file mode 100644
index 0000000..d39b01a
--- /dev/null
+++ b/dynamic-layers/openembedded-layer/recipes-devtools/bpftrace/bpftrace_0.16.0.bb
@@ -0,0 +1,42 @@
+SUMMARY = "bpftrace"
+HOMEPAGE = "https://github.com/iovisor/bpftrace"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+DEPENDS += "bison-native \
+            flex-native \
+            gzip-native \
+            elfutils \
+            bcc \
+            systemtap \
+            libcereal \
+            libbpf \
+            "
+
+PV .= "+git${SRCREV}"
+RDEPENDS:${PN} += "bash python3 xz"
+
+SRC_URI = "git://github.com/iovisor/bpftrace;branch=master;protocol=https \
+"
+SRCREV = "ed06d87ef19e0b24a96244b1bf50ef85c3f63a37"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+def llvm_major_version(d):
+    pvsplit = d.getVar('LLVMVERSION').split('.')
+    return pvsplit[0]
+
+LLVM_MAJOR_VERSION = "${@llvm_major_version(d)}"
+
+EXTRA_OECMAKE = " \
+    -DCMAKE_ENABLE_EXPORTS=1 \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DLLVM_REQUESTED_VERSION=${LLVM_MAJOR_VERSION} \
+    -DBUILD_TESTING=OFF \
+    -DENABLE_MAN=OFF \
+"
+
+COMPATIBLE_HOST = "(x86_64.*|aarch64.*|powerpc64.*|riscv64.*)-linux"
+COMPATIBLE_HOST:libc-musl = "null"