1 files changed, 40 insertions, 0 deletions

diff --git a/recipes-compliance/lynis/lynis_3.1.6.bb b/recipes-compliance/lynis/lynis_3.1.6.bb
new file mode 100644
index 0000000..722072f
--- /dev/null
+++ b/recipes-compliance/lynis/lynis_3.1.6.bb
@@ -0,0 +1,40 @@
+# Copyright (C) 2017 Armin Kuster  <akuster808@gmail.com>
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Lynis is a free and open source security and auditing tool."
+HOMEDIR = "https://cisofy.com/lynis/"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3edd6782854304fd11da4975ab9799c1"
+
+SRC_URI = "git://github.com/CISOfy/lynis.git;branch=master;protocol=https"
+
+SRCREV = "06153321ea50d53a27446084e646d9f43fe46e0e"
+
+#UPSTREAM_CHECK = "https://downloads.cisofy.com/lynis"
+
+inherit autotools-brokensep
+
+do_compile[noexec] = "1"
+do_configure[noexec] = "1"
+
+do_install () {
+        install -d ${D}/${bindir}
+        install -d ${D}/${sysconfdir}/lynis
+        install -m 555 ${S}/lynis ${D}/${bindir}
+
+        install -d ${D}/${datadir}/lynis/db
+        install -d ${D}/${datadir}/lynis/plugins
+        install -d ${D}/${datadir}/lynis/include
+        install -d ${D}/${datadir}/lynis/extras
+
+        cp -r ${S}/db/* ${D}/${datadir}/lynis/db/.
+        cp -r ${S}/plugins/*  ${D}/${datadir}/lynis/plugins/.
+        cp -r ${S}/include/* ${D}/${datadir}/lynis/include/.
+        cp -r ${S}/extras/*  ${D}/${datadir}/lynis/extras/.
+        cp ${S}/*.prf ${D}/${sysconfdir}/lynis
+}
+
+FILES:${PN} += "${sysconfdir}/developer.prf ${sysconfdir}/default.prf"
+FILES:${PN}-doc += "lynis.8 FAQ README CHANGELOG.md CONTRIBUTIONS.md CONTRIBUTORS.md" 
+
+RDEPENDS:${PN} += "procps findutils coreutils iproute2-ip iproute2-ss net-tools"