gst-plugins: partially sync packaging with OE .dev

Gst-plugins get 2 extra packages:

${PN}-apps: helper apps in ${bindir}
${PN}-meta: meta package that will drag in all plugins, libs and apps ${PN} generates

And all libs are split out and run through debian style renaming if enabled.

The packaging include was split out to be reused by external plugins (e.g. gst-plugin-gl, gst-fluendo-*).

The new package list looks like:

libgstapp-0.10-0_0.10.32-r1_armv7a.ipk
libgstfft-0.10-0_0.10.32-r1_armv7a.ipk
[..]
gst-plugins-base-videorate_0.10.32-r1_armv7a.ipk
gst-plugins-base-videoscale_0.10.32-r1_armv7a.ipk
[..]
gst-plugins-base-meta_0.10.32-r1_armv7a.ipk
[..]
gst-plugins-base-apps_0.10.32-r1_armv7a.ipk

(From OE-Core rev: 4bfd595934c1f6839ae848b09ecca439d92bf014)

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta/recipes-multimedia/gstreamer/gst-plugins-package.inc b/meta/recipes-multimedia/gstreamer/gst-plugins-package.inc
new file mode 100644
index 0000000000..796df14a9e
--- /dev/null
+++ b/meta/recipes-multimedia/gstreamer/gst-plugins-package.inc
@@ -0,0 +1,34 @@
+LIBV = "0.10"
+
+python populate_packages_prepend () {
+        gst_libdir = bb.data.expand('${libdir}/gstreamer-${LIBV}', d)
+        postinst = bb.data.getVar('plugin_postinst', d, 1)
+        glibdir = bb.data.expand('${libdir}', d)
+
+        do_split_packages(d, glibdir, '^lib(.*)\.so\.*', 'lib%s', 'gstreamer %s library', extra_depends='', allow_links=True)
+        do_split_packages(d, gst_libdir, 'libgst(.*)\.so$', bb.data.expand('${PN}-%s', d), 'GStreamer plugin for %s', postinst=postinst, extra_depends=bb.data.expand('${PN}',d))
+        do_split_packages(d, gst_libdir, 'libgst(.*)\.l?a$', bb.data.expand('${PN}-%s-dev', d), 'GStreamer plugin for %s (development files)', extra_depends=bb.data.expand('${PN}-dev',d))
+        
+        pn = bb.data.getVar('PN', d, 1)
+        metapkg =  pn + '-meta'
+        bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
+        bb.data.setVar('FILES_' + metapkg, "", d)
+        blacklist = [ pn + '-locale', pn + '-dev', pn + '-dbg', pn + '-doc' ]
+        metapkg_rdepends = []
+        packages = bb.data.getVar('PACKAGES', d, 1).split()
+        for pkg in packages[1:]:
+                if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.endswith('-dbg') and not pkg.count('locale') and not pkg.count('-static'):
+                        metapkg_rdepends.append(pkg)
+        bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
+        bb.data.setVar('DESCRIPTION_' + metapkg, pn + ' meta package', d)
+}
+
+ALLOW_EMPTY = "1"
+
+PACKAGES += "${PN}-apps ${PN}-meta"
+FILES_${PN}-apps = "${bindir}"
+
+FILES_${PN} = "${datadir}/gstreamer-${LIBV}"
+FILES_${PN}-dbg += "${libdir}/gstreamer-${LIBV}/.debug"
+
+