From 21b28425177943e96f50e322fe97007ea9b3a160 Mon Sep 17 00:00:00 2001
From: Leon Anavi <leon.anavi@konsulko.com>
Date: Wed, 20 Jan 2021 13:10:27 +0200
Subject: python3-pyserial: Upgrade 3.4 -> 3.5

Upgrade to release 3.5:

- iAdd a backend for Silicon Labs CP2110/4 HID-to-UART bridge.
  (depends on hid module)
- Use absolute import everywhere
- win32: miniterm Working CMD.exe terminal using Windows 10 ANSI
  support
- Make ListPortInfo hashable
- threaded: "write" returns byte count
- Add bytesize and stopbits argument parser to tcp_serial_redirect
- loop: add out_waiting
- list_ports_linux: Correct "interface" property on Linux hosts
- Remove Python 3.2 and 3.3 from test
- doc updates
- miniterm: add CTRL+T Q as alternative to exit
- miniterm: suspend function key changed to CTRL-T Z
- add command line tool entries pyserial-miniterm (replaces
  miniterm.py) and pyserial-ports (runs serial.tools.list_ports).
- python -m serial opens miniterm (use w/o args and it will print
  port list too) [experimental]
- Don't open port if self.port is not set while entering context
  manager
- refactor: raise new instances for PortNotOpenError and
  SerialTimeoutException
- list_ports: set default name attribute
- fix: compare only of the same type in
  list_ports_common.ListPortInfo
- rfc2217/close(): fix race-condition
- return b'' when connection closes on rfc2217 connection
- rfc2217/close(): fix race condition
- Fixed flush_input_buffer() for situations where the remote end
  has closed the socket.
- reset_input_buffer() can hang on sockets
- examples: port_publisher python 3 fixes
- miniterm: Fix miniterm constructor exit_character and
  menu_character
- miniterm: use exclusive access for native serial ports by
  default
- miniterm: fix double use of CTRL-T + s use z for suspend instead
- examples: refactor wx example, use Bind to avoid deprecated
  warnings, IsChecked, unichr
- posix: fix PosixPollSerial with timeout=None and add cancel
  support
- option for low latency mode on linux
- Add support to xr-usb-serial ports
- posix: Don't catch the SerialException we just raised
- posix: Fix custom baud rate to not temporarily set 38400 baud
  rates on linux
- list_ports: use hardcoded path to library on osx

Following the rename of miniterm.py and the new command line tool
entry, task do_install_append has been updated accordingly.

License-Update: Update year

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Acked-by: Trevor Gamblin <trevor.gamblin@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../python/python3-pyserial_3.5.bb                 | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-pyserial_3.5.bb

(limited to 'meta-python/recipes-devtools/python/python3-pyserial_3.5.bb')

diff --git a/meta-python/recipes-devtools/python/python3-pyserial_3.5.bb b/meta-python/recipes-devtools/python/python3-pyserial_3.5.bb
new file mode 100644
index 0000000000..4be80e28cd
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pyserial_3.5.bb
@@ -0,0 +1,62 @@
+SUMMARY = "Serial Port Support for Python"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=520e45e59fc2cf94aa53850f46b86436"
+
+SRC_URI[sha256sum] = "3c77e014170dfffbd816e6ffc205e9842efb10be9f58ec16d3e8675b4925cddb"
+
+inherit pypi setuptools3 ptest
+
+do_install_append() {
+    rm -f ${D}${bindir}/pyserial-miniterm
+    rm -f ${D}${bindir}/pyserial-ports
+    rmdir ${D}${bindir}
+}
+
+PACKAGES =+ "${PN}-java ${PN}-osx ${PN}-win32 ${PN}-tools"
+
+FILES_${PN}-java = " \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/*java* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*java* \
+"
+
+FILES_${PN}-osx = " \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/*osx* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/*osx* \
+"
+
+FILES_${PN}-win32 = " \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/*serialcli* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*serialcli* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/*win32* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*win32* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/miniterm* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/miniterm* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/*windows* \
+    ${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/*windows* \
+"
+
+RDEPENDS_${PN} = "\
+    ${PYTHON_PN}-fcntl \
+    ${PYTHON_PN}-io \
+    ${PYTHON_PN}-logging \
+    ${PYTHON_PN}-netclient \
+    ${PYTHON_PN}-numbers \
+    ${PYTHON_PN}-shell \
+    ${PYTHON_PN}-stringold \
+    ${PYTHON_PN}-threading \
+"
+
+BBCLASSEXTEND = "native nativesdk"
+
+SRC_URI += " \
+	file://run-ptest \
+"
+
+RDEPENDS_${PN}-ptest += " \
+	${PYTHON_PN}-pytest \
+"
+
+do_install_ptest() {
+	install -d ${D}${PTEST_PATH}/test
+	cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
+}
-- 
cgit v1.2.3-54-g00ecf