intel-mediasdk: add recipe

Intel(R) Media SDK provides an API to access hardware-accelerated
video decode, encode and filtering on Intel® platforms with integrated
graphics.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

2 files changed, 37 insertions, 0 deletions

diff --git a/conf/include/maintainers.inc b/conf/include/maintainers.inc
index 55df19d0..d501d5ff 100644
--- a/conf/include/maintainers.inc
+++ b/conf/include/maintainers.inc
@@ -6,6 +6,7 @@ RECIPE_MAINTAINER_pn-gma500-gfx-check = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-gmmlib = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-intel-gpu-tools = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-intel-media-driver = "Anuj Mittal <anuj.mittal@intel.com>"
+RECIPE_MAINTAINER_pn-intel-mediasdk = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-intel-microcode = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-core-image-minimal-initramfs = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-iucode-tool = "Anuj Mittal <anuj.mittal@intel.com>"
diff --git a/recipes-multimedia/mediasdk/intel-mediasdk_18.3.1.bb b/recipes-multimedia/mediasdk/intel-mediasdk_18.3.1.bb
new file mode 100644
index 00000000..fe57b64e
--- /dev/null
+++ b/recipes-multimedia/mediasdk/intel-mediasdk_18.3.1.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Intel(R) Media SDK for hardware accelerated media processing"
+DESCRIPTION = "Intel(R) Media SDK provides an API to access hardware-accelerated \
+video decode, encode and filtering on Intel® platforms with integrated graphics."
+
+HOMEPAGE = "https://github.com/Intel-Media-SDK/MediaSDK"
+BUGTRACKER = "https://github.com/Intel-Media-SDK/MediaSDK/issues"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3cb331af679cd8f968bf799a9c55b46e"
+
+# Only for 64 bit until media-driver issues aren't fixed
+COMPATIBLE_HOST = '(x86_64).*-linux'
+
+DEPENDS += "libdrm libva intel-media-driver"
+
+PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "x11", "dri3", "", d)} \
+                   ${@bb.utils.contains("DISTRO_FEATURES", "wayland", "wayland", "", d)}"
+
+PACKAGECONFIG[dri3]     = "-DENABLE_X11_DRI3=ON, -DENABLE_X11_DRI3=OFF"
+PACKAGECONFIG[wayland]  = "-DENABLE_WAYLAND=ON, -DENABLE_WAYLAND=OFF, wayland wayland-native"
+
+SRC_URI = " \
+            git://github.com/Intel-Media-SDK/MediaSDK.git;protocol=https;branch=${BPN}-18.3 \
+            "
+
+SRCREV = "2e946771649c47525fcbbea057e2a2c1072e173e"
+S = "${WORKDIR}/git"
+
+inherit cmake pkgconfig
+
+EXTRA_OECMAKE += "-DMFX_INCLUDE=${S}/api/include -DBUILD_SAMPLES=OFF"
+
+FILES_${PN} += " \
+                 ${libdir}/mfx \
+                 ${datadir}/mfx/plugins.cfg \
+                 "