From dec8d20c290d68c1b741a818e4bc56c51a9da5f4 Mon Sep 17 00:00:00 2001
From: Alexander Kanavin <alexander.kanavin@linux.intel.com>
Date: Fri, 4 Dec 2015 15:35:38 +0200
Subject: python-setuptools: update to 18.7.1

(From OE-Core rev: 3df78d4850e06ba4febd638bf52ee3b2927c5094)

Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
---
 .../python/python-setuptools_18.7.1.bb             | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 meta/recipes-devtools/python/python-setuptools_18.7.1.bb

(limited to 'meta/recipes-devtools/python/python-setuptools_18.7.1.bb')

diff --git a/meta/recipes-devtools/python/python-setuptools_18.7.1.bb b/meta/recipes-devtools/python/python-setuptools_18.7.1.bb
new file mode 100644
index 0000000000..1cc877491e
--- /dev/null
+++ b/meta/recipes-devtools/python/python-setuptools_18.7.1.bb
@@ -0,0 +1,47 @@
+SUMMARY = "Downloads, builds, installs, upgrades, and uninstalls Python packages"
+HOMEPAGE = "https://pypi.python.org/pypi/setuptools"
+SECTION = "devel/python"
+LICENSE = "Python-2.0 | ZPL-2.0"
+LIC_FILES_CHKSUM = "file://setup.py;beginline=78;endline=78;md5=8a314270dd7a8dbca741775415f1716e"
+
+SRCNAME = "setuptools"
+
+PROVIDES = "python-distribute"
+
+DEPENDS += "python"
+DEPENDS_class-native += "python-native"
+
+inherit distutils
+
+SRC_URI = "https://pypi.python.org/packages/source/s/setuptools/setuptools-${PV}.tar.gz"
+SRC_URI[md5sum] = "a0984da9cd8d7b582e1fd7de67dfdbcc"
+SRC_URI[sha256sum] = "aff36c95035e0b311eacb1434e3f7e85f5ccaad477773847e582978f8f45bd74"
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/setuptools"
+
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+
+DISTUTILS_INSTALL_ARGS += "--install-lib=${D}${libdir}/${PYTHON_DIR}/site-packages"
+
+do_install_prepend() {
+    install -d ${D}/${libdir}/${PYTHON_DIR}/site-packages
+}
+
+RDEPENDS_${PN} = "\
+  python-stringold \
+  python-email \
+  python-shell \
+  python-distutils \
+  python-compression \
+"
+
+RDEPENDS_${PN}_class-native = "\
+  python-distutils \
+  python-compression \
+"
+
+RREPLACES_${PN} = "python-distribute"
+RPROVIDES_${PN} = "python-distribute"
+RCONFLICTS_${PN} = "python-distribute"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
cgit v1.2.3-54-g00ecf