From a7feabbc2115311226995f4d54b516f8bee0ccea Mon Sep 17 00:00:00 2001
From: Tom Geelen <t.f.g.geelen@gmail.com>
Date: Sat, 21 Dec 2024 22:57:01 +0000
Subject: python3-pillow: upgrade 10.4.0 -> 11.0.0

Signed-off-by: Tom Geelen <t.f.g.geelen@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../python/python3-pillow_11.0.0.bb                | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-pillow_11.0.0.bb

(limited to 'meta-python/recipes-devtools/python/python3-pillow_11.0.0.bb')

diff --git a/meta-python/recipes-devtools/python/python3-pillow_11.0.0.bb b/meta-python/recipes-devtools/python/python3-pillow_11.0.0.bb
new file mode 100644
index 0000000000..86e8dc6f6b
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-pillow_11.0.0.bb
@@ -0,0 +1,73 @@
+DESCRIPTION = "Python Imaging Library (Fork). Pillow is the friendly PIL fork by Alex \
+Clark and Contributors. PIL is the Python Imaging Library by Fredrik Lundh and \
+Contributors."
+HOMEPAGE = "https://pillow.readthedocs.io"
+LICENSE = "HPND"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c349a4b4b9ec2377a8fd6a7df87dbffe"
+
+SRC_URI = "git://github.com/python-pillow/Pillow.git;branch=main;protocol=https \
+           file://0001-support-cross-compiling.patch \
+           file://run-ptest \
+           "
+SRCREV = "204aae6682fc936f5350b3fe70335776f81480a7"
+
+inherit python_setuptools_build_meta ptest
+
+PEP517_BUILD_OPTS += " \
+    -C platform-guessing=disable \
+    -C zlib=enable \
+    -C jpeg=enable \
+    -C tiff=enable \
+    -C freetype=enable \
+    -C lcms=enable \
+    -C jpeg2000=enable \
+    -C webp=disable \
+    -C webpmux=disable \
+    -C imagequant=disable \
+"
+
+DEPENDS += " \
+    zlib \
+    jpeg \
+    tiff \
+    freetype \
+    lcms \
+    openjpeg \
+"
+
+RDEPENDS:${PN} += " \
+    python3-misc \
+    python3-logging \
+    python3-numbers \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxcb', '', d)} \
+"
+# python3-compile for filecmp module
+RDEPENDS:${PN}-ptest += " \
+    bash \
+    ghostscript \
+    jpeg-tools \
+    libwebp \
+    python3-compile \
+    python3-core \
+    python3-image \
+    python3-mmap \
+    python3-pytest \
+    python3-pytest-timeout \
+    python3-resource \
+    python3-unittest-automake-output \
+    python3-unixadmin\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'tk', '', d)} \
+"
+
+CVE_PRODUCT = "pillow"
+
+S = "${WORKDIR}/git"
+
+RPROVIDES:${PN} += "python3-imaging"
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/Tests
+    cp -rf ${S}/Tests ${D}${PTEST_PATH}/
+}
+
+BBCLASSEXTEND = "native"
-- 
cgit v1.2.3-54-g00ecf