diffutils: upgrade to 3.6

diffutils-3.5-gcc7.patch is removed as it's merged in this version.

do_configure_prepend is removed to solve the following configure error.

  error: possibly undefined macro: gl_TYPE_WINT_T_PREREQ

A workaround patch is made to fix the following compilation error for glibc.

  error: dereferencing pointer to incomplete type 'const struct rpl_option'

(From OE-Core rev: 0c09f9f5700696670b2a9d0466124309100eb296)

Signed-off-by: Chen Qi <Qi.Chen@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta/recipes-extended/diffutils/diffutils_3.6.bb b/meta/recipes-extended/diffutils/diffutils_3.6.bb
new file mode 100644
index 0000000000..a2ea484d88
--- /dev/null
+++ b/meta/recipes-extended/diffutils/diffutils_3.6.bb
@@ -0,0 +1,34 @@
+LICENSE = "GPLv3+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+require diffutils.inc
+
+SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
+           file://0001-Unset-need_charset_alias-when-building-for-musl.patch \
+           file://run-ptest \
+"
+SRC_URI_append_libc-glibc = " file://0001-explicitly-disable-replacing-getopt.patch"
+
+SRC_URI[md5sum] = "07cf286672ced26fba54cd0313bdc071"
+SRC_URI[sha256sum] = "d621e8bdd4b573918c8145f7ae61817d1be9deb4c8d2328a65cea8e11d783bd6"
+
+EXTRA_OECONF += "ac_cv_path_PR_PROGRAM=${bindir}/pr --without-libsigsegv-prefix"
+
+# Fix "Argument list too long" error when len(TMPDIR) = 410
+acpaths = "-I ./m4"
+
+inherit ptest
+
+do_install_ptest() {
+        t=${D}${PTEST_PATH}
+        install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
+        cp -r ${S}/tests $t/
+        install ${B}/tests/Makefile $t/tests/
+        sed -e 's|^Makefile:|_Makefile:|' \
+            -e 's|bash|sh|' \
+            -e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
+            -e 's|^srcdir = \(.*\)|srcdir = .|' \
+            -e 's|"`$(built_programs)`"|diff|' \
+            -e 's|gawk|awk|g' \
+            -i $t/tests/Makefile
+}