1 files changed, 47 insertions, 0 deletions

diff --git a/recipes-extended/seabios/seabios_1.14.0.bb b/recipes-extended/seabios/seabios_1.14.0.bb
new file mode 100644
index 00000000..1591cb62
--- /dev/null
+++ b/recipes-extended/seabios/seabios_1.14.0.bb
@@ -0,0 +1,47 @@
+DESCRIPTION = "SeaBIOS"
+HOMEPAGE = "http://www.coreboot.org/SeaBIOS"
+LICENSE = "LGPLv3"
+SECTION = "firmware"
+
+inherit python3native
+
+SRC_URI = " \
+    https://www.seabios.org/downloads/seabios-${PV}.tar.gz \
+    file://hostcc.patch \
+    file://python3.patch \
+    "
+S = "${WORKDIR}/${PN}-${PV}"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504         \
+                    file://COPYING.LESSER;md5=6a6a8e020838b23406c81b19c1d46df6  \
+                    "
+
+SRC_URI[md5sum] = "9df3b7de6376850d09161137e7a9b61f"
+SRC_URI[sha256sum] = "eb70cc62b29aa83e10a653233acebf4bb154d00d0c87dc2a2c6e2da75e5e81fd"
+
+FILES_${PN} = "/usr/share/firmware"
+
+DEPENDS += "util-linux-native file-native bison-native flex-native gettext-native acpica-native"
+
+TUNE_CCARGS = ""
+EXTRA_OEMAKE += "HOSTCC='${BUILD_CC}'"
+EXTRA_OEMAKE += "CROSS_PREFIX=${TARGET_PREFIX}"
+
+COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
+
+do_configure() {
+    oe_runmake defconfig
+}
+
+do_compile() {
+    unset CPP
+    unset CPPFLAGS
+    oe_runmake
+}
+
+do_install() {
+    oe_runmake
+    install -d ${D}/usr/share/firmware
+    install -m 0644 out/bios.bin ${D}/usr/share/firmware/
+}
+