qtbase: install and split package fonts

- fonts were not installed (at least in qt 5.0.2) so install
them manually.
- split the font package in smaller package as done in qt4 to
save space on the target.
- use OE_QMAKE_PATH_LIBS which corresponds with:
  mkspecs/features/qpa/genericunixfontdatabase.prf:    fonts.path = $$[QT_INSTALL_LIBS]/fonts

Signed-off-by: Eric Bénard <eric@eukrea.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>

1 files changed, 30 insertions, 2 deletions

diff --git a/recipes-qt/qt5/qtbase.inc b/recipes-qt/qt5/qtbase.inc
index 0df3b2a6..2a5e3bc3 100644
--- a/recipes-qt/qt5/qtbase.inc
+++ b/recipes-qt/qt5/qtbase.inc
@@ -173,7 +173,35 @@ do_install_append() {
     # qemu built on host breaks do_package, remove it here (will be replaces with right qemu when do_compile is fixed
     # ERROR: objcopy failed with exit code 1 (cmd was 'arm-oe-linux-gnueabi-objcopy' --only-keep-debug '/OE/oe-core/tmp-eglibc/work/armv5te-oe-linux-gnueabi/qtbase/5.0.1-r0.0/package/usr/bin/qmake' '/OE/oe-core/tmp-eglibc/work/armv5te-oe-linux-gnueabi/qtbase/5.0.1-r0.0/package/usr/bin/.debug/qmake')
     rm -f ${D}/${bindir}/${QT_DIR_NAME}/qmake
+    # install fonts manually if they are missing
+    if [ ! -d ${D}/${OE_QMAKE_PATH_LIBS}/fonts ]; then
+        cp -a ${S}/lib/fonts ${D}/${OE_QMAKE_PATH_LIBS}
+    fi
 }
 
-PACKAGES =. "${PN}-fonts "
-FILES_${PN}-fonts = "${libdir}/${QT_DIR_NAME}/fonts ${libdir}/fonts"
+PACKAGES =. " \
+    ${PN}-fonts \
+    ${PN}-fonts-ttf-vera \
+    ${PN}-fonts-ttf-dejavu \
+    ${PN}-fonts-pfa \
+    ${PN}-fonts-pfb \
+    ${PN}-fonts-qpf \
+"
+
+RRECOMMENDS_${PN}-fonts = " \
+    ${PN}-fonts-ttf-vera \
+    ${PN}-fonts-ttf-dejavu \
+    ${PN}-fonts-pfa \
+    ${PN}-fonts-pfb \
+    ${PN}-fonts-qpf \
+"
+
+ALLOW_EMPTY_${PN}-fonts = "1"
+
+FILES_${PN}-fonts-ttf-vera       = "${OE_QMAKE_PATH_LIBS}/fonts/Vera*.ttf"
+FILES_${PN}-fonts-ttf-dejavu     = "${OE_QMAKE_PATH_LIBS}/fonts/DejaVu*.ttf"
+FILES_${PN}-fonts-pfa            = "${OE_QMAKE_PATH_LIBS}/fonts/*.pfa"
+FILES_${PN}-fonts-pfb            = "${OE_QMAKE_PATH_LIBS}/fonts/*.pfb"
+FILES_${PN}-fonts-qpf            = "${OE_QMAKE_PATH_LIBS}/fonts/*.qpf*"
+FILES_${PN}-fonts                = "${OE_QMAKE_PATH_LIBS}/fonts/README \
+                                    ${OE_QMAKE_PATH_LIBS}/fonts/fontdir"