i2c-tools: uprev to 3.1.2

The only changes based on the CHANGES file are:
  decode-dimms: Fix DDR3 extended temp range refresh rate decoding
  py-smbus: Add support for python 3
The python3 changes use python3 as the default and 2 as the fallback.
py-smbus is not currently built so no python changes have been made.

The local copy of Module.mk is unchanged aside from moving it to
a directory that is not version specific to avoid uprev noise.

(From OE-Core rev: e0cbd3c64dab5db5df6415bbc0042b1b50b3c7ac)

Signed-off-by: Randy MacLeod <Randy.MacLeod@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta/recipes-devtools/i2c-tools/i2c-tools_3.1.2.bb b/meta/recipes-devtools/i2c-tools/i2c-tools_3.1.2.bb
new file mode 100644
index 0000000000..92f4d69d3a
--- /dev/null
+++ b/meta/recipes-devtools/i2c-tools/i2c-tools_3.1.2.bb
@@ -0,0 +1,34 @@
+SUMMARY = "Set of i2c tools for linux"
+SECTION = "base"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+
+SRC_URI = "http://dl.lm-sensors.org/i2c-tools/releases/${BP}.tar.bz2 \
+           file://Module.mk \
+"
+SRC_URI[md5sum] = "7104a1043d11a5e2c7b131614eb1b962"
+SRC_URI[sha256sum] = "db5e69f2e2a6e3aa2ecdfe6a5f490b149c504468770f58921c8c5b8a7860a441"
+
+inherit autotools-brokensep
+
+do_compile_prepend() {
+    cp ${WORKDIR}/Module.mk ${S}/eepromer/
+    sed -i 's#/usr/local#/usr#' ${S}/Makefile
+    echo "include eepromer/Module.mk" >> ${S}/Makefile
+}
+
+do_install_append() {
+    install -d ${D}${includedir}/linux
+    install -m 0644 include/linux/i2c-dev.h ${D}${includedir}/linux/i2c-dev-user.h
+    rm -f ${D}${includedir}/linux/i2c-dev.h
+}
+
+PACKAGES =+ "${PN}-misc"
+FILES_${PN}-misc = "${sbindir}/i2c-stub-from-dump \
+                        ${bindir}/ddcmon \
+                        ${bindir}/decode-edid \
+                        ${bindir}/decode-dimms \
+                        ${bindir}/decode-vaio \
+                       "
+RDEPENDS_${PN} += "${PN}-misc"
+RDEPENDS_${PN}-misc += "perl"