From 440ccdf152c846572bf2b7636177181a9134a83f Mon Sep 17 00:00:00 2001
From: Martin Jansa <Martin.Jansa@gmail.com>
Date: Mon, 2 Jun 2014 12:19:49 +0200
Subject: luajit: upgrade to 2.0.3, add native support

* http://luajit.org/changes.html says:
  This release has the new PS4 port and various important bugfixes over
  2.0.2 - an update is recommended.
* add native support (used by efl-native)
* drop lua dependency, it doesn't need lua to be built before luajit
* LIC_FILES_CHKSUM change is only from copyright year update
  < Copyright (C) 2005-2013 Mike Pall. All rights reserved.
  ---
  > Copyright (C) 2005-2014 Mike Pall. All rights reserved.

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-devtools/luajit/luajit_2.0.2.bb | 54 ------------------------
 meta-oe/recipes-devtools/luajit/luajit_2.0.3.bb | 55 +++++++++++++++++++++++++
 2 files changed, 55 insertions(+), 54 deletions(-)
 delete mode 100644 meta-oe/recipes-devtools/luajit/luajit_2.0.2.bb
 create mode 100644 meta-oe/recipes-devtools/luajit/luajit_2.0.3.bb

(limited to 'meta-oe/recipes-devtools')

diff --git a/meta-oe/recipes-devtools/luajit/luajit_2.0.2.bb b/meta-oe/recipes-devtools/luajit/luajit_2.0.2.bb
deleted file mode 100644
index b719b48e09..0000000000
--- a/meta-oe/recipes-devtools/luajit/luajit_2.0.2.bb
+++ /dev/null
@@ -1,54 +0,0 @@
-SUMMARY = "Just-In-Time Compiler for Lua"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=1793ef52a5d577794cd886a501a7f861"
-HOMEPAGE = "http://luajit.org"
-
-DEPENDS += "lua5.1"
-SRC_URI = "http://luajit.org/download/LuaJIT-${PV}.tar.gz;name=tarball \
-           file://0001-Do-not-strip-automatically-this-leaves-the-stripping.patch \
-          "
-SRC_URI[tarball.md5sum] = "112dfb82548b03377fbefbba2e0e3a5b"
-SRC_URI[tarball.sha256sum] = "c05202974a5890e777b181908ac237625b499aece026654d7cc33607e3f46c38"
-
-SRC_URI_append_fslmachine = " file://ppc-fixplt.patch "
-
-S = "${WORKDIR}/LuaJIT-${PV}"
-
-inherit pkgconfig binconfig
-
-do_configure_prepend() {
-    sed -i -e s:/usr/local:${prefix}:g ${S}/Makefile
-    sed -i -e s:/lib$:${base_libdir}:g ${S}/Makefile
-}
-
-EXTRA_OEMAKE = 'CROSS=${HOST_PREFIX} TARGET_CFLAGS="${TOOLCHAIN_OPTIONS}" TARGET_LDFLAGS="${TOOLCHAIN_OPTIONS}" TARGET_SHLDFLAGS="${TOOLCHAIN_OPTIONS}"'
-EXTRA_OEMAKE_append_powerpc = ' HOST_CC="${BUILD_CC} -m32"'
-EXTRA_OEMAKE_append_x86-64 = ' HOST_CC="${BUILD_CC}"'
-EXTRA_OEMAKE_append_i586 = ' HOST_CC="${BUILD_CC} -m32"'
-EXTRA_OEMAKE_append_powerpc64 = ' HOST_CC="${BUILD_CC}"'
-EXTRA_OEMAKE_append_arm = ' HOST_CC="${BUILD_CC} -m32"'
-EXTRA_OEMAKE_append_mips64 = ' HOST_CC="${BUILD_CC} -m32"'
-
-do_compile () {
-    oe_runmake
-}
-
-do_install () {
-    oe_runmake 'DESTDIR=${D}' install
-    rmdir ${D}${datadir}/lua/5.1 \
-          ${D}${datadir}/lua \
-          ${D}${libdir}/lua/5.1 \
-          ${D}${libdir}/lua
-}
-
-PACKAGES += 'luajit-common'
-
-FILES_${PN} += "${libdir}/libluajit-5.1.so.2 \
-    ${libdir}/libluajit-5.1.so.${PV} \
-"
-FILES_${PN}-dev += "${libdir}/libluajit-5.1.a \
-    ${libdir}/libluajit-5.1.so \
-    ${libdir}/pkgconfig/luajit.pc \
-"
-FILES_luajit-common = "${datadir}/${BPN}-${PV}"
-
diff --git a/meta-oe/recipes-devtools/luajit/luajit_2.0.3.bb b/meta-oe/recipes-devtools/luajit/luajit_2.0.3.bb
new file mode 100644
index 0000000000..de3a40bbca
--- /dev/null
+++ b/meta-oe/recipes-devtools/luajit/luajit_2.0.3.bb
@@ -0,0 +1,55 @@
+SUMMARY = "Just-In-Time Compiler for Lua"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=97b6446bbf9d55616838f821585c5978"
+HOMEPAGE = "http://luajit.org"
+
+SRC_URI = "http://luajit.org/download/LuaJIT-${PV}.tar.gz \
+           file://0001-Do-not-strip-automatically-this-leaves-the-stripping.patch \
+"
+SRC_URI[md5sum] = "f14e9104be513913810cd59c8c658dc0"
+SRC_URI[sha256sum] = "55be6cb2d101ed38acca32c5b1f99ae345904b365b642203194c585d27bebd79"
+
+SRC_URI_append_fslmachine = " file://ppc-fixplt.patch "
+
+S = "${WORKDIR}/LuaJIT-${PV}"
+
+inherit pkgconfig binconfig
+
+BBCLASSEXTEND = "native"
+
+do_configure_prepend() {
+    sed -i -e s:/usr/local:${prefix}:g ${S}/Makefile
+    sed -i -e s:/lib$:${base_libdir}:g ${S}/Makefile
+}
+
+EXTRA_OEMAKE = 'CROSS=${HOST_PREFIX} TARGET_CFLAGS="${TOOLCHAIN_OPTIONS}" TARGET_LDFLAGS="${TOOLCHAIN_OPTIONS}" TARGET_SHLDFLAGS="${TOOLCHAIN_OPTIONS}"'
+EXTRA_OEMAKE_append_powerpc = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_x86-64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_i586 = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_powerpc64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_arm = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_mips64 = ' HOST_CC="${BUILD_CC} -m32"'
+
+do_compile () {
+    oe_runmake
+}
+
+do_install () {
+    oe_runmake 'DESTDIR=${D}' install
+    rmdir ${D}${datadir}/lua/5.* \
+          ${D}${datadir}/lua \
+          ${D}${libdir}/lua/5.* \
+          ${D}${libdir}/lua
+}
+
+PACKAGES += 'luajit-common'
+
+FILES_${PN} += "${libdir}/libluajit-5.1.so.2 \
+    ${libdir}/libluajit-5.1.so.${PV} \
+"
+FILES_${PN}-dev += "${libdir}/libluajit-5.1.a \
+    ${libdir}/libluajit-5.1.so \
+    ${libdir}/pkgconfig/luajit.pc \
+"
+FILES_luajit-common = "${datadir}/${BPN}-${PV}"
+
-- 
cgit v1.2.3-54-g00ecf