2 files changed, 80 insertions, 1 deletions

diff --git a/meta/classes/image-mklibs.bbclass b/meta/classes/image-mklibs.bbclass
new file mode 100644
index 0000000000..0e72b018c0
--- /dev/null
+++ b/meta/classes/image-mklibs.bbclass
@@ -0,0 +1,69 @@
+do_rootfs[depends] += "mklibs-native:do_populate_sysroot"
+
+IMAGE_PREPROCESS_COMMAND += "mklibs_optimize_image; "
+
+mklibs_optimize_image_doit() {
+        rm -rf ${WORKDIR}/mklibs
+        mkdir -p ${WORKDIR}/mklibs/dest
+        cd ${IMAGE_ROOTFS}
+        du -bs > ${WORKDIR}/mklibs/du.before.mklibs.txt
+        for i in `find .`; do file $i; done \
+                | grep ELF \
+                | grep "LSB executable" \
+                | grep "dynamically linked" \
+                | sed "s/:.*//" \
+                | sed "s+^\./++" \
+                > ${WORKDIR}/mklibs/executables.list
+
+        case ${TARGET_ARCH} in
+                powerpc | mips )
+                        dynamic_loader="/lib/ld.so.1"
+                        ;;
+                x86_64)
+                        dynamic_loader="/lib/ld-linux-x86-64.so.2"
+                        ;;
+                i586 )
+                        dynamic_loader="/lib/ld-linux.so.2"
+                        ;;
+                arm )
+                        dynamic_loader="/lib/ld-linux.so.3"
+                        ;;
+                * )
+                        dynamic_loader="/unknown_dynamic_linker"
+                        ;;
+        esac
+
+        mklibs -v \
+                --ldlib ${dynamic_loader} \
+                --sysroot ${PKG_CONFIG_SYSROOT_DIR} \
+                --root ${IMAGE_ROOTFS} \
+                --target `echo ${TARGET_PREFIX} | sed 's/-$//' ` \
+                -d ${WORKDIR}/mklibs/dest \
+                `cat ${WORKDIR}/mklibs/executables.list`
+
+        cd ${WORKDIR}/mklibs/dest
+        for i in *
+        do
+                cp $i `find ${IMAGE_ROOTFS} -name $i`
+        done
+
+        cd ${IMAGE_ROOTFS}
+        du -bs > ${WORKDIR}/mklibs/du.after.mklibs.txt
+
+        echo rootfs size before mklibs optimization: `cat ${WORKDIR}/mklibs/du.before.mklibs.txt`
+        echo rootfs size after mklibs optimization: `cat ${WORKDIR}/mklibs/du.after.mklibs.txt`
+}
+
+mklibs_optimize_image() {
+        for img in ${MKLIBS_OPTIMIZED_IMAGES}
+        do
+                if [ "${img}" == "${PN}" ] || [ "${img}" == "all" ]
+                then
+                        mklibs_optimize_image_doit
+                        break
+                fi
+        done
+}
+
+
+EXPORT_FUNCTIONS mklibs_optimize_image
diff --git a/meta/conf/local.conf.sample b/meta/conf/local.conf.sample
index d9f7098f0c..d61aaebdd0 100644
--- a/meta/conf/local.conf.sample
+++ b/meta/conf/local.conf.sample
@@ -73,10 +73,20 @@ EXTRA_IMAGE_FEATURES_mx31ads = "tools-testapps debug-tweaks"
 #PACKAGE_CLASSES ?= "package_rpm package_deb package_ipk"
 PACKAGE_CLASSES ?= "package_rpm package_ipk"
 
+# mklibs library size optimization is more useful to smaller images, 
+# and less useful for bigger images. Also mklibs library optimization can break the ABI compatibility, so should not be applied to the images which are tobe
+# extended or upgraded later.
+#This enabled mklibs library size optimization just for the specified image.
+#MKLIBS_OPTIMIZED_IMAGES ?= "poky-image-minimal"
+#This enable mklibs library size optimization will be for all the images.
+#MKLIBS_OPTIMIZED_IMAGES ?= "all"
+
 # A list of additional classes to use when building the system
+# include 'image-mklibs' to reduce shared library files size for an image
 # include 'image-prelink' in order to prelink the filesystem image
 # include 'image-swab' to perform host system intrusion detection
-USER_CLASSES ?= "image-prelink"
+# NOTE: if listing mklibs & prelink both, then make sure mklibs is before prelink
+USER_CLASSES ?= "image-mklibs image-prelink"
 
 # POKYMODE controls the characteristics of the generated packages/images by
 # telling poky which type of toolchain to use.