multitail: New "tail for multiple files in parallel" v7.1.5

The build fails with

../sources/multitail-7.1.5/mt.c: In function 'do_color_print':
../sources/multitail-7.1.5/mt.c:712:25: warning: implicit declaration of function 'waddnwstr'; did you mean 'waddnstr'? [-Wimplicit-function-declarat
  712 |                         waddnwstr(win -> win, &wcur, 1);
      |                         ^~~~~~~~~
      |                         waddnstr

I suspect it's due to gcc-16, because in a build environment with gcc-15 it
compiles. Upstream has already set a todo at this code line.

Signed-off-by: Jörg Sommer <joerg.sommer@navimatix.de>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

1 files changed, 37 insertions, 0 deletions

diff --git a/meta-oe/recipes-extended/multitail/multitail_7.1.5.bb b/meta-oe/recipes-extended/multitail/multitail_7.1.5.bb
new file mode 100644
index 0000000000..0f441c6930
--- /dev/null
+++ b/meta-oe/recipes-extended/multitail/multitail_7.1.5.bb
@@ -0,0 +1,37 @@
+SUMMARY = "tail for multiple files in parallel"
+DESCRIPTION = "\
+    MultiTail allows you to monitor logfiles and command output in multiple \
+    windows in a terminal, colorize, filter and merge \
+"
+HOMEPAGE = "https://vanheusden.com/multitail/screenshots.html"
+BUGTRACKER = "https://github.com/folkertvanheusden/multitail/issues"
+SECTION = "console/utils"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e4d13123d158ecd203b5b9ffe50a0c76"
+
+SRC_URI = "git://github.com/folkertvanheusden/multitail.git;protocol=https;branch=master;tag=${PV}"
+SRCREV = "247e7ff727d9a8bed410f1bbf86f247c059546d9"
+
+DEPENDS = "ncurses"
+
+inherit cmake
+
+# Work around the implicit declaration of function 'waddnwstr' in mt.c:712
+CFLAGS += "-Wno-error=implicit-function-declaration"
+
+EXTRA_OECMAKE += "\
+    -DCOMPILER_WARNINGS_ARE_ERRORS=OFF \
+    -DUSE_CPPCHECK=OFF \
+"
+
+PACKAGECONFIG ?= "utf8"
+
+PACKAGECONFIG[utf8] = "-DUTF8_SUPPORT=ON,-DUTF8_SUPPORT=OFF"
+
+do_install:append() {
+    mv -v ${D}${prefix}/etc ${D}${sysconfdir}
+    mv -v ${D}${sysconfdir}/multitail.conf.new ${D}${sysconfdir}/multitail.conf
+    # These are example files to illustrate input conversion
+    mv -v ${D}${sysconfdir}/multitail/conversion-scripts ${D}${docdir}/multitail-${PV}
+}