summaryrefslogtreecommitdiffstats
path: root/meta-networking/recipes-connectivity/samba/samba_4.4.5.bb
diff options
context:
space:
mode:
authorJackie Huang <jackie.huang@windriver.com>2016-08-15 13:45:14 +0800
committerJoe MacDonald <joe_macdonald@mentor.com>2016-08-16 21:26:12 -0400
commit35326fa74dee53ffa4bd454e5fc95fdcbf0d5da6 (patch)
tree891a2c80bf0ea3ee4bb7dac92b3997f177bc4c0d /meta-networking/recipes-connectivity/samba/samba_4.4.5.bb
parent6555c34fd3a392d72983d3d2ae6464e32fe44fa0 (diff)
downloadmeta-openembedded-35326fa74dee53ffa4bd454e5fc95fdcbf0d5da6.tar.gz
samba: upgrade to 4.4.5
* This is a security release in order to address the following defect: - CVE-2016-2119 (Client side SMB2/3 required signing can be downgraded) * Detail release note: - https://www.samba.org/samba/history/samba-4.4.5.html * Removed part of the 10-use-only-libsystemd.patch which has been fixed in new version. Signed-off-by: Jackie Huang <jackie.huang@windriver.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
Diffstat (limited to 'meta-networking/recipes-connectivity/samba/samba_4.4.5.bb')
-rw-r--r--meta-networking/recipes-connectivity/samba/samba_4.4.5.bb319
1 files changed, 319 insertions, 0 deletions
diff --git a/meta-networking/recipes-connectivity/samba/samba_4.4.5.bb b/meta-networking/recipes-connectivity/samba/samba_4.4.5.bb
new file mode 100644
index 0000000000..e35d527f8a
--- /dev/null
+++ b/meta-networking/recipes-connectivity/samba/samba_4.4.5.bb
@@ -0,0 +1,319 @@
1SECTION = "console/network"
2
3LICENSE = "GPL-3.0+ & LGPL-3.0+ & GPL-2.0+"
4LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
5 file://${COREBASE}/meta/files/common-licenses/LGPL-3.0;md5=bfccfe952269fff2b407dd11f2f3083b \
6 file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6 "
7
8SAMBA_MIRROR = "http://samba.org/samba/ftp"
9MIRRORS += "\
10${SAMBA_MIRROR} http://mirror.internode.on.net/pub/samba \n \
11${SAMBA_MIRROR} http://www.mirrorservice.org/sites/ftp.samba.org \n \
12"
13
14SRC_URI = "${SAMBA_MIRROR}/stable/samba-${PV}.tar.gz \
15 file://00-fix-typos-in-man-pages.patch \
16 file://10-use-only-libsystemd.patch \
17 file://16-do-not-check-xsltproc-manpages.patch \
18 file://20-do-not-import-target-module-while-cross-compile.patch \
19 file://21-add-config-option-without-valgrind.patch \
20 file://0006-avoid-using-colon-in-the-checking-msg.patch \
21 file://volatiles.03_samba \
22 "
23
24SRC_URI[md5sum] = "6950c5e9f7bdeb8a610c2ca957a15be4"
25SRC_URI[sha256sum] = "b876ef2e63f66265490e80a122e66ef2d7616112b839df68f56ac2e1ce17a7bd"
26
27inherit systemd waf-samba cpan-base perlnative update-rc.d
28# remove default added RDEPENDS on perl
29RDEPENDS_${PN}_remove = "perl"
30
31DEPENDS += "readline virtual/libiconv zlib popt libtalloc libtdb libtevent libldb krb5 libbsd libaio"
32
33SYSVINITTYPE_linuxstdbase = "lsb"
34SYSVINITTYPE = "sysv"
35
36INITSCRIPT_NAME = "samba.sh"
37INITSCRIPT_PARAMS = "start 20 3 5 . stop 20 0 1 6 ."
38
39PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)} \
40 ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', '${SYSVINITTYPE}', '', d)} \
41 ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
42 ${@bb.utils.contains('DISTRO_FEATURES', 'zeroconf', 'zeroconf', '', d)} \
43 acl cups ldap \
44"
45
46RDEPENDS_${PN}-base += "${@bb.utils.contains('PACKAGECONFIG', 'lsb', 'lsb', '', d)}"
47RDEPENDS_${PN}-ctdb-tests += "bash"
48
49PACKAGECONFIG[acl] = "--with-acl-support,--without-acl-support,acl"
50PACKAGECONFIG[fam] = "--with-fam,--without-fam,gamin"
51PACKAGECONFIG[pam] = "--with-pam --with-pammodulesdir=${base_libdir}/security,--without-pam,libpam"
52PACKAGECONFIG[lsb] = ",,lsb"
53PACKAGECONFIG[sysv] = ",,sysvinit"
54PACKAGECONFIG[cups] = "--enable-cups,--disable-cups,cups"
55PACKAGECONFIG[ldap] = "--with-ldap,--without-ldap,openldap"
56PACKAGECONFIG[sasl] = ",,cyrus-sasl"
57PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd"
58PACKAGECONFIG[dmapi] = "--with-dmapi,--without-dmapi,dmapi"
59PACKAGECONFIG[zeroconf] = "--enable-avahi,--disable-avahi,avahi"
60PACKAGECONFIG[valgrind] = ",--without-valgrind,valgrind,"
61PACKAGECONFIG[lttng] = "--with-lttng, --without-lttng,lttng-ust"
62PACKAGECONFIG[archive] = "--with-libarchive, --without-libarchive, libarchive"
63
64
65SAMBA4_IDMAP_MODULES="idmap_ad,idmap_rid,idmap_adex,idmap_hash,idmap_tdb2"
66SAMBA4_PDB_MODULES="pdb_tdbsam,${@bb.utils.contains('PACKAGECONFIG', 'ldap', 'pdb_ldap,', '', d)}pdb_ads,pdb_smbpasswd,pdb_wbc_sam,pdb_samba4"
67SAMBA4_AUTH_MODULES="auth_unix,auth_wbc,auth_server,auth_netlogond,auth_script,auth_samba4"
68SAMBA4_MODULES="${SAMBA4_IDMAP_MODULES},${SAMBA4_PDB_MODULES},${SAMBA4_AUTH_MODULES}"
69
70SAMBA4_LIBS="heimdal,!zlib,!popt,!talloc,!pytalloc,!pytalloc-util,!tevent,!pytevent,!tdb,!pytdb,!ldb,!pyldb"
71
72EXTRA_OECONF += "--enable-fhs \
73 --with-piddir=/run \
74 --with-sockets-dir=/run/samba \
75 --with-modulesdir=${libdir}/samba \
76 --with-lockdir=${localstatedir}/lib/samba \
77 --with-cachedir=${localstatedir}/lib/samba \
78 --disable-gnutls \
79 --disable-rpath-install \
80 --with-shared-modules=${SAMBA4_MODULES} \
81 --bundled-libraries=${SAMBA4_LIBS} \
82 --with-system-mitkrb5 \
83 --without-ad-dc \
84 ${@base_conditional('TARGET_ARCH', 'x86_64', '', '--disable-glusterfs', d)} \
85 --with-cluster-support \
86 --with-profiling-data \
87 --with-libiconv=${STAGING_DIR_HOST}${prefix} \
88 "
89DISABLE_STATIC = ""
90
91LDFLAGS += "-Wl,-z,relro,-z,now"
92
93do_install_append() {
94 if ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'true', 'false', d)}; then
95 install -d ${D}${systemd_unitdir}/system
96 for i in nmb smb winbind; do
97 install -m 0644 packaging/systemd/$i.service ${D}${systemd_unitdir}/system
98 done
99 sed -i 's,\(ExecReload=\).*\(/kill\),\1${base_bindir}\2,' ${D}${systemd_unitdir}/system/*.service
100
101 install -d ${D}${sysconfdir}/tmpfiles.d
102 install -m644 packaging/systemd/samba.conf.tmp ${D}${sysconfdir}/tmpfiles.d/samba.conf
103 echo "d ${localstatedir}/log/samba 0755 root root -" \
104 >> ${D}${sysconfdir}/tmpfiles.d/samba.conf
105 elif ${@bb.utils.contains('PACKAGECONFIG', 'lsb', 'true', 'false', d)}; then
106 install -d ${D}${sysconfdir}/init.d
107 install -m 0755 packaging/LSB/samba.sh ${D}${sysconfdir}/init.d
108 elif ${@bb.utils.contains('PACKAGECONFIG', 'sysv', 'true', 'false', d)}; then
109 install -d ${D}${sysconfdir}/init.d
110 install -m 0755 packaging/sysv/samba.init ${D}${sysconfdir}/init.d/samba.sh
111 sed -e 's,/opt/samba/bin,${sbindir},g' \
112 -e 's,/opt/samba/smb.conf,${sysconfdir}/samba/smb.conf,g' \
113 -e 's,/opt/samba/log,${localstatedir}/log/samba,g' \
114 -e 's,/etc/init.d/samba.server,${sysconfdir}/init.d/samba.sh,g' \
115 -i ${D}${sysconfdir}/init.d/samba.sh
116 fi
117
118 install -d ${D}${sysconfdir}/samba
119 echo "127.0.0.1 localhost" > ${D}${sysconfdir}/samba/lmhosts
120 install -m644 packaging/LSB/smb.conf ${D}${sysconfdir}/samba/smb.conf
121 install -D -m 644 ${WORKDIR}/volatiles.03_samba ${D}${sysconfdir}/default/volatiles/03_samba
122
123 install -d ${D}${sysconfdir}/sysconfig/
124 install -m644 packaging/systemd/samba.sysconfig ${D}${sysconfdir}/sysconfig/samba
125
126 rm -rf ${D}/run ${D}${localstatedir}/run ${D}${localstatedir}/log
127}
128
129PACKAGES += "${PN}-python ${PN}-python-dbg ${PN}-pidl libwinbind libwinbind-dbg libwinbind-krb5-locator"
130PACKAGES =+ "libwbclient libnss-winbind winbind winbind-dbg libnetapi libsmbsharemodes \
131 libsmbclient libsmbclient-dev lib${PN}-base ${PN}-base ${PN}-ctdb-tests"
132
133RDEPENDS_${PN} += "${PN}-base"
134
135FILES_${PN}-base = "${sbindir}/nmbd \
136 ${sbindir}/smbd \
137 ${sysconfdir}/init.d \
138 ${localstatedir}/lib/samba \
139 ${localstatedir}/nmbd \
140 ${localstatedir}/spool/samba \
141"
142
143FILES_${PN}-ctdb-tests = "${bindir}/ctdb_run_tests \
144 ${libdir}/ctdb-tests \
145 ${datadir}/ctdb-tests \
146 /run/ctdb \
147 "
148
149# figured out by
150# FILES="tmp/work/cortexa9hf-vfp-neon-poky-linux-gnueabi/samba/4.1.12-r0/image/usr/sbin/smbd tmp/work/cortexa9hf-vfp-neon-poky-linux-gnueabi/samba/4.1.12-r0/image/usr/sbin/nmbd"
151#
152# while [ "${FILES}" != "${OLDFILES}" ]
153# do
154# OLDFILES="${FILES}"
155# NEEDED=`tmp/sysroots/x86_64-linux/usr/libexec/arm-poky-linux-gnueabi.gcc-cross-initial-arm/gcc/arm-poky-linux-gnueabi/5.2.0/objdump -x ${FILES} | grep NEEDED | egrep -E 'so(.[0-9]|$)' | sort -u | perl -MData::Dumper -le 'while (<>) {chomp; push @lib, (split)[1]}; print "(", join("|", @lib), ")"'`
156# NF=`find tmp/work/cortexa9hf-vfp-neon-poky-linux-gnueabi/samba/4.1.12-r0/image/usr/lib -type f | egrep "${NEEDED}" | sort -u`
157#
158# FILES=`perl -le 'foreach (@ARGV) { $f{$_}++ }; print join(" ", sort keys %f)' ${FILES} ${NF}`
159# done
160#
161# LIBS=`echo ${FILES} | sed -e 's,tmp/work/cortexa9hf-vfp-neon-poky-linux-gnueabi/samba/4.1.12-r0/image/usr/lib,${libdir},g' -e 's,.so.[0-9]+.*$,.so.*,g'`
162# for l in ${LIBS}
163# do
164# echo $l
165# done
166
167FILES_lib${PN}-base = "\
168 ${sysconfdir}/default \
169 ${sysconfdir}/samba \
170 ${libdir}/libdcerpc-binding.so.* \
171 ${libdir}/libgensec.so.* \
172 ${libdir}/libndr-krb5pac.so.* \
173 ${libdir}/libndr-nbt.so.* \
174 ${libdir}/libndr-standard.so.* \
175 ${libdir}/libndr.so.* \
176 ${libdir}/libnetapi.so.* \
177 ${libdir}/libpdb.so.* \
178 ${libdir}/libsamba-credentials.so.* \
179 ${libdir}/libsamba-hostconfig.so.* \
180 ${libdir}/libsamba-util.so.* \
181 ${libdir}/libsamdb.so.* \
182 ${libdir}/libsmbconf.so.* \
183 ${libdir}/libtevent-util.so.* \
184 ${libdir}/samba/libCHARSET3.so \
185 ${libdir}/samba/libaddns.so \
186 ${libdir}/samba/libads.so \
187 ${libdir}/samba/libasn1util.so \
188 ${libdir}/samba/libauth.so \
189 ${libdir}/samba/libauth_sam_reply.so \
190 ${libdir}/samba/libauthkrb5.so \
191 ${libdir}/samba/libccan.so \
192 ${libdir}/samba/libcli-ldap-common.so \
193 ${libdir}/samba/libcli-nbt.so \
194 ${libdir}/samba/libcli_cldap.so \
195 ${libdir}/samba/libcli_smb_common.so \
196 ${libdir}/samba/libcli_spoolss.so \
197 ${libdir}/samba/libcliauth.so \
198 ${libdir}/samba/libdbwrap.so \
199 ${libdir}/samba/libdcerpc-samba.so \
200 ${libdir}/samba/liberrors.so \
201 ${libdir}/samba/libflag_mapping.so \
202 ${libdir}/samba/libgse.so \
203 ${libdir}/samba/libinterfaces.so \
204 ${libdir}/samba/libkrb5samba.so \
205 ${libdir}/samba/libldbsamba.so \
206 ${libdir}/samba/liblibcli_lsa3.so \
207 ${libdir}/samba/liblibcli_netlogon3.so \
208 ${libdir}/samba/liblibsmb.so \
209 ${libdir}/samba/libmsrpc3.so \
210 ${libdir}/samba/libndr-samba.so \
211 ${libdir}/samba/libndr-samba4.so \
212 ${libdir}/samba/libnpa_tstream.so \
213 ${libdir}/samba/libntdb.so.* \
214 ${libdir}/samba/libpopt_samba3.so \
215 ${libdir}/samba/libprinting_migrate.so \
216 ${libdir}/samba/libsamba-modules.so \
217 ${libdir}/samba/libsamba-security.so \
218 ${libdir}/samba/libsamba-sockets.so \
219 ${libdir}/samba/libsamba3-util.so \
220 ${libdir}/samba/libsamdb-common.so \
221 ${libdir}/samba/libsecrets3.so \
222 ${libdir}/samba/libserver-role.so \
223 ${libdir}/samba/libsmb_transport.so \
224 ${libdir}/samba/libsmbd_base.so \
225 ${libdir}/samba/libsmbd_conn.so \
226 ${libdir}/samba/libsmbd_shim.so \
227 ${libdir}/samba/libsmbregistry.so \
228 ${libdir}/samba/libtdb-wrap.so \
229 ${libdir}/samba/libutil_cmdline.so \
230 ${libdir}/samba/libutil_ntdb.so \
231 ${libdir}/samba/libutil_reg.so \
232 ${libdir}/samba/libutil_setid.so \
233 ${libdir}/samba/libutil_tdb.so \
234 ${libdir}/samba/pdb/smbpasswd.so \
235 ${libdir}/samba/pdb/tdbsam.so \
236 ${libdir}/samba/pdb/wbc_sam.so \
237"
238
239FILES_winbind-dbg = "${libdir}/idmap/.debug/*.so \
240 ${libdir}/security/.debug/pam_winbind.so \
241"
242
243FILES_${PN} += "${libdir}/vfs/*.so \
244 ${libdir}/charset/*.so \
245 ${libdir}/*.dat \
246 ${libdir}/auth/*.so \
247 ${libdir}/security/pam_smbpass.so \
248"
249
250FILES_${PN}-dbg += "${libdir}/vfs/.debug/*.so \
251 ${libdir}/charset/.debug/*.so \
252 ${libdir}/auth/.debug/*.so \
253 ${libdir}/security/.debug/pam_smbpass.so \
254"
255
256FILES_libwbclient = "${libdir}/libwbclient.so.* ${libdir}/samba/libwinbind-client.so"
257FILES_libnetapi = "${libdir}/libnetapi.so.*"
258FILES_libsmbsharemodes = "${libdir}/libsmbsharemodes.so.*"
259FILES_libsmbclient = "${libdir}/libsmbclient.so.*"
260FILES_libsmbclient-dev = "${libdir}/libsmbclient.so ${includedir}"
261FILES_winbind = "${sbindir}/winbindd \
262 ${bindir}/wbinfo \
263 ${bindir}/ntlm_auth \
264 ${sysconfdir}/init.d/winbind \
265 ${systemd_unitdir}/system/winbind.service \
266"
267
268FILES_libnss-winbind = "${libdir}/libnss_*${SOLIBS} \
269 ${libdir}/nss_info \
270"
271
272FILES_${PN} += "${base_libdir}/security/pam_smbpass.so \
273"
274
275SMB_SERVICE="${systemd_unitdir}/system/nmb.service ${systemd_unitdir}/system/smb.service"
276SMB_SYSV="${sysconfdir}/init.d ${sysconfdir}/rc?.d"
277FILES_${PN}-base +="${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${SMB_SERVICE}', '', d)}"
278FILES_${PN}-base +="${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', '${SMB_SYSV}', '', d)}"
279
280FILES_${PN}-dbg += "${libdir}/samba/idmap/.debug/* \
281 ${libdir}/samba/pdb/.debug/* \
282 ${libdir}/samba/auth/.debug/* \
283 ${libdir}/samba/nss_info/.debug/* \
284 ${libdir}/samba/ldb/.debug/* \
285 ${libdir}/samba/vfs/.debug/* \
286 ${base_libdir}/security/.debug/pam_smbpass.so \
287"
288
289FILES_libwinbind = "${base_libdir}/security/pam_winbind.so"
290FILES_libwinbind += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_unitdir}/system/winbind.service', '', d)}"
291FILES_libwinbind-dbg = "${base_libdir}/security/.debug/pam_winbind.so"
292FILES_libwinbind-krb5-locator = "${libdir}/winbind_krb5_locator.so"
293
294FILES_${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.so \
295 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/_ldb_text.py \
296 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/*.py \
297 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/*.so \
298 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/dcerpc/*.so \
299 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/dcerpc/*.py \
300 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/external/* \
301 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/kcc/* \
302 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/netcmd/*.py \
303 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/provision/*.py \
304 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/samba3/*.py \
305 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/samba3/*.so \
306 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/subunit/* \
307 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/tests/* \
308 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/third_party/* \
309 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/web_server/* \
310"
311
312FILES_${PN}-python-dbg = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/.debug/* \
313 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/.debug/* \
314 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/samba3/.debug/* \
315 ${libdir}/python${PYTHON_BASEVERSION}/site-packages/samba/dcerpc/.debug/* \
316"
317
318RDEPENDS_${PN}-pidl_append = " perl"
319FILES_${PN}-pidl = "${bindir}/pidl ${datadir}/perl5/Parse"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-07-27 20:44:37 +0000