summaryrefslogtreecommitdiffstats
path: root/meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb')
-rw-r--r--meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb116
1 files changed, 116 insertions, 0 deletions
diff --git a/meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb b/meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb
new file mode 100644
index 0000000..66a30f8
--- /dev/null
+++ b/meta/recipes-sato/webkit/webkit-gtk_1.8.3.bb
@@ -0,0 +1,116 @@
1DESCRIPTION = "WebKitGTK+ is the port of the portable web rendering engine WebKitK to the GTK+ platform."
2HOMEPAGE = "http://www.webkitgtk.org/"
3BUGTRACKER = "http://bugs.webkit.org/"
4
5LICENSE = "BSD & LGPLv2+"
6LIC_FILES_CHKSUM = "file://Source/WebCore/rendering/RenderApplet.h;endline=22;md5=fb9694013ad71b78f8913af7a5959680 \
7 file://Source/WebKit/gtk/webkit/webkit.h;endline=21;md5=b4fbe9f4a944f1d071dba1d2c76b3351 \
8 file://Source/JavaScriptCore/parser/Parser.h;endline=23;md5=b57c8a2952a8d0e655988fa0ecb2bf7f"
9
10PR = "r0"
11
12# Choice of language backends - icu has issues on Big Endian machines so use pango
13ICU_LIB = "icu"
14ICU_LIB_powerpc = "pango"
15
16DEPENDS = "zlib enchant gnome-keyring libsoup-2.4 curl libxml2 cairo libxslt libxt libidn gnutls \
17 gtk+ gstreamer gst-plugins-base flex-native gperf-native perl-native-runtime sqlite3 ${ICU_LIB}"
18DEPENDS += " ${@base_contains('DISTRO_FEATURES', 'opengl', 'virtual/libgl', '', d)}"
19
20SRC_URI = "\
21 http://www.webkitgtk.org/releases/webkit-${PV}.tar.xz \
22 file://nodolt.patch \
23 file://no-gtkdoc.patch \
24 file://webgit-gtk_fix_build_with_automake_1.12.patch \
25 file://bison-2.6.patch \
26 "
27
28SRC_URI[md5sum] = "dcbf9d5e2e6391f857c29a57528b32a6"
29SRC_URI[sha256sum] = "ada02d636af61aed38f142d3cded662d141ce71264f624c4eb873621a74cc9e7"
30
31inherit autotools lib_package gtk-doc pkgconfig
32
33S = "${WORKDIR}/webkit-${PV}/"
34
35EXTRA_OECONF = "\
36 --enable-debug=no \
37 --enable-svg \
38 --enable-icon-database=yes \
39 --enable-fullscreen-api \
40 --enable-image-resizer \
41 --enable-link-prefetch \
42 --with-gtk=2.0 \
43 --disable-geolocation \
44 ${@base_contains('DISTRO_FEATURES', 'opengl', '--enable-webgl', '--disable-webgl', d)} \
45 UNICODE_CFLAGS=-D_REENTRANT \
46 "
47
48#default unicode backend icu breaks in cross-compile when target and host are different endian type
49EXTRA_OECONF_append_powerpc = " --with-unicode-backend=glib"
50
51CPPFLAGS_append_powerpc = " -I${STAGING_INCDIR}/pango-1.0 \
52 -I${STAGING_LIBDIR}/glib-2.0/include \
53 -I${STAGING_INCDIR}/glib-2.0"
54
55EXTRA_AUTORECONF = " -I Source/autotools "
56
57
58#| ./Source/JavaScriptCore/heap/HandleTypes.h: In static member function 'static T* JSC::HandleTypes<T>::getFromSlot(JSC::HandleSlot) [with T = JSC::Structure, JSC::HandleTypes<T>::ExternalType = JSC::Structure*, JSC::HandleSlot = JSC::JSValue*]':
59#| ./Source/JavaScriptCore/heap/Handle.h:141:79: instantiated from 'JSC::Handle<T>::ExternalType JSC::Handle<T>::get() const [with T = JSC::Structure, JSC::Handle<T>::ExternalType = JSC::Structure*]'
60#| ./Source/JavaScriptCore/runtime/ScopeChain.h:39:75: instantiated from here
61#| ./Source/JavaScriptCore/heap/HandleTypes.h:38:130: warning: cast from 'JSC::JSCell*' to 'JSC::HandleTypes<JSC::Structure>::ExternalType {aka JSC::Structure*}' increases required alignment of target type [-Wcast-align]
62#| {standard input}: Assembler messages:
63#| {standard input}:28873: Error: invalid immediate: 983040 is out of range
64#| {standard input}:28873: Error: value of 983040 too large for field of 2 bytes at 15110
65#| /OE/shr-core/tmp/sysroots/x86_64-linux/usr/libexec/armv4t-oe-linux-gnueabi/gcc/arm-oe-linux-gnueabi/4.6.2/as: BFD (GNU Binutils) 2.21.1 assertion fail /OE/shr-core/tmp/work/armv4t-oe-linux-gnueabi/binutils-cross-2.21.1a-r0/binutils-2.21.1/bfd/elf.c:2819
66#| arm-oe-linux-gnueabi-g++: internal compiler error: Segmentation fault (program as)
67#| Please submit a full bug report,
68#| with preprocessed source if appropriate.
69#| See <http://gcc.gnu.org/bugs.html> for instructions.
70#| make[1]: *** [Source/JavaScriptCore/jit/libjavascriptcoregtk_1_0_la-JIT.lo] Error 1
71#| make[1]: Leaving directory `/OE/shr-core/tmp/work/armv4t-oe-linux-gnueabi/webkit-gtk-1.5.1+svnr90727-r0'
72ARM_INSTRUCTION_SET = "arm"
73
74CONFIGUREOPT_DEPTRACK = ""
75
76do_configure_append() {
77 # somethings wrong with icu, fix it up manually
78 for makefile in $(find ${S} -name "GNUmakefile") ; do
79 sed -i s:-I/usr/include::g $makefile
80 done
81}
82
83# A dirty hack for GNU make 3.82 bug which means it drops required
84# dependencies. https://bugs.webkit.org/show_bug.cgi?id=79498 is the WebKitGTK+
85# bug, and http://savannah.gnu.org/bugs/?30653 is the GNU Make bug. This is
86# fixed in Make CVS, so 3.83 won't have this problem.
87do_compile() {
88 if [ x"$MAKE" = x ]; then MAKE=make; fi
89 bbnote ${MAKE} ${EXTRA_OEMAKE} "$@"
90 for error_count in 1 2 3; do
91 bbnote "Attempt $error_count of 3"
92 exit_code=0
93 ${MAKE} ${EXTRA_OEMAKE} "$@" || exit_code=1
94 if [ $exit_code = 0 ]; then
95 break
96 fi
97 done
98 if [ ! $exit_code = 0 ]; then
99 die "oe_runmake failed"
100 fi
101}
102
103do_install_append() {
104 rmdir ${D}${libexecdir}
105}
106
107PACKAGES =+ "${PN}-webinspector ${PN}launcher-dbg ${PN}launcher libjavascriptcore"
108FILES_${PN}launcher = "${bindir}/GtkLauncher"
109FILES_${PN}launcher-dbg = "${bindir}/.debug/GtkLauncher"
110FILES_libjavascriptcore = "${libdir}/libjavascriptcoregtk-1.0.so.*"
111FILES_${PN}-webinspector = "${datadir}/webkitgtk-*/webinspector/"
112FILES_${PN} += "${datadir}/webkitgtk-*/resources/error.html \
113 ${datadir}/webkitgtk-*/images \
114 ${datadir}/glib-2.0/schemas"
115
116