xen, xen-tools: update recipes for python3

Adds patches for packaged scripts to enable deployment with python3
where they have been ported to python 3 upstream.

setuptools3 inherits distutils3 which modifies ${B}, so cd ${S} is
needed in the do_configure, do_compile and do_install steps.

Remove python 2 dependency from the Xen recipes by adding a new
separate recipe, xen-python2, for packaging the remaining optional
scripts which are yet to be ported to python 3. Package naming in
the separate recipe is chosen to support transition back into the
xen-tools recipe if the scripts are ported later.

Use RSUGGESTS to support inclusion of the xen-python2 scripts in
images that include python 2.

Drop the remus package python dependency since the script was removed
in 2014: commit 5b66f84e37a45038f9e5dae7a5768a5525d1e6ba

Add python3 RDEPENDS needed to run xenmon.

Signed-off-by: Christopher Clark <christopher.clark6@baesystems.com>
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>

1 files changed, 68 insertions, 0 deletions

diff --git a/recipes-extended/xen/xen-python2.bb b/recipes-extended/xen/xen-python2.bb
new file mode 100644
index 00000000..08d8e92a
--- /dev/null
+++ b/recipes-extended/xen/xen-python2.bb
@@ -0,0 +1,68 @@
+SUMMARY = "Xen hypervisor tools written in python 2"
+DESCRIPTION = "Unported utility scripts for the Xen hypervisor"
+HOMEPAGE = "http://xen.org"
+LICENSE = "GPLv2"
+SECTION = "console/tools"
+
+SRCREV ?= "a5fcafbfbee55261853fba07149c1c795f2baf58"
+
+XEN_REL ?= "4.12"
+XEN_BRANCH ?= "stable-4.12"
+
+SRC_URI = "git://xenbits.xen.org/xen.git;branch=${XEN_BRANCH}"
+
+LIC_FILES_CHKSUM ?= "file://COPYING;md5=bbb4b1bdc2c3b6743da3c39d03249095"
+
+PV = "${XEN_REL}+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+# Packages in this recipe do not use ${PN} to allow for simpler
+# movement of the package back into the xen-tools recipe if/when
+# the scripts are ported to python 3.
+
+RDEPENDS_xen-tools-xencov-split ="python"
+RDEPENDS_xen-tools-xencons = "python"
+RDEPENDS_xen-tools-xenpvnetboot = "python"
+RDEPENDS_xen-tools-xentrace-format = "python"
+
+RRECOMMENDS_xen-tools-xencov-trace = "xen-tools-xencov"
+RRECOMMENDS_xen-tools-xentrace-format = "xen-tools-xentrace"
+
+PACKAGES = " \
+    xen-tools-xencons \
+    xen-tools-xencov-split \
+    xen-tools-xenpvnetboot \
+    xen-tools-xentrace-format \
+    "
+
+FILES_xen-tools-xencons = " \
+    ${bindir}/xencons \
+    "
+
+FILES_xen-tools-xencov-split = " \
+    ${bindir}/xencov_split \
+    "
+
+FILES_xen-tools-xenpvnetboot = " \
+    ${libdir}/xen/bin/xenpvnetboot \
+    "
+
+FILES_xen-tools-xentrace-format = " \
+    ${bindir}/xentrace_format \
+    "
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 ${S}/tools/xentrace/xentrace_format \
+                    ${D}${bindir}/xentrace_format
+    install -m 0755 ${S}/tools/misc/xencons ${D}${bindir}/xencons
+    install -m 0755 ${S}/tools/misc/xencov_split ${D}${bindir}/xencov_split
+
+    install -d ${D}${libdir}/xen/bin
+    install -m 0755 ${S}/tools/misc/xenpvnetboot \
+                    ${D}${libdir}/xen/bin/xenpvnetboot
+}