From 67b858ec99655d6540a4ecc61242dbe5232f55fb Mon Sep 17 00:00:00 2001
From: Wang Mingyu <wangmy@fujitsu.com>
Date: Thu, 12 Mar 2026 18:51:59 +0800
Subject: python3-orjson: upgrade 3.11.6 -> 3.11.7

Changelog:
==============
- Use a faster library to serialize float. Users with byte-exact regression
  tests should note positive exponents are now written using a +, e.g.,
  1.2e+30 instead of 1.2e30. Both formats are spec-compliant.
- ABI compatibility with CPython 3.15 alpha 5 free-threading.

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
---
 .../python/python3-orjson_3.11.7.bb                | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-orjson_3.11.7.bb

(limited to 'meta-python/recipes-devtools/python/python3-orjson_3.11.7.bb')

diff --git a/meta-python/recipes-devtools/python/python3-orjson_3.11.7.bb b/meta-python/recipes-devtools/python/python3-orjson_3.11.7.bb
new file mode 100644
index 0000000000..63e2e089e1
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-orjson_3.11.7.bb
@@ -0,0 +1,46 @@
+SUMMARY = "orjson is a fast, correct JSON library for Python"
+HOMEPAGE = "https://pypi.org/project/orjson/"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE-MIT;md5=b377b220f43d747efdec40d69fcaa69d"
+
+SRCREV = "ec2b066cae79ae4a90ed126ac5723335dd99e408"
+PYPI_SRC_URI = "git://github.com/ijl/orjson;protocol=https;branch=master;tag=${PV};destsuffix=orjson-${PV}"
+
+CVE_PRODUCT = "orjson"
+
+require ${BPN}-crates.inc
+
+inherit pypi python_maturin cargo-update-recipe-crates ptest-python-pytest
+
+SRC_URI += " \
+    file://0001-Guard-avx512-module-with-x86-target-cfg.patch \
+    file://0002-Guard-x86-feature-detection-macro-in-pystrref-object.patch \
+"
+DEPENDS = "python3-maturin-native"
+
+RDEPENDS:${PN} += "python3-maturin python3-mypy"
+
+do_compile:prepend() {
+    sed -i "/panic = \"abort\"/d" ${S}/Cargo.toml
+}
+
+do_install_ptest:append() {
+    install -d ${D}${PTEST_PATH}/data
+    cp -rf ${S}/data/* ${D}${PTEST_PATH}/data/
+    install -d ${D}${PTEST_PATH}/test
+    cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
+}
+
+RDEPENDS:${PN}-ptest += "\
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-faker \
+    python3-numpy \
+    python3-pandas \
+    python3-pendulum \
+    python3-psutil \
+    python3-pytz \
+    python3-tzdata \
+"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
cgit v1.2.3-54-g00ecf