summaryrefslogtreecommitdiffstats
path: root/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb')
-rw-r--r--meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb68
1 files changed, 68 insertions, 0 deletions
diff --git a/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb
new file mode 100644
index 0000000..c349249
--- /dev/null
+++ b/meta/recipes-sato/rxvt-unicode/rxvt-unicode_9.14.bb
@@ -0,0 +1,68 @@
1SECTION = "x11/utils"
2DESCRIPTION = "rxvt-unicode is a clone of the well known \
3terminal emulator rxvt, modified to store text in Unicode \
4(either UCS-2 or UCS-4) and to use locale-correct input and \
5output. It also supports mixing multiple fonts at the \
6same time, including Xft fonts."
7LICENSE = "GPLv2+"
8LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
9 file://src/main.C;beginline=1;endline=31;md5=775485398a09fa7aee6f90464af88432"
10
11DEPENDS = "virtual/libx11 libxt libxft gdk-pixbuf"
12
13PR = "r0"
14
15SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
16 file://xwc.patch \
17 file://rxvt.desktop \
18 file://rxvt.png"
19
20SRC_URI[md5sum] = "022235a9a8b012c29e72c49177be6ce4"
21SRC_URI[sha256sum] = "29928a33be6b3fb0edd126df2c3d35e1900f8268b546ce54430780c550fa1d52"
22
23inherit autotools update-alternatives
24
25PROVIDES = "virtual/x-terminal-emulator"
26ALTERNATIVE_NAME = "x-terminal-emulator"
27ALTERNATIVE_PATH = "${bindir}/rxvt"
28
29CFLAGS_append = " -fpermissive"
30
31# This is necessary so that the "tic" command executed during the install can
32# link with the correct libary in staging.
33export LD_LIBRARY_PATH = "${STAGING_LIBDIR_NATIVE}"
34
35EXTRA_OECONF = "--enable-menubar --enable-xim \
36 --enable-utmp --enable-wtmp --enable-lastlog \
37 --disable-strings --with-term=rxvt --enable-keepscrolling \
38 --enable-xft --with-name=rxvt --enable-frills \
39 --enable-swapscreen --enable-transparency \
40 --with-codesets=eu \
41 --enable-cursor-blink --enable-pointer-blank \
42 --enable-text-blink --enable-rxvt-scroll \
43 --enable-combining --enable-shared \
44 --enable-xgetdefault \
45 --disable-perl \
46 --with-x=${STAGING_DIR_HOST}${prefix}"
47
48do_configure_prepend () {
49 cp aclocal.m4 acinclude.m4
50}
51
52do_compile_prepend () {
53 echo '#define UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
54 echo '#define WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
55 echo '#define LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
56 echo '#define HAVE_XLOCALE 1' >> config.h
57}
58
59do_install_append () {
60 install -d ${D}/${datadir}
61 install -d ${D}/${datadir}/applications
62 install -d ${D}/${datadir}/pixmaps/
63
64 install -m 0644 ${WORKDIR}/rxvt.png ${D}/${datadir}/pixmaps
65 install -m 0644 ${WORKDIR}/rxvt.desktop ${D}/${datadir}/applications
66}
67
68FILES_${PN} += "${datadir}/applications/rxvt.desktop ${datadir}/pixmaps/rxvt.png"