From 58e071451f3083da7bbfe682a566b9bb48ac67be Mon Sep 17 00:00:00 2001
From: Wang Mingyu <wangmy@fujitsu.com>
Date: Thu, 9 Apr 2026 18:32:10 +0800
Subject: python3-orjson: upgrade 3.11.7 -> 3.11.8

Build and compatibility improvements.

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
---
 .../python/python3-orjson_3.11.8.bb                | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-orjson_3.11.8.bb

(limited to 'meta-python/recipes-devtools/python/python3-orjson_3.11.8.bb')

diff --git a/meta-python/recipes-devtools/python/python3-orjson_3.11.8.bb b/meta-python/recipes-devtools/python/python3-orjson_3.11.8.bb
new file mode 100644
index 0000000000..22a0205af3
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-orjson_3.11.8.bb
@@ -0,0 +1,46 @@
+SUMMARY = "orjson is a fast, correct JSON library for Python"
+HOMEPAGE = "https://pypi.org/project/orjson/"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
+
+SRCREV = "5cbb3d0398a2f42de51210270286fecd798c5d78"
+PYPI_SRC_URI = "git://github.com/ijl/orjson;protocol=https;branch=master;tag=${PV};destsuffix=orjson-${PV}"
+
+CVE_PRODUCT = "orjson"
+
+require ${BPN}-crates.inc
+
+inherit pypi python_maturin cargo-update-recipe-crates ptest-python-pytest
+
+SRC_URI += " \
+    file://0001-Guard-avx512-module-with-x86-target-cfg.patch \
+    file://0002-Guard-x86-feature-detection-macro-in-pystrref-object.patch \
+"
+DEPENDS = "python3-maturin-native"
+
+RDEPENDS:${PN} += "python3-maturin python3-mypy"
+
+do_compile:prepend() {
+    sed -i "/panic = \"abort\"/d" ${S}/Cargo.toml
+}
+
+do_install_ptest:append() {
+    install -d ${D}${PTEST_PATH}/data
+    cp -rf ${S}/data/* ${D}${PTEST_PATH}/data/
+    install -d ${D}${PTEST_PATH}/test
+    cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
+}
+
+RDEPENDS:${PN}-ptest += "\
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-faker \
+    python3-numpy \
+    python3-pandas \
+    python3-pendulum \
+    python3-psutil \
+    python3-pytz \
+    python3-tzdata \
+"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
cgit v1.2.3-54-g00ecf