python3-rapidjson: upgrade 1.11 -> 1.12

Changelog:
 Generate wheels on PyPI using final Python 3.12 release, thanks to cibuildwheel 2.16.2

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 41 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-rapidjson_1.12.bb b/meta-python/recipes-devtools/python/python3-rapidjson_1.12.bb
new file mode 100644
index 0000000000..f0f6c0dbac
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-rapidjson_1.12.bb
@@ -0,0 +1,41 @@
+SUMMARY = "Python wrapper around rapidjson"
+HOMEPAGE = "https://github.com/python-rapidjson/python-rapidjson"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4daf3929156304df67003c33274a98bd"
+
+SRC_URI = "git://github.com/python-rapidjson/python-rapidjson.git;protocol=https;branch=master"
+SRCREV = "5063cc63008b41e129344b012fc59b114cacd5c9"
+
+S = "${WORKDIR}/git"
+
+# Inheriting ptest provides functionality for packaging and installing runtime tests for this recipe
+inherit setuptools3 ptest
+
+SETUPTOOLS_BUILD_ARGS += " --rj-include-dir=${RECIPE_SYSROOT}${includedir}"
+
+# run-ptest is a shell script that starts the test suite
+SRC_URI += " \
+    file://run-ptest \
+"
+
+DEPENDS += " \
+    rapidjson \
+"
+
+# Adding required python package for the ptest (pytest and pytest->automake report translation)
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-unittest-automake-output \
+    ${PYTHON_PN}-pytz \
+"
+
+RDEPENDS:${PN} += " \
+    ${PYTHON_PN}-core \
+"
+
+# Installing the test suite on the target
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}