python3-tblib: add recipe

Serialization library for Exceptions and Tracebacks.

It is a runtime dependency for python3-django ptests.

The ptests for this recipe run under a second.

Sample output:

root@qemux86-64:~# ptest-runner
START: ptest-runner
2026-01-15T19:37
BEGIN: /usr/lib/python3-tblib/ptest
PASS: tests/test_issue30.py:test_30
PASS: tests/test_issue65.py:test_65
PASS: tests/test_perf.py:test_perf
[...many passing lines...]
PASS: tests/test_tblib.py:test_parse_traceback
PASS: tests/test_tblib.py:test_large_line_number
PASS: tests/test_tblib.py:test_pytest_integration
============================================================================
Testsuite summary
DURATION: 1
END: /usr/lib/python3-tblib/ptest
2026-01-15T19:37
STOP: ptest-runner
TOTAL: 1 FAIL: 0

Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 22 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-tblib_3.2.2.bb b/meta-python/recipes-devtools/python/python3-tblib_3.2.2.bb
new file mode 100644
index 0000000000..ae3ba730c5
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-tblib_3.2.2.bb
@@ -0,0 +1,22 @@
+SUMMARY = "Serialization library for Exceptions and Tracebacks."
+HOMEPAGE = "https://github.com/ionelmc/python-tblib"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=810c4c43873f8d9331fb067a6473a960"
+
+inherit pypi python_setuptools_build_meta ptest-python-pytest
+
+SRC_URI[sha256sum] = "e9a652692d91bf4f743d4a15bc174c0b76afc750fe8c7b6d195cc1c1d6d2ccec"
+
+do_install_ptest:append(){
+    install -m 0644 ${S}/pytest.ini ${D}${PTEST_PATH}
+    # The tests are comparing exception outputs with expected ones, and it doesn't
+    # expect carets in the exception.
+    sed -i 's/pytest/PYTHONNODEBUGRANGES=1 pytest/' ${D}${PTEST_PATH}/run-ptest
+}
+
+RDEPENDS:${PN}-ptest += " \
+    python3-misc \
+    python3-pytest-benchmark \
+    python3-statistics \
+    python3-twisted \
+"