change layout to follow oe-core guidelines of recipes

Follow the rules defined in:
http://git.yoctoproject.org/cgit/cgit.cgi/poky/tree/meta/recipes.txt

recipes-bsp          - Anything with links to specific hardware or
                       hardware configuration information
recipes-connectivity - Libraries and applications related to
                       communication with other devices
recipes-core         - What's needed to build a basic working Linux
                       image including commonly used dependencies
recipes-devtools     - Tools primarily used by the build system (but can
                       also be used on targets)
recipes-extended     - Applications which whilst not essential add
                       features compared to the alternatives in
                       core. May be needed for full tool functionality
                       or LSB compliance.
recipes-gnome        - All things related to the GTK+ application
                       framework
recipes-graphics     - X and other graphically related system libraries
recipes-kernel       - The kernel and generic applications/libraries
                       with strong kernel dependencies
recipes-lsb4         - Recipes added for the sole purpose of supporting
                       the Linux Standard Base (LSB) 4.x
recipes-multimedia   - Codecs and support utilties for audio, images and
                       video
recipes-rt           - Provides package and image recipes for using and
                       testing the PREEMPT_RT kernel
recipes-qt           - All things related to the Qt application
                       framework
recipes-sato         - The Sato demo/reference UI/UX, its associated
                       apps and configuration
recipes-support      - Recipes used by other recipes but that are not
                       directly included in images
recipes-dpaa         - recipes related to fsl dpaa feature
recipes-virtualization - recipes related to fsl virtualization feature

Signed-off-by: Ting Liu <b28495@freescale.com>

5 files changed, 154 insertions, 0 deletions

diff --git a/recipes-virtualization/hv-cfg/hv-cfg_git.bb b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
new file mode 100644
index 0000000..2c6bb85
--- /dev/null
+++ b/recipes-virtualization/hv-cfg/hv-cfg_git.bb
@@ -0,0 +1,46 @@
+DESCRIPTION = "Hypervisor Config"
+SECTION = "hv-cfg"
+LICENSE = "BSD"
+PR = "r6"
+
+LIC_FILES_CHKSUM = " \
+        file://p2041rdb/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p3041ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p4080ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+        file://p5020ds/LICENSE;md5=96dd72f26e9bb861de5c76c60e35e1bc \
+"
+
+DEPENDS += "dtc-native"
+
+# this package is specific to the machine itself
+INHIBIT_DEFAULT_DEPS = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_HOST_fslmachine = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+inherit deploy
+
+SRCREV = "d037ab9d5b9ecd58e10a7dac2b601d781ed9b5bf"
+SRC_URI = "git://git.freescale.com/ppc/sdk/hv-cfg.git"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+        make install
+
+        M=`echo ${MACHINE} | sed s/-64b//g`
+        install -d ${D}/boot/hv-cfg
+        cp -r ${S}/${M}/${M}/* ${D}/boot/hv-cfg
+}
+
+do_deploy () {
+        M=`echo ${MACHINE} | sed s/-64b//g`
+        install -d ${DEPLOYDIR}/hv-cfg
+        cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/hv-cfg
+}
+addtask deploy after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot"
+
+ALLOW_EMPTY_${PN} = "1"
diff --git a/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules b/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules
new file mode 100644
index 0000000..5edfa11
--- /dev/null
+++ b/recipes-virtualization/hypervisor/files/81-fsl-embedded-hv.rules
@@ -0,0 +1,2 @@
+# Add rule to handle setting up device node for FSL HV mgmt driver
+SUBSYSTEM=="misc", KERNEL=="fsl-hv", NAME="fsl-hv"
diff --git a/recipes-virtualization/hypervisor/hypervisor_git.bb b/recipes-virtualization/hypervisor/hypervisor_git.bb
new file mode 100644
index 0000000..dc86406
--- /dev/null
+++ b/recipes-virtualization/hypervisor/hypervisor_git.bb
@@ -0,0 +1,90 @@
+DESCRIPTION = "Freescale embedded hypervisor"
+SECTION = "embedded-hv"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://README;endline=22;md5=0655bbc3b7d7166c30c87208b4e23cf0"
+
+PR = "r3"
+
+DEPENDS = "u-boot-mkimage-native"
+
+inherit deploy
+
+S = "${WORKDIR}/git"
+
+# TODO: fix dtc to use the already built package
+SRC_URI = " \
+        git://git.freescale.com/ppc/sdk/hypervisor/hypervisor.git;name=hypervisor \
+        git://git.freescale.com/ppc/sdk/hypervisor/kconfig.git;name=kconfig;destsuffix=git/kconfig \
+        git://git.freescale.com/ppc/sdk/hypervisor/libos.git;name=libos;destsuffix=git/libos \
+        git://www.jdl.com/software/dtc.git;name=dtc;destsuffix=dtc \
+        git://git.freescale.com/ppc/sdk/hypertrk.git;name=hypertrk;destsuffix=git/hypertrk \
+        file://81-fsl-embedded-hv.rules \
+          "
+
+SRCREV_FORMAT="hypervisor"
+SRCREV = "e6092cdf2a225c66c1ea46b1151eb828da29d139"
+SRCREV_kconfig = "a56025d4da992b856796b0eccac2e410d751dbac"
+SRCREV_libos = "5268371581f3ef3959be2a53235edfa6a8c6aa7c"
+SRCREV_dtc = "033089f29099bdfd5c2d6986cdb9fd07b16cfde0"
+SRCREV_hypertrk = "975c98b562186afbd3bbf103ae54b96cf9b3e533"
+
+EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
+
+DEFCONFIG = "defconfig"
+DEFCONFIG_powerpc64 = "64bit_defconfig"
+
+COMPATIBLE_HOST_fslmachine = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+inherit cml1
+do_configure () {
+        oe_runmake ${DEFCONFIG}
+}
+
+PKG_HV_HYPERTRK_SUPPORT = "n"
+do_compile () {
+        if [ "${PKG_HV_HYPERTRK_SUPPORT}" = "y" ]
+        then
+                oe_runmake silentoldconfig
+                export HV_DIR=$PWD
+                cd hypertrk
+                oe_runmake deploy
+                cd ..
+        fi
+
+        oe_runmake
+        oe_runmake partman
+}
+
+do_install () {
+        install -d ${D}/${bindir}
+        install ${S}/output/bin/linux/partman ${D}/${bindir}/partman
+
+        install -d ${D}${sysconfdir}/udev/rules.d
+        install -m 0644 ${WORKDIR}/81-fsl-embedded-hv.rules ${D}${sysconfdir}/udev/rules.d
+
+        install -d ${D}/boot/hv
+        install ${S}/output/.config ${D}/boot/hv/hypervisor.config
+        install -m 644 ${S}/output/bin/hv ${S}/output/bin/hv.map \
+                ${S}/output/bin/hv.uImage ${S}/output/bin/hv.bin \
+                        ${D}/boot/hv/
+}
+
+do_deploy () {
+        install -d ${DEPLOYDIR}/hv/
+        install ${S}/output/.config ${DEPLOYDIR}/hv/hypervisor.config
+        install -m 644 ${S}/output/bin/hv ${S}/output/bin/hv.map \
+                ${S}/output/bin/hv.uImage ${S}/output/bin/hv.bin \
+                        ${DEPLOYDIR}/hv/
+}
+addtask deploy before do_build after do_install
+
+do_deploy_append() {
+        rm -f ${S}/../hv
+}
+
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+ALLOW_EMPTY_${PN} = "1"
+PACKAGES_prepend = "${PN}-image ${PN}-partman "
+FILES_${PN}-image = "/boot/"
+FILES_${PN}-partman = "${bindir}/partman"
diff --git a/recipes-virtualization/mux-server/files/mux-server-1.02.tar.gz b/recipes-virtualization/mux-server/files/mux-server-1.02.tar.gz
new file mode 100644
index 0000000..d8f2014
--- /dev/null
+++ b/recipes-virtualization/mux-server/files/mux-server-1.02.tar.gz
diff --git a/recipes-virtualization/mux-server/mux-server_1.02.bb b/recipes-virtualization/mux-server/mux-server_1.02.bb
new file mode 100644
index 0000000..ab9cce1
--- /dev/null
+++ b/recipes-virtualization/mux-server/mux-server_1.02.bb
@@ -0,0 +1,16 @@
+DESCRIPTION = "A Linux-based utility supporting console multiplexing and demultiplexing"
+SECTION = "mux-server"
+LICENSE = "LGPL-2.1"
+# TODO: add a dedicated COPYING file
+LIC_FILES_CHKSUM = "file://mux_server.c;endline=9;md5=e59eeb0812bb88b7af2d932f2dc22aed"
+
+SRC_URI = "file://mux-server-${PV}.tar.gz;name=mux_server"
+
+EXTRA_OEMAKE='HOSTCC="${CC}"'
+
+do_install () {
+        install -d ${D}${bindir}
+        install -m 755 mux_server ${D}${bindir}
+}
+
+BBCLASSEXTEND = "native nativesdk"