python3-gevent: upgrade 22.10.2 -> 23.7.0

Changelog:
============
Features
----------
-Add preliminary support for Python 3.12, using greenlet 3.0a1.
-Update the bundled c-ares version to 1.19.1.

Bugfixes
------------
-Fix an edge case connecting a non-blocking SSLSocket that could result in an AttributeError.
-Make gevent's FileObjectThread (mostly used on Windows) implement readinto cooperatively.
-Work around an AttributeError during cyclic garbage collection when Python finalizers (__del__ and the like) attempt to use gevent APIs.

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

1 files changed, 35 insertions, 0 deletions

diff --git a/meta-python/recipes-devtools/python/python3-gevent_23.7.0.bb b/meta-python/recipes-devtools/python/python3-gevent_23.7.0.bb
new file mode 100644
index 0000000000..a82abcc096
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-gevent_23.7.0.bb
@@ -0,0 +1,35 @@
+SUMMARY = "A coroutine-based Python networking library"
+DESCRIPTION = "gevent is a coroutine-based Python networking library that uses greenlet to provide \
+a high-level synchronous API on top of the libevent event loop."
+HOMEPAGE = "http://www.gevent.org"
+LICENSE = "MIT & Python-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=4de99aac27b470c29c6c309e0c279b65"
+DEPENDS += "${PYTHON_PN}-greenlet libev libuv c-ares python3-cython-native"
+
+RDEPENDS:${PN} = "${PYTHON_PN}-greenlet \
+                  ${PYTHON_PN}-mime \
+                  ${PYTHON_PN}-pprint \
+                 "
+
+SRC_URI += "file://0001-_setuputils.py-Do-not-add-sys_inc_dir.patch"
+
+SRC_URI[sha256sum] = "d0d3630674c1b344b256a298ab1ff43220f840b12af768131b5d74e485924237"
+
+inherit pypi setuptools3
+
+# Don't embed libraries, link to the system provided libs instead
+export GEVENTSETUP_EMBED_CARES = "0"
+export GEVENTSETUP_EMBED_LIBEV = "0"
+export GEVENTSETUP_EMBED_LIBUV = "0"
+
+do_configure:append() {
+        # Delete the embedded copies of libraries so we can't accidentally link to them
+        rm -rf ${S}/deps
+
+        # Delete the generated cython files, as they are all out of date with python 3.11
+        rm -rf ${S}/src/gevent/*.c
+}
+
+do_compile:append() {
+        sed -i -e 's#${WORKDIR}##g' ${S}/src/gevent/*.c ${S}/src/gevent/libev/*.c ${S}/src/gevent/resolver/*.c
+}