1 files changed, 61 insertions, 0 deletions

diff --git a/meta/packages/udev/udev.inc b/meta/packages/udev/udev.inc
new file mode 100644
index 0000000000..a3896a6978
--- /dev/null
+++ b/meta/packages/udev/udev.inc
@@ -0,0 +1,61 @@
+DESCRIPTION = "udev is a program which dynamically creates and removes device nodes from \
+/dev/. It responds to /sbin/hotplug device events and requires a 2.6 kernel."
+LICENSE = "GPL"
+
+SRC_URI += " \
+           file://udev.rules \
+           file://devfs-udev.rules \
+           file://links.conf \
+           file://permissions.rules \
+           file://mount.sh \
+           file://network.sh \
+           file://local.rules \
+           file://init"
+
+UDEV_DEVFS_RULES ?= "0"
+
+PACKAGES =+ "udev-utils"
+FILES_udev-utils = "${usrbindir}/udevinfo ${usrbindir}/udevtest"
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "udev"
+INITSCRIPT_PARAMS = "start 04 S ."
+
+export CROSS = "${TARGET_PREFIX}"
+export HOSTCC = "${BUILD_CC}"
+export udevdir ?= "/dev"
+export usrbindir := "${bindir}"
+export usrsbindir := "${sbindir}"
+export etcdir = "${sysconfdir}"
+LD = "${CC}"
+bindir = "/bin"
+sbindir = "/sbin"
+
+UDEV_EXTRAS = "<override me>"
+FILES_${PN} += "${usrbindir} ${usrsbindir}"
+EXTRA_OEMAKE = "-e \
+                'EXTRAS=${UDEV_EXTRAS}' \
+                'STRIP=echo'"
+
+do_install () {
+        install -d ${D}${usrsbindir} \
+                   ${D}${sbindir}
+        oe_runmake 'DESTDIR=${D}' INSTALL=install install
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
+
+        install -d ${D}${sysconfdir}/udev/rules.d/
+
+        install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
+        install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
+        install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
+        if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
+                install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
+        fi
+
+        install -d ${D}${sysconfdir}/udev/scripts/
+
+        install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
+        install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
+}