python3-jsonschema: 4.7.1 -> 4.7.2 + fixed the rdepends

And spitted the files for the tests into a -test package

buildhistory:
  images/raspberrypi4_64/glibc/core-image-base: IMAGESIZE changed from 208024 to 183660 (-12%)
  Changes to images/raspberrypi4_64/glibc/core-image-base (installed-package-names.txt):
    python3-pyparsing was removed
    python3-pip was removed
    python3-setuptools-scm was removed
    python3-packaging was removed
    python3-typing-extensions was removed
    python3-pkg-resources was removed
    python3-tomli was removed
    python3-setuptools was removed

(From OE-Core rev: d744882251236800412870922b30ddbc70d214e5)

Signed-off-by: Jan Vermaete <jan.vermaete@gmail.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/meta/recipes-devtools/python/python3-jsonschema_4.7.2.bb b/meta/recipes-devtools/python/python3-jsonschema_4.7.2.bb
new file mode 100644
index 0000000000..af728ab2d6
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-jsonschema_4.7.2.bb
@@ -0,0 +1,48 @@
+SUMMARY = "An implementation of JSON Schema validation for Python"
+HOMEPAGE = "https://github.com/Julian/jsonschema"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=7a60a81c146ec25599a3e1dabb8610a8 \
+                    file://json/LICENSE;md5=9d4de43111d33570c8fe49b4cb0e01af"
+
+SRC_URI[sha256sum] = "73764f461d61eb97a057c929368610a134d1d1fffd858acfe88864ee94f1f1d3"
+
+inherit pypi python_hatchling
+
+PACKAGES =+ "${PN}-tests"
+FILES:${PN}-tests = "${libdir}/${PYTHON_DIR}/site-packages/jsonschema/tests"
+
+DEPENDS += "${PYTHON_PN}-hatch-vcs-native"
+
+PACKAGECONFIG ??= "format"
+PACKAGECONFIG[format] = ",,,\
+    ${PYTHON_PN}-idna \
+    ${PYTHON_PN}-jsonpointer \
+    ${PYTHON_PN}-webcolors \
+    ${PYTHON_PN}-rfc3987 \
+    ${PYTHON_PN}-strict-rfc3339 \
+"
+PACKAGECONFIG[nongpl] = ",,,\
+    ${PYTHON_PN}-idna \
+    ${PYTHON_PN}-jsonpointer \
+    ${PYTHON_PN}-webcolors \
+    ${PYTHON_PN}-rfc3986-validator \
+    ${PYTHON_PN}-rfc3339-validator \
+"
+
+RDEPENDS:${PN} += " \
+    ${PYTHON_PN}-attrs \
+    ${PYTHON_PN}-core \
+    ${PYTHON_PN}-datetime \
+    ${PYTHON_PN}-importlib-metadata \
+    ${PYTHON_PN}-io \
+    ${PYTHON_PN}-json \
+    ${PYTHON_PN}-netclient \
+    ${PYTHON_PN}-numbers \
+    ${PYTHON_PN}-pprint \
+    ${PYTHON_PN}-pyrsistent \
+    ${PYTHON_PN}-zipp \
+"
+
+RDEPENDS:${PN}-tests = "${PN}"
+
+BBCLASSEXTEND = "native nativesdk"