DESCRIPTION = "SWIG - Simplified Wrapper and Interface Generator"
HOMEPAGE = "http://swig.sourceforge.net/"
LICENSE = "BSD & GPLv3"
LIC_FILES_CHKSUM = "file://LICENSE;md5=e7807a6282784a7dde4c846626b08fc6 \
                    file://LICENSE-GPL;md5=d32239bcb673463ab874e80d47fae504 \
                    file://LICENSE-UNIVERSITIES;md5=8ce9dcc8f7c994de4a408b205c72ba08"

SECTION = "devel"
INC_PR = "r3"

DEPENDS = "libpcre python"

SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}-${PV}.tar.gz"

inherit autotools pythonnative

EXTRA_OECONF = " \
	--with-python=${PYTHON} \
	--without-allegrocl \
	--without-android \
	--without-boost \
	--without-chicken \
	--without-clisp \
	--without-csharp \
	--without-d \
	--without-gcj \
	--without-go \
	--without-guile \
	--without-java \
	--without-lua \
	--without-mzscheme \
	--without-ocaml \
	--without-octave \
	--without-perl5 \
	--without-pike \
	--without-php \
	--without-python3 \
	--without-r \
	--without-ruby \
	--without-tcl \
"

BBCLASSEXTEND = "native"

do_configure() {
	install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/Tools/config
	install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/Tools/config
	install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
	install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
	oe_runconf
}

