summaryrefslogtreecommitdiffstats
path: root/meta/recipes-core/images/build-appliance-image_12.0.1.bb
diff options
context:
space:
mode:
authorAlexander Kanavin <alexander.kanavin@linux.intel.com>2016-01-19 15:37:35 (GMT)
committerRichard Purdie <richard.purdie@linuxfoundation.org>2016-01-20 17:07:11 (GMT)
commit0436e3fe2e359b9b559c1ebb6094ee786253ea89 (patch)
treeb3703da2f7d43a92e0875956dbe2dc115931023b /meta/recipes-core/images/build-appliance-image_12.0.1.bb
parenta206a19cb2e628fb7a8b2db5093572915afff6ec (diff)
downloadpoky-0436e3fe2e359b9b559c1ebb6094ee786253ea89.tar.gz
build-appliance-image: bump version to 14.0
This is done to make recipe version reporting tool happy. (From OE-Core rev: 7a31e2bfa26ca4a8942abb5d9c94d529cfa2ce54) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Diffstat (limited to 'meta/recipes-core/images/build-appliance-image_12.0.1.bb')
-rw-r--r--meta/recipes-core/images/build-appliance-image_12.0.1.bb93
1 files changed, 0 insertions, 93 deletions
diff --git a/meta/recipes-core/images/build-appliance-image_12.0.1.bb b/meta/recipes-core/images/build-appliance-image_12.0.1.bb
deleted file mode 100644
index 8f9ce1b..0000000
--- a/meta/recipes-core/images/build-appliance-image_12.0.1.bb
+++ /dev/null
@@ -1,93 +0,0 @@
1SUMMARY = "An image containing the build system itself"
2DESCRIPTION = "An image containing the build system that you can boot and run using either VMware Player or VMware Workstation."
3HOMEPAGE = "http://www.yoctoproject.org/documentation/build-appliance"
4
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=4d92cd373abda3937c2bc47fbc49d690 \
7 file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
8
9IMAGE_INSTALL = "packagegroup-core-boot packagegroup-core-ssh-openssh packagegroup-self-hosted"
10
11IMAGE_FEATURES += "x11-base package-management splash"
12
13# Ensure there's enough space to do a core-image-sato build, with rm_work enabled
14IMAGE_ROOTFS_EXTRA_SPACE = "41943040"
15
16# Do a quiet boot with limited console messages
17APPEND += "rootfstype=ext4 quiet"
18
19DEPENDS = "zip-native"
20IMAGE_FSTYPES = "vmdk"
21
22inherit core-image
23
24SRCREV ?= "992e5774714ef44bc91d45e2aaf2acfc23c72d63"
25SRC_URI = "git://git.yoctoproject.org/poky \
26 file://Yocto_Build_Appliance.vmx \
27 file://Yocto_Build_Appliance.vmxf \
28 "
29
30IMAGE_CMD_ext4_append () {
31 # We don't need to reserve much space for root, 0.5% is more than enough
32 tune2fs -m 0.5 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4
33}
34
35fakeroot do_populate_poky_src () {
36 # Because fetch2's git's unpack uses -s cloneflag, the unpacked git repo
37 # will become invalid in the target.
38 rm -rf ${WORKDIR}/git/.git
39 rm -f ${WORKDIR}/git/.gitignore
40
41 cp -Rp ${WORKDIR}/git ${IMAGE_ROOTFS}/home/builder/poky
42
43 mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/conf
44 mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/downloads
45 cp -RpL ${DL_DIR}/* ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/
46
47 # Remove the git2_* tarballs -- this is ok since we still have the git2/.
48 rm -rf ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/git2_*
49
50 echo "/usr/bin" > ${IMAGE_ROOTFS}/home/builder/poky/build/pseudodone
51 echo "INHERIT += \"rm_work\"" >> ${IMAGE_ROOTFS}/home/builder/poky/build/conf/auto.conf
52 mkdir -p ${IMAGE_ROOTFS}/home/builder/pseudo
53 echo "export PSEUDO_PREFIX=/usr" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
54 echo "export PSEUDO_LOCALSTATEDIR=/home/builder/pseudo" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
55 echo "export PSEUDO_LIBDIR=/usr/lib/pseudo/lib64" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
56
57 chown builder.builder ${IMAGE_ROOTFS}/home/builder/pseudo
58
59 chown -R builder.builder ${IMAGE_ROOTFS}/home/builder/poky
60
61 # Allow builder to use sudo to setup tap/tun
62 echo "builder ALL=(ALL) NOPASSWD: ALL" >> ${IMAGE_ROOTFS}/etc/sudoers
63
64 # Use Clearlooks GTK+ theme
65 mkdir -p ${IMAGE_ROOTFS}/etc/gtk-2.0
66 echo 'gtk-theme-name = "Clearlooks"' > ${IMAGE_ROOTFS}/etc/gtk-2.0/gtkrc
67}
68
69IMAGE_PREPROCESS_COMMAND += "do_populate_poky_src; "
70
71addtask rootfs after do_unpack
72
73python () {
74 # Ensure we run these usually noexec tasks
75 d.delVarFlag("do_fetch", "noexec")
76 d.delVarFlag("do_unpack", "noexec")
77}
78
79create_bundle_files () {
80 cd ${WORKDIR}
81 mkdir -p Yocto_Build_Appliance
82 cp *.vmx* Yocto_Build_Appliance
83 ln -sf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.vmdk Yocto_Build_Appliance/Yocto_Build_Appliance.vmdk
84 zip -r ${DEPLOY_DIR_IMAGE}/Yocto_Build_Appliance-${DATETIME}.zip Yocto_Build_Appliance
85 ln -sf Yocto_Build_Appliance-${DATETIME}.zip ${DEPLOY_DIR_IMAGE}/Yocto_Build_Appliance.zip
86}
87
88python do_bundle_files() {
89 bb.build.exec_func('create_bundle_files', d)
90}
91
92addtask bundle_files after do_vmimg before do_build
93do_bundle_files[nostamp] = "1"