From 5621e9d7a81bfa316d0a4230df21cc832e8f52cf Mon Sep 17 00:00:00 2001
From: zhengruoqin <zhengrq.fnst@fujitsu.com>
Date: Tue, 20 Sep 2022 10:30:55 +0800
Subject: python3-pyzmq: upgrade 23.2.1 -> 24.0.0

Signed-off-by: Zheng Ruoqin <zhengrq.fnst@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../python/python3-pyzmq_24.0.0.bb                 | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-pyzmq_24.0.0.bb

(limited to 'meta-python/recipes-devtools/python/python3-pyzmq_24.0.0.bb')

diff --git a/meta-python/recipes-devtools/python/python3-pyzmq_24.0.0.bb b/meta-python/recipes-devtools/python/python3-pyzmq_24.0.0.bb
new file mode 100644
index 0000000000..33e3ba6602
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pyzmq_24.0.0.bb
@@ -0,0 +1,55 @@
+SUMMARY = "PyZMQ: Python bindings for ZMQ"
+DESCRIPTION = "This package contains Python bindings for ZeroMQ. ZMQ is a lightweight and fast messaging implementation."
+HOMEPAGE = "http://zeromq.org/bindings:python"
+LICENSE = "BSD-3-Clause & LGPL-3.0-only"
+LIC_FILES_CHKSUM = "\
+    file://COPYING.BSD;md5=11c65680f637c3df7f58bbc8d133e96e \
+    file://COPYING.LESSER;md5=12c592fa0bcfff3fb0977b066e9cb69e \
+"
+
+DEPENDS = "python3-packaging-native zeromq"
+
+SRC_URI:append = " \
+    file://club-rpath-out.patch \
+    file://run-ptest \
+"
+SRC_URI[sha256sum] = "13b008bd142c9f6079ad75a30504eef2291502e9eac90e722b16fcf9ce856147"
+
+inherit pypi pkgconfig python_setuptools_build_meta ptest
+
+PACKAGES =+ "\
+    ${PN}-test \
+"
+
+FILES:${PN}-test += "\
+    ${libdir}/${PYTHON_DIR}/site-packages/*/tests \
+"
+
+RDEPENDS:${PN} += "\
+        ${PYTHON_PN}-json \
+        ${PYTHON_PN}-multiprocessing \
+"
+
+RDEPENDS:${PN}-ptest += "\
+        ${PN}-test \
+        ${PYTHON_PN}-pytest \
+"
+
+do_compile:prepend() {
+    echo [global] > ${S}/setup.cfg
+    echo zmq_prefix = ${STAGING_DIR_HOST} >> ${S}/setup.cfg
+    echo have_sys_un_h = True >> ${S}/setup.cfg
+    echo skip_check_zmq = True >> ${S}/setup.cfg
+    echo libzmq_extension = False >> ${S}/setup.cfg
+    echo no_libzmq_extension = True >> ${S}/setup.cfg
+}
+
+do_install:append() {
+        sed -i -e 's#${RECIPE_SYSROOT}##g' ${D}${PYTHON_SITEPACKAGES_DIR}/zmq/utils/config.json
+        sed -i -e 's#${RECIPE_SYSROOT}##g' ${D}${PYTHON_SITEPACKAGES_DIR}/zmq/utils/compiler.json
+}
+
+do_install_ptest() {
+        install -d ${D}${PTEST_PATH}/tests
+        cp -rf ${S}/zmq/tests/* ${D}${PTEST_PATH}/tests/
+}
-- 
cgit v1.2.3-54-g00ecf