Rename all git bb recipes.

1 files changed, 47 insertions, 0 deletions

diff --git a/recipes-security/selinux/libselinux_git.bb b/recipes-security/selinux/libselinux_git.bb
new file mode 100644
index 0000000..8de51e0
--- /dev/null
+++ b/recipes-security/selinux/libselinux_git.bb
@@ -0,0 +1,47 @@
+SUMMARY = "SELinux library and simple utilities"
+DESCRIPTION = "libselinux provides an API for SELinux applications to get and set \
+process and file security contexts and to obtain security policy \
+decisions.  Required for any applications that use the SELinux API."
+SECTION = "base"
+PR = "r1"
+LICENSE = "NSA-Public_Domain"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=84b4d2c6ef954a2d4081e775a270d0d0"
+
+include selinux_git.inc
+inherit lib_package
+
+SRCREV = "339f8079d7b9dd1e0b0138e2d096dc7c60b2092e"
+S = "${WORKDIR}/git/libselinux"
+DEPENDS += "libsepol python python-native swig-native"
+
+PACKAGES += "${PN}-python"
+FILES_${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/selinux/*"
+FILES_${PN}-dbg += "${libdir}/python${PYTHON_BASEVERSION}/site-packages/selinux/.debug/*"
+
+python __anonymous () {
+        import re
+        target = d.getVar('TARGET_ARCH', True)
+        extra_oemake = d.getVar('EXTRA_OEMAKE', True)
+        p = re.compile('i.86')
+        target = p.sub('i386',target)
+        d.setVar("EXTRA_OEMAKE", extra_oemake + " ARCH='" + target + "'")
+}
+
+do_compile_append() {
+    oe_runmake pywrap -j1 \
+            INCLUDEDIR='${STAGING_INCDIR}' \
+            LIBDIR='${STAGING_LIBDIR}' \
+            PYLIBVER='python${PYTHON_BASEVERSION}' \
+            PYINC='-I${STAGING_INCDIR}/$(PYLIBVER)' \
+            PYLIB='-L${STAGING_LIBDIR}/$(PYLIBVER) -l$(PYLIBVER)' \
+            PYTHONLIBDIR='${PYLIB}'
+}
+
+do_install_append() {
+    oe_runmake install-pywrap swigify \
+            DESTDIR=${D} \
+            PYLIBVER='python${PYTHON_BASEVERSION}' \
+            PYLIBDIR='${D}/${libdir}/$(PYLIBVER)'
+}
+
+BBCLASSEXTEND = "native"