1 files changed, 58 insertions, 0 deletions

diff --git a/meta/packages/linux-libc-headers/linux-libc-headers_2.6.30.bb b/meta/packages/linux-libc-headers/linux-libc-headers_2.6.30.bb
new file mode 100644
index 0000000000..d9f3fab80d
--- /dev/null
+++ b/meta/packages/linux-libc-headers/linux-libc-headers_2.6.30.bb
@@ -0,0 +1,58 @@
+require linux-libc-headers.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PR = "r2"
+
+SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${PV}.tar.bz2 "
+
+S = "${WORKDIR}/linux-${PV}"
+
+set_arch() {
+        case ${TARGET_ARCH} in
+                alpha*)   ARCH=alpha ;;
+                arm*)     ARCH=arm ;;
+                cris*)    ARCH=cris ;;
+                hppa*)    ARCH=parisc ;;
+                i*86*)    ARCH=i386 ;;
+                ia64*)    ARCH=ia64 ;;
+                mips*)    ARCH=mips ;;
+                m68k*)    ARCH=m68k ;;
+                powerpc*) ARCH=powerpc ;;
+                s390*)    ARCH=s390 ;;
+                sh*)      ARCH=sh ;;
+                sparc64*) ARCH=sparc64 ;;
+                sparc*)   ARCH=sparc ;;
+                x86_64*)  ARCH=x86_64 ;;
+                avr32*)   ARCH=avr32 ;;
+                bfin*)    ARCH=blackfin ;;
+        esac
+}
+
+do_configure() {
+        set_arch
+        oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_compile () {
+}
+
+do_install() {
+        set_arch
+        oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+}
+
+STAGE_TEMP="${WORKDIR}/temp-staging"
+
+do_stage () {
+        set_arch
+        echo $ARCH
+        rm -rf ${STAGE_TEMP}
+        mkdir -p ${STAGE_TEMP}
+        oe_runmake headers_install INSTALL_HDR_PATH=${STAGE_TEMP}${exec_prefix} ARCH=$ARCH
+        install -d ${STAGING_INCDIR}
+        rm -rf ${STAGING_INCDIR}/linux ${STAGING_INCDIR}/asm ${STAGING_INCDIR}/asm-generic
+        cp -pfLR ${STAGE_TEMP}${includedir}/linux ${STAGING_INCDIR}/
+        cp -pfLR ${STAGE_TEMP}${includedir}/asm ${STAGING_INCDIR}/
+        cp -pfLR ${STAGE_TEMP}${includedir}/asm-generic ${STAGING_INCDIR}/
+}