python3-pywbem: Upgrade 0.15.0 -> 0.17.2

Upgrade to release 0.17.2:

- Test: Fixed virtualenv related failures during install test.
- Dev: Increased the versions of the base packages ‘pip’,
  ‘setuptools’ and ‘wheel’ to the content of Ubuntu 18.04 as
  a minimum, and to the lowest versions that support a particular
  Python versions beyond that. This only affects development of
  pywbem.
- Setup: Added the scripts for installing OS-level dependencies
  (pywbem_os_setup.sh/.bat) to the source distribution archive.
  Note that starting with the upcoming pywbem 1.0.0, these scripts
  are no longer needed, so this change will not be rolled forward
  into 1.0.0.
- Increased the version of ‘PyYAML’ from 5.1 to 5.3 on Python 2.7,
  to pick up a fix for dealing with Unicode characters above U+FFFF
  in narrow Python builds. This could not be fixed for Python 2.6
  since PyYAML 3.12 dropped support for Python 2.6
- Fixed raise error for invalid reference_direction in
  WBEMServer.get_central_instances().
- Fixed raise error for missing ports in WBEMListener.__init__().

Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
Acked-by: Trevor Gamblin <trevor.gamblin@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 56 insertions, 0 deletions

diff --git a/meta-python/recipes-extended/pywbem/python3-pywbem_0.17.2.bb b/meta-python/recipes-extended/pywbem/python3-pywbem_0.17.2.bb
new file mode 100644
index 0000000000..ce63822b47
--- /dev/null
+++ b/meta-python/recipes-extended/pywbem/python3-pywbem_0.17.2.bb
@@ -0,0 +1,56 @@
+SUMMARY = "Python WBEM Client and Provider Interface"
+DESCRIPTION = "\
+A Python library for making CIM (Common Information Model) operations over \
+HTTP using the WBEM CIM-XML protocol. It is based on the idea that a good \
+WBEM client should be easy to use and not necessarily require a large amount \
+of programming knowledge. It is suitable for a large range of tasks from \
+simply poking around to writing web and GUI applications. \
+\
+WBEM, or Web Based Enterprise Management is a manageability protocol, like \
+SNMP, standardised by the Distributed Management Task Force (DMTF) available \
+at http://www.dmtf.org/standards/wbem. \
+\
+It also provides a Python provider interface, and is the fastest and easiest \
+way to write providers on the planet."
+HOMEPAGE = "http://pywbem.github.io"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=fbc093901857fcd118f065f900982c24"
+
+SRC_URI[md5sum] = "6100157c720ba272895b3f79a05c8dc3"
+SRC_URI[sha256sum] = "84dac33f77d5ff2c3d8eb42fc7de2ffb6d33f5e4954ef89db0dbf3fe646a2809"
+
+inherit pypi setuptools3 update-alternatives
+
+DEPENDS += " \
+    ${PYTHON_PN}-ply-native \
+    ${PYTHON_PN}-pyyaml-native \
+    ${PYTHON_PN}-six-native \
+"
+
+do_install_append() {
+    mv ${D}${bindir}/wbemcli.py ${D}${bindir}/pywbemcli
+
+    rm -f ${D}${bindir}/*.bat
+}
+
+RDEPENDS_${PN}_class-target += "\
+    ${PYTHON_PN}-datetime \
+    ${PYTHON_PN}-io \
+    ${PYTHON_PN}-netclient \
+    ${PYTHON_PN}-ply \
+    ${PYTHON_PN}-pyyaml \
+    ${PYTHON_PN}-six \
+    ${PYTHON_PN}-stringold \
+    ${PYTHON_PN}-threading \
+    ${PYTHON_PN}-unixadmin \
+    ${PYTHON_PN}-xml \
+"
+
+ALTERNATIVE_${PN} = "mof_compiler pywbemcli wbemcli"
+ALTERNATIVE_TARGET[mof_compiler] = "${bindir}/mof_compiler"
+ALTERNATIVE_TARGET[pywbemcli] = "${bindir}/pywbemcli"
+ALTERNATIVE_TARGET[wbemcli] = "${bindir}/wbemcli"
+
+ALTERNATIVE_PRIORITY = "60"
+
+BBCLASSEXTEND = "native"