e2fsprogs: 1.42.9 -> 1.43 (master)

Upgrade to 1.43 (master) to make "mke2fs -d" support xattr, so that the
layer which requires xattr such as meta-selinux can populate images
easily.

* Remove the following patches since they are alredy in the source.
  0001-e2fsprogs-fix-cross-compilation-problem.patch
  0001-libext2fs-fix-potential-buffer-overflow-in-closefs.patch
  0001-mke2fs-add-the-ability-to-copy-files-from-a-given-di.patch
  0002-misc-create_inode.c-copy-files-recursively.patch
  0003-misc-create_inode.c-create-special-file.patch
  0004-misc-create_inode.c-create-symlink.patch
  0005-misc-create_inode.c-copy-regular-file.patch
  0006-misc-create_inode.c-create-directory.patch
  0007-misc-create_inode.c-set-owner-mode-time-for-the-inod.patch
  0008-mke2fs.c-add-an-option-d-root-directory.patch
  0009-misc-create_inode.c-handle-hardlinks.patch
  0010-debugfs-use-the-functions-in-misc-create_inode.c.patch
  0011-mke2fs.8.in-update-the-manual-for-the-d-option.patch
  0012-Fix-musl-build-failures.patch
  CVE-2015-0247.patch
  copy-in-create-hardlinks-with-the-correct-directory-.patch
  fix-icache.patch
  misc-mke2fs.c-return-error-when-failed-to-populate-fs.patch

* Remove cache_inode.patch since it is not needed any more

* Updated mkdir.patch and ptest.patch

* Add --enable-libblkid to EXTRA_OECONF since libblkid is not created by
  default.

* Time of core-image-sato-sdk do_rootfs:
  - Before upgrade
    real    3m18.508s
    user    7m42.088s
    sys     1m1.984s

  - After upgrade
    real    3m21.552s
    user    7m38.496s
    sys     1m0.644s

   The are nearly the same

* The "fsck -f" shows the image is OK, and also can boot.

[YOCTO #8622]

(From OE-Core rev: a1f235ad736d322bb50eb4a4293b6b2f4e5200aa)

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 93 insertions, 0 deletions

diff --git a/meta/recipes-devtools/e2fsprogs/e2fsprogs_git.bb b/meta/recipes-devtools/e2fsprogs/e2fsprogs_git.bb
new file mode 100644
index 0000000000..0aab8ae3f6
--- /dev/null
+++ b/meta/recipes-devtools/e2fsprogs/e2fsprogs_git.bb
@@ -0,0 +1,93 @@
+require e2fsprogs.inc
+
+SRC_URI += "file://acinclude.m4 \
+            file://remove.ldconfig.call.patch \
+            file://quiet-debugfs.patch \
+            file://run-ptest \
+            file://ptest.patch \
+            file://mkdir.patch \
+"
+
+SRCREV = "0f26747167cc9d82df849b0aad387bf824f04544"
+PV = "1.42+1.43-git${SRCPV}"
+
+EXTRA_OECONF += "--libdir=${base_libdir} --sbindir=${base_sbindir} \
+                --enable-elf-shlibs --disable-libuuid --disable-uuidd \
+                --enable-libblkid --enable-verbose-makecmds"
+
+EXTRA_OECONF_darwin = "--libdir=${base_libdir} --sbindir=${base_sbindir} --enable-bsd-shlibs"
+
+do_configure_prepend () {
+        cp ${WORKDIR}/acinclude.m4 ${S}/
+}
+
+do_install () {
+        oe_runmake 'DESTDIR=${D}' install
+        oe_runmake 'DESTDIR=${D}' install-libs
+        # We use blkid from util-linux now so remove from here
+        rm -f ${D}${base_libdir}/libblkid*
+        rm -rf ${D}${includedir}/blkid
+        rm -f ${D}${base_libdir}/pkgconfig/blkid.pc
+        rm -f ${D}${base_sbindir}/blkid
+        rm -f ${D}${base_sbindir}/fsck
+        rm -f ${D}${base_sbindir}/findfs
+
+        # e2initrd_helper and the pkgconfig files belong in libdir
+        if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
+                install -d ${D}${libdir}
+                mv ${D}${base_libdir}/e2initrd_helper ${D}${libdir}
+                mv ${D}${base_libdir}/pkgconfig ${D}${libdir}
+        fi
+
+        oe_multilib_header ext2fs/ext2_types.h
+        install -d ${D}${base_bindir}
+        mv ${D}${bindir}/chattr ${D}${base_bindir}/chattr.e2fsprogs
+
+        install -v -m 755 ${S}/contrib/populate-extfs.sh ${D}${base_sbindir}/
+}
+
+do_install_append_class-target() {
+        # Clean host path in compile_et, mk_cmds
+        sed -i -e "s,ET_DIR=\"${S}/lib/et\",ET_DIR=\"${datadir}/et\",g" ${D}${bindir}/compile_et
+        sed -i -e "s,SS_DIR=\"${S}/lib/ss\",SS_DIR=\"${datadir}/ss\",g" ${D}${bindir}/mk_cmds
+}
+
+RDEPENDS_e2fsprogs = "e2fsprogs-badblocks"
+RRECOMMENDS_e2fsprogs = "e2fsprogs-mke2fs e2fsprogs-e2fsck"
+
+PACKAGES =+ "e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-tune2fs e2fsprogs-badblocks e2fsprogs-resize2fs"
+PACKAGES =+ "libcomerr libss libe2p libext2fs"
+
+FILES_e2fsprogs-resize2fs = "${base_sbindir}/resize2fs*"
+FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck ${base_sbindir}/fsck.ext*"
+FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs ${base_sbindir}/mkfs.ext* ${sysconfdir}/mke2fs.conf"
+FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs ${base_sbindir}/e2label"
+FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks"
+FILES_libcomerr = "${base_libdir}/libcom_err.so.*"
+FILES_libss = "${base_libdir}/libss.so.*"
+FILES_libe2p = "${base_libdir}/libe2p.so.*"
+FILES_libext2fs = "${libdir}/e2initrd_helper ${base_libdir}/libext2fs.so.*"
+FILES_${PN}-dev += "${datadir}/*/*.awk ${datadir}/*/*.sed ${base_libdir}/*.so"
+
+ALTERNATIVE_${PN} = "chattr"
+ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_LINK_NAME[chattr] = "${base_bindir}/chattr"
+ALTERNATIVE_TARGET[chattr] = "${base_bindir}/chattr.e2fsprogs"
+
+ALTERNATIVE_${PN}-doc = "libblkid.3 blkid.8 findfs.8 fsck.8"
+ALTERNATIVE_LINK_NAME[libblkid.3] = "${mandir}/man3/libblkid.3"
+ALTERNATIVE_LINK_NAME[blkid.8] = "${mandir}/man8/blkid.8"
+ALTERNATIVE_LINK_NAME[findfs.8] = "${mandir}/man8/findfs.8"
+ALTERNATIVE_LINK_NAME[fsck.8] = "${mandir}/man8/fsck.8"
+
+RDEPENDS_${PN}-ptest += "${PN} ${PN}-tune2fs coreutils procps bash"
+
+do_compile_ptest() {
+        oe_runmake -C ${B}/tests
+}
+
+do_install_ptest() {
+        cp -a ${B}/tests ${D}${PTEST_PATH}/test
+        cp -a ${S}/tests/* ${D}${PTEST_PATH}/test
+        sed -e 's!../e2fsck/e2fsck!e2fsck!g' -i ${D}${PTEST_PATH}/test/*/expect*
+}