mtd-utils: Update version to include fixes after 1.5.0

This includes fixes on master branch not in the 1.5.0 release

(From OE-Core rev: 51a2478b5542b2a1315c98d3f807535b9f0c46d2)

Signed-off-by: Lauren Post <lauren.post@freescale.com>
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/recipes-devtools/mtd/mtd-utils_git.bb b/meta/recipes-devtools/mtd/mtd-utils_git.bb
new file mode 100644
index 0000000000..f1e2a8e084
--- /dev/null
+++ b/meta/recipes-devtools/mtd/mtd-utils_git.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Tools for managing memory technology devices"
+SECTION = "base"
+DEPENDS = "zlib lzo e2fsprogs util-linux"
+HOMEPAGE = "http://www.linux-mtd.infradead.org/"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+                    file://include/common.h;beginline=1;endline=17;md5=ba05b07912a44ea2bf81ce409380049c"
+
+# Use the latest version at 26 Oct, 2013
+SRCREV = "dcea43eba91642939c82739387147da26d572758"
+SRC_URI = "git://git.infradead.org/mtd-utils.git \
+                file://add-exclusion-to-mkfs-jffs2-git-2.patch \
+"
+
+PV = "1.5.0+git${SRCPV}"
+
+S = "${WORKDIR}/git/"
+
+EXTRA_OEMAKE = "'CC=${CC}' 'RANLIB=${RANLIB}' 'AR=${AR}' 'CFLAGS=${CFLAGS} -I${S}/include -DWITHOUT_XATTR' 'BUILDDIR=${S}'"
+
+do_install () {
+        oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} INCLUDEDIR=${includedir}
+}
+
+PACKAGES =+ "mtd-utils-jffs2 mtd-utils-ubifs mtd-utils-misc"
+
+FILES_mtd-utils-jffs2 = "${sbindir}/mkfs.jffs2 ${sbindir}/jffs2dump ${sbindir}/jffs2reader ${sbindir}/sumtool"
+FILES_mtd-utils-ubifs = "${sbindir}/mkfs.ubifs ${sbindir}/ubi*"
+FILES_mtd-utils-misc = "${sbindir}/nftl* ${sbindir}/ftl* ${sbindir}/rfd* ${sbindir}/doc* ${sbindir}/serve_image ${sbindir}/recv_image"
+
+PARALLEL_MAKE = ""
+
+BBCLASSEXTEND = "native"