bind: update to 9.8.1

The COPYRIGHT File was updates for both Year and showing the complete
list of contributors, this change effectively adds BSD equivlant to
the licensing terms.

(From OE-Core rev: a770a56aba6419372654ea6f1413672a0aa19cc0)

Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/meta/recipes-connectivity/bind/bind_9.8.1.bb b/meta/recipes-connectivity/bind/bind_9.8.1.bb
new file mode 100644
index 0000000000..330acdbef2
--- /dev/null
+++ b/meta/recipes-connectivity/bind/bind_9.8.1.bb
@@ -0,0 +1,55 @@
+DESCRIPTION = "ISC Internet Domain Name Server"
+HOMEPAGE = "http://www.isc.org/sw/bind/"
+SECTION = "console/network"
+
+LICENSE = "ISC & BSD"
+LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=0fbe2a3ab3c68ac3fea3cad13093877c"
+
+DEPENDS = "openssl"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.isc.org/isc/bind9/${PV}/${BPN}-${PV}.tar.gz \
+           file://conf.patch \
+           file://cross-build-fix.patch \
+           "
+
+SRC_URI[md5sum] = "cf31117c5d35af34d4c0702970ad9fb7"
+SRC_URI[sha256sum] = "02285dc429cb2a6687a1b2446e9ee22c1df27f2577225b05be5092395ee7c92c"
+
+# --enable-exportlib is necessary for building dhcp
+EXTRA_OECONF = " --enable-ipv6=no --with-randomdev=/dev/random --disable-threads \
+                 --disable-devpoll --disable-epoll --with-gost=no \
+                 --sysconfdir=${sysconfdir}/bind \
+                 --with-openssl=${STAGING_LIBDIR}/.. --with-libxml2=${STAGING_LIBDIR}/.. \
+                 --enable-exportlib --with-export-includedir=${includedir} --with-export-libdir=${libdir} \
+               "
+inherit autotools update-rc.d
+
+INITSCRIPT_NAME = "bind"
+INITSCRIPT_PARAMS = "defaults"
+
+PARALLEL_MAKE = ""
+
+PACKAGES_prepend = "${PN}-utils "
+FILES_${PN}-utils = "${bindir}/host ${bindir}/dig ${bindir}/nslookup"
+FILES_${PN}-dev += "${bindir}/isc-config.h"
+
+do_install_append() {
+        rm "${D}${bindir}/nslookup"
+        install -d "${D}${sysconfdir}/bind"
+        install -d "${D}${sysconfdir}/init.d"
+        install -m 644 ${S}/conf/* "${D}${sysconfdir}/bind/"
+        install -m 755 "${S}/init.d" "${D}${sysconfdir}/init.d/bind"
+}
+
+CONFFILES_${PN} = " \
+        ${sysconfdir}/bind/named.conf \
+        ${sysconfdir}/bind/named.conf.local \
+        ${sysconfdir}/bind/named.conf.options \
+        ${sysconfdir}/bind/db.0 \
+        ${sysconfdir}/bind/db.127 \
+        ${sysconfdir}/bind/db.empty \
+        ${sysconfdir}/bind/db.local \
+        ${sysconfdir}/bind/db.root \
+        "
+