Initial population

git-svn-id: https://svn.o-hand.com/repos/poky@1 311d38ba-8fff-0310-9ca6-ca027cbcb966

1 files changed, 64 insertions, 0 deletions

diff --git a/openembedded/packages/linux-libc-headers/linux-libc-headers_2.6.11.1.bb b/openembedded/packages/linux-libc-headers/linux-libc-headers_2.6.11.1.bb
new file mode 100644
index 0000000000..c7d6367c7b
--- /dev/null
+++ b/openembedded/packages/linux-libc-headers/linux-libc-headers_2.6.11.1.bb
@@ -0,0 +1,64 @@
+SECTION = "devel"
+DESCRIPTION = "Sanitized set of 2.6 kernel headers for the C library's use."
+HOMEPAGE = "http://ep09.pld-linux.org/~mmazur/linux-libc-headers/"
+# license note from the package: 
+#   Linux-libc-headers are derived from linux kernel headers. For license of a
+#   particular header, check it's content, and if copyright notice isn't present,
+#   standard linux kernel license applies. 
+# since we assume GPL for linux i think we can also assume it here
+LICENSE = "GPL"
+MAINTAINER = "Chris Larson <kergoth@handhelds.org>"
+INHIBIT_DEFAULT_DEPS = "1"
+PR = "r1"
+
+SRC_URI = "http://ep09.pld-linux.org/~mmazur/linux-libc-headers/linux-libc-headers-${PV}.tar.bz2 \
+        file://keyboard.patch;patch=1"
+
+S = "${WORKDIR}/linux-libc-headers-${PV}"
+
+do_configure () {
+        case ${TARGET_ARCH} in
+                alpha*)   ARCH=alpha ;;
+                arm*)     ARCH=arm ;;
+                cris*)    ARCH=cris ;;
+                hppa*)    ARCH=parisc ;;
+                i*86*)    ARCH=i386 ;;
+                ia64*)    ARCH=ia64 ;;
+                mips*)    ARCH=mips ;;
+                m68k*)    ARCH=m68k ;;
+                powerpc*) ARCH=ppc ;;
+                s390*)    ARCH=s390 ;;
+                sh*)      ARCH=sh ;;
+                sparc64*) ARCH=sparc64 ;;
+                sparc*)   ARCH=sparc ;;
+                x86_64*)  ARCH=x86_64 ;;
+        esac
+        if test !  -e include/asm-$ARCH; then
+                oefatal unable to create asm symlink in kernel headers
+        fi
+        cp -a "include/asm-$ARCH" "include/asm"
+        if test "$ARCH" = "arm"; then
+                cp -a include/asm/arch-ebsa285 include/asm/arch
+        elif test "$ARCH" = "sh"; then
+                cp -a include/asm/cpu-${TARGET_ARCH} include/asm/cpu || die "unable to create include/asm/cpu"
+        fi
+}
+
+do_stage () {
+        install -d ${STAGING_INCDIR}
+        rm -rf ${STAGING_INCDIR}/linux ${STAGING_INCDIR}/asm
+        cp -pfLR include/linux ${STAGING_INCDIR}/
+        cp -pfLR include/asm ${STAGING_INCDIR}/
+        rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/linux
+        rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/asm
+        install -d ${CROSS_DIR}/${TARGET_SYS}/include
+        cp -pfLR include/linux ${CROSS_DIR}/${TARGET_SYS}/include/
+        cp -pfLR include/asm ${CROSS_DIR}/${TARGET_SYS}/include/
+}
+
+do_install() {
+        install -d ${D}${includedir}
+        cp -pfLR include/linux ${D}${includedir}/
+        cp -pfLR include/asm ${D}${includedir}/
+}
+