summaryrefslogtreecommitdiffstats
path: root/meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb
diff options
context:
space:
mode:
Diffstat (limited to 'meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb')
-rw-r--r--meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb141
1 files changed, 141 insertions, 0 deletions
diff --git a/meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb b/meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb
new file mode 100644
index 0000000000..10919523f2
--- /dev/null
+++ b/meta/recipes-multimedia/ffmpeg/ffmpeg_3.2.bb
@@ -0,0 +1,141 @@
1SUMMARY = "A complete, cross-platform solution to record, convert and stream audio and video."
2DESCRIPTION = "FFmpeg is the leading multimedia framework, able to decode, encode, transcode, \
3 mux, demux, stream, filter and play pretty much anything that humans and machines \
4 have created. It supports the most obscure ancient formats up to the cutting edge."
5HOMEPAGE = "https://www.ffmpeg.org/"
6SECTION = "libs"
7
8LICENSE = "GPLv2+"
9LICENSE_FLAGS = "commercial"
10
11LIC_FILES_CHKSUM = "file://COPYING.GPLv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
12 file://COPYING.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
13 file://COPYING.LGPLv2.1;md5=bd7a443320af8c812e4c18d1b79df004 \
14 file://COPYING.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02"
15
16SRC_URI = "https://www.ffmpeg.org/releases/${BP}.tar.xz \
17 file://mips64_cpu_detection.patch \
18 "
19SRC_URI[md5sum] = "3c065fb5baae1aeb1494a09ac984b2de"
20SRC_URI[sha256sum] = "88f70c1b8cab108f494ecbab5ba302cdb35d59a84cea88008b5fe49be068d5da"
21
22# Build fails when thumb is enabled: https://bugzilla.yoctoproject.org/show_bug.cgi?id=7717
23ARM_INSTRUCTION_SET = "arm"
24
25# Should be API compatible with libav (which was a fork of ffmpeg)
26# libpostproc was previously packaged from a separate recipe
27PROVIDES = "libav libpostproc"
28
29DEPENDS = "alsa-lib zlib libogg yasm-native"
30
31inherit autotools pkgconfig
32
33PACKAGECONFIG ??= "avdevice avfilter avcodec avformat swresample swscale postproc \
34 bzlib gpl lzma theora x264 \
35 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 xv', '', d)}"
36
37# libraries to build in addition to avutil
38PACKAGECONFIG[avdevice] = "--enable-avdevice,--disable-avdevice"
39PACKAGECONFIG[avfilter] = "--enable-avfilter,--disable-avfilter"
40PACKAGECONFIG[avcodec] = "--enable-avcodec,--disable-avcodec"
41PACKAGECONFIG[avformat] = "--enable-avformat,--disable-avformat"
42PACKAGECONFIG[swresample] = "--enable-swresample,--disable-swresample"
43PACKAGECONFIG[swscale] = "--enable-swscale,--disable-swscale"
44PACKAGECONFIG[postproc] = "--enable-postproc,--disable-postproc"
45PACKAGECONFIG[avresample] = "--enable-avresample,--disable-avresample"
46
47# features to support
48PACKAGECONFIG[bzlib] = "--enable-bzlib,--disable-bzlib,bzip2"
49PACKAGECONFIG[gpl] = "--enable-gpl,--disable-gpl"
50PACKAGECONFIG[gsm] = "--enable-libgsm,--disable-libgsm,libgsm"
51PACKAGECONFIG[jack] = "--enable-indev=jack,--disable-indev=jack,jack"
52PACKAGECONFIG[libvorbis] = "--enable-libvorbis,--disable-libvorbis,libvorbis"
53PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz"
54PACKAGECONFIG[mp3lame] = "--enable-libmp3lame,--disable-libmp3lame,lame"
55PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
56PACKAGECONFIG[schroedinger] = "--enable-libschroedinger,--disable-libschroedinger,schroedinger"
57PACKAGECONFIG[speex] = "--enable-libspeex,--disable-libspeex,speex"
58PACKAGECONFIG[theora] = "--enable-libtheora,--disable-libtheora,libtheora"
59PACKAGECONFIG[vaapi] = "--enable-vaapi,--disable-vaapi,libva"
60PACKAGECONFIG[vpx] = "--enable-libvpx,--disable-libvpx,libvpx"
61PACKAGECONFIG[x11] = "--enable-x11grab,--disable-x11grab,virtual/libx11 libxfixes libxext xproto virtual/libsdl"
62PACKAGECONFIG[x264] = "--enable-libx264,--disable-libx264,x264"
63PACKAGECONFIG[xv] = "--enable-outdev=xv,--disable-outdev=xv,libxv"
64
65# Check codecs that require --enable-nonfree
66USE_NONFREE = "${@bb.utils.contains_any('PACKAGECONFIG', [ 'openssl' ], 'yes', '', d)}"
67
68EXTRA_OECONF = " \
69 --disable-stripping \
70 --enable-pic \
71 --enable-shared \
72 --enable-pthreads \
73 ${@bb.utils.contains('USE_NONFREE', 'yes', '--enable-nonfree', '', d)} \
74 \
75 --cross-prefix=${TARGET_PREFIX} \
76 \
77 --ld="${CCLD}" \
78 --cc="${CC}" \
79 --cxx="${CXX}" \
80 --arch=${TARGET_ARCH} \
81 --target-os="linux" \
82 --enable-cross-compile \
83 --extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
84 --extra-ldflags="${TARGET_LDFLAGS}" \
85 --sysroot="${STAGING_DIR_TARGET}" \
86 --enable-hardcoded-tables \
87 ${EXTRA_FFCONF} \
88 --libdir=${libdir} \
89 --shlibdir=${libdir} \
90 --datadir=${datadir}/ffmpeg \
91"
92
93do_configure() {
94 ${S}/configure ${EXTRA_OECONF}
95}
96
97PACKAGES_DYNAMIC += "^lib(av(codec|device|filter|format|util|resample)|swscale|swresample|postproc).*"
98
99# ffmpeg disables PIC on some platforms (e.g. x86-32)
100INSANE_SKIP_${MLPREFIX}libavcodec = "textrel"
101INSANE_SKIP_${MLPREFIX}libavdevice = "textrel"
102INSANE_SKIP_${MLPREFIX}libavfilter = "textrel"
103INSANE_SKIP_${MLPREFIX}libavformat = "textrel"
104INSANE_SKIP_${MLPREFIX}libavutil = "textrel"
105INSANE_SKIP_${MLPREFIX}libavresample = "textrel"
106INSANE_SKIP_${MLPREFIX}libswscale = "textrel"
107INSANE_SKIP_${MLPREFIX}libswresample = "textrel"
108INSANE_SKIP_${MLPREFIX}libpostproc = "textrel"
109
110python populate_packages_prepend() {
111 av_libdir = d.expand('${libdir}')
112 av_pkgconfig = d.expand('${libdir}/pkgconfig')
113
114 # Runtime package
115 do_split_packages(d, av_libdir, '^lib(.*)\.so\..*',
116 output_pattern='lib%s',
117 description='libav %s library',
118 extra_depends='',
119 prepend=True,
120 allow_links=True)
121
122 # Development packages (-dev, -staticdev)
123 do_split_packages(d, av_libdir, '^lib(.*)\.so$',
124 output_pattern='lib%s-dev',
125 description='libav %s development package',
126 extra_depends='${PN}-dev',
127 prepend=True,
128 allow_links=True)
129 do_split_packages(d, av_pkgconfig, '^lib(.*)\.pc$',
130 output_pattern='lib%s-dev',
131 description='libav %s development package',
132 extra_depends='${PN}-dev',
133 prepend=True)
134 do_split_packages(d, av_libdir, '^lib(.*)\.a$',
135 output_pattern='lib%s-staticdev',
136 description='libav %s development package - static library',
137 extra_depends='${PN}-dev',
138 prepend=True,
139 allow_links=True)
140
141}
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-08-14 22:36:32 +0000