Refactored MACHINE_* usage

* Added 'conf/machine/boards' as a default FILESEXTRAPATH
  (for each available layer).
* Change MACHINE_* to rely only on the path being relative to
  'conf/machine/boards'.
* Fixed up linux-xlnx.inc and linux-machine-common.inc to use 'MACHINE_*'
  for default files.
* Fixed KERNEL_DEVICETREE setting such that the variable is valid before
  the base __anonymous function of linux-dtb.inc is executed.

Signed-off-by: Nathan Rossi <nathan.rossi@xilinx.com>

3 files changed, 64 insertions, 29 deletions

diff --git a/recipes-kernel/linux/linux-machine-common.inc b/recipes-kernel/linux/linux-machine-common.inc
index 6d8cd8c5..2ef76ff9 100644
--- a/recipes-kernel/linux/linux-machine-common.inc
+++ b/recipes-kernel/linux/linux-machine-common.inc
@@ -5,6 +5,4 @@ require linux-machine-config.inc
 DEPENDS_append_microblaze += "u-boot-mkimage-native"
 
 # Common Device Tree Includes
-# (put them in ${WORKDIR} to avoid using dtc with include paths)
-FILESEXTRAPATHS_append := "${XILINX_LAYERDIR}/conf/machine/boards/common:"
-SRC_URI_append += "file://zynq-7-base.dtsi"
+MACHINE_DEVICETREE_append_zynq += "common/zynq-7-base.dtsi"
diff --git a/recipes-kernel/linux/linux-machine-config.inc b/recipes-kernel/linux/linux-machine-config.inc
index 184011f4..6568e4b5 100644
--- a/recipes-kernel/linux/linux-machine-config.inc
+++ b/recipes-kernel/linux/linux-machine-config.inc
@@ -1,34 +1,71 @@
+#
+# This include file implements the MACHINE_DEVICETREE and MACHINE_KCONFIG
+# variable handling for the Kernel.
+#
+# e.g. (set in the associated <machine>.conf)
+# MACHINE_DEVICETREE := "zc702/zc702-zynq7.dts"
+# MACHINE_KCONFIG := "common/rtc.cfg"
+#
+# This will expand out to:
+# SRC_URI_append += "file://zc702/zc702-zynq7.dts file://common/rtc.cfg"
+# KERNEL_DEVICETREE ?= "${WORKDIR}/devicetree/zc702-zynq7.dts"
+#
+# This include also adds all the 'conf/machine/boards' for all layers (that are
+# available) to the FILESEXTRAPATHS.
+#
 
-# Scan all files in MACHINE_DEVICETREE and MACHINE_KCONFIG and populate SRC_URI,
-# FILESEXTRAPATHS and KERNEL_DEVICETREE.
-python __anonymous () {
+# Returns a space seperated list of all '.dts' files which 
+def get_all_devicetrees(d):
     workdir = d.getVar("WORKDIR", True)
     machine_devicetree = d.getVar("MACHINE_DEVICETREE", True) or ''
-    machine_kconfigs = d.getVar("MACHINE_KCONFIG", True) or ''
-    extrapaths = set()
-    sources = set()
     if machine_devicetree:
-        # linux-dtb.inc gets processed before this '__anonymous'
-        depends = d.getVar("DEPENDS", True)
-        d.setVar("DEPENDS", "%s dtc-native" % depends)
-        packages = d.getVar("PACKAGES", True)
-        d.setVar("PACKAGES", "%s kernel-devicetree" % packages)
-        
         files=set()
         for path in machine_devicetree.split():
-            sources.add("file://" + os.path.basename(path))
-            extrapaths.add(os.path.dirname(path))
-            if os.path.splitext(os.path.basename(path))[1] == '.dts':
-                files.add(os.path.join(workdir, os.path.basename(path)))
-        d.setVar("KERNEL_DEVICETREE", ' '.join(files))
-    if machine_kconfigs:
-        for path in machine_kconfigs.split():
-            files.add(os.path.join(workdir, os.path.basename(path)))
-            sources.add("file://" + os.path.basename(path))
-            extrapaths.add(os.path.dirname(path))
+            if os.path.splitext(path)[1] == '.dts':
+                files.add(os.path.join(workdir, "devicetree", os.path.basename(path)))
+        if len(files) != 0:
+            return ' '.join(files)
+    return ''
+
+# Retuns a ':' seperated list of expanded '${BBPATH}/$path'
+def get_additional_bbpath_filespath(path, d):
+    board_extrapaths = []
+    bbpath = d.getVar("BBPATH", True) or ""
+    for i in bbpath.split(":"):
+        board_extrapaths.append(os.path.join(i, path))
+    if len(board_extrapaths):
+        return ":".join(board_extrapaths) + ":"
+    return ""
+
+# If KERNEL_DEVICETREE is not set, default to the device tree's provided by
+# MACHINE_DEVICETREE
+KERNEL_DEVICETREE ?= "${@get_all_devicetrees(d)}"
+
+# Appends the '<layer>/conf/machine/boards' path to FILESEXTRAPATHS for all
+# layers (using the ${BBPATH})
+FILESEXTRAPATHS_append := "${@get_additional_bbpath_filespath('conf/machine/boards', d)}"
 
-    if len(extrapaths) != 0:
-        d.setVar("FILESEXTRAPATHS_append", ":".join(extrapaths) + ":")
+# Using the MACHINE_DEVICETREE and MACHINE_KCONFIG vars, append them to SRC_URI
+python () {
+    machine_devicetree = d.getVar("MACHINE_DEVICETREE", True) or ''
+    machine_kconfigs = d.getVar("MACHINE_KCONFIG", True) or ''
+    sources = set()
+    for path in (machine_devicetree.split() + machine_kconfigs.split()):
+        sources.add("file://" + path)
     if len(sources) != 0:
         d.setVar("SRC_URI_append", " %s " % " ".join(sources))
 }
+
+# Copy all device tree's into the same directory. This is due to compatibility
+# with dtc and the use of DTSI (Device Tree Includes), the version of DTC in
+# Yocto does not provide include path support.
+do_install_prepend() {
+        if test -n "${MACHINE_DEVICETREE}"; then
+                mkdir -p ${WORKDIR}/devicetree
+                for i in ${MACHINE_DEVICETREE}; do
+                        if test -e ${WORKDIR}/$i; then
+                                cp ${WORKDIR}/$i ${WORKDIR}/devicetree
+                        fi
+                done
+        fi
+}
diff --git a/recipes-kernel/linux/linux-xlnx.inc b/recipes-kernel/linux/linux-xlnx.inc
index b31d61bd..0065466d 100644
--- a/recipes-kernel/linux/linux-xlnx.inc
+++ b/recipes-kernel/linux/linux-xlnx.inc
@@ -18,8 +18,8 @@ COMPATIBLE_MACHINE = "qemumicroblaze|qemuzynq|microblaze|zynq"
 
 # Common kernel configuration parts
 # Arch specific kernel configuration parts
-SRC_URI_append_zynq += "file://zynq_defconfig_${LINUX_VERSION}.cfg"
-SRC_URI_append_microblaze += "file://microblaze_defconfig_${LINUX_VERSION}.cfg"
+MACHINE_KCONFIG_append_zynq += "common/zynq_defconfig_${LINUX_VERSION}.cfg"
+MACHINE_KCONFIG_append_microblaze += "common/microblaze_defconfig_${LINUX_VERSION}.cfg"
 
 # Add the modules directory to the 'kernel-base' files list
 FILES_kernel-base_append = " /lib/modules/${KERNEL_VERSION}/kernel"