summaryrefslogtreecommitdiffstats
path: root/recipes-multimedia/libva/intel-media-driver_21.1.3.bb
diff options
context:
space:
mode:
Diffstat (limited to 'recipes-multimedia/libva/intel-media-driver_21.1.3.bb')
-rw-r--r--recipes-multimedia/libva/intel-media-driver_21.1.3.bb50
1 files changed, 50 insertions, 0 deletions
diff --git a/recipes-multimedia/libva/intel-media-driver_21.1.3.bb b/recipes-multimedia/libva/intel-media-driver_21.1.3.bb
new file mode 100644
index 0000000..637d8f0
--- /dev/null
+++ b/recipes-multimedia/libva/intel-media-driver_21.1.3.bb
@@ -0,0 +1,50 @@
1SUMMARY = "VA driver for Intel Gen based graphics hardware"
2DESCRIPTION = "Intel Media Driver for VAAPI is a new VA-API (Video Acceleration API) \
3user mode driver supporting hardware accelerated decoding, encoding, \
4and video post processing for GEN based graphics hardware."
5
6HOMEPAGE = "https://github.com/intel/media-driver"
7BUGTRACKER = "https://github.com/intel/media-driver/issues"
8
9LICENSE = "MIT & BSD-3-Clause"
10LIC_FILES_CHKSUM = "file://LICENSE.md;md5=6aab5363823095ce682b155fef0231f0 \
11 file://media_driver/media_libvpx.LICENSE;md5=d5b04755015be901744a78cc30d390d4 \
12 "
13
14COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
15
16inherit features_check
17REQUIRED_DISTRO_FEATURES = "opengl"
18
19DEPENDS += "libva gmmlib"
20
21SRC_URI = "git://github.com/intel/media-driver.git;protocol=https;nobranch=1 \
22 "
23
24SRCREV = "bec8e1382637589bc3f302edf6c866bec3d754dd"
25S = "${WORKDIR}/git"
26
27COMPATIBLE_HOST_x86-x32 = "null"
28
29UPSTREAM_CHECK_GITTAGREGEX = "^intel-media-(?P<pver>(?!600\..*)\d+(\.\d+)+)$"
30
31inherit cmake pkgconfig
32
33MEDIA_DRIVER_ARCH_x86 = "32"
34MEDIA_DRIVER_ARCH_x86-64 = "64"
35
36EXTRA_OECMAKE += " \
37 -DMEDIA_RUN_TEST_SUITE=OFF \
38 -DARCH=${MEDIA_DRIVER_ARCH} \
39 -DMEDIA_BUILD_FATAL_WARNINGS=OFF \
40 "
41
42CXXFLAGS_append_x86 = " -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE"
43
44do_configure_prepend_toolchain-clang() {
45 sed -i -e '/-fno-tree-pre/d' ${S}/media_driver/cmake/linux/media_compile_flags_linux.cmake
46}
47
48FILES_${PN} += " \
49 ${libdir}/dri/ \
50 "