1 files changed, 46 insertions, 0 deletions

diff --git a/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.3.p4.6.bb b/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.3.p4.6.bb
new file mode 100644
index 000000000..d513c7200
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.3.p4.6.bb
@@ -0,0 +1,46 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2022 NXP
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX GPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5a0bf11f745e68024f37b4724a5364fe"
+DEPENDS = "libgal-imx"
+PROVIDES = "virtual/libg2d"
+
+FSLBIN_NAME     = "${PN}-${PV}-${TARGET_ARCH}"
+
+SRC_URI = "${FSL_MIRROR}/${FSLBIN_NAME}.bin;name=${TARGET_ARCH};fsl-eula=true"
+SRC_URI[aarch64.md5sum] = "41e6c3a6f8d4151d30c1f34341465b30"
+SRC_URI[aarch64.sha256sum] = "70e007f66459ee6a392f4a21f4d4a753ff22a75b728cc7d952251b00ba3ab51e"
+SRC_URI[arm.md5sum] = "4c751218aa4db1f545bcec17ee963cc0"
+SRC_URI[arm.sha256sum] = "288f78419d825e71563c38a39a738f040e098b581b76e6f8b8fc5895e7d9d7c4"
+
+S = "${WORKDIR}/${FSLBIN_NAME}"
+
+inherit fsl-eula-unpack
+
+SOC_INSTALL_DIR               = "SOC_INSTALL_DIR_NOT_SET"
+SOC_INSTALL_DIR:mx8mm-nxp-bsp = "mx8mm"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    if [ -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR} ]; then
+        cp -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR}/*.so* ${D}${libdir}
+    fi
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+INSANE_SKIP:${PN} = "ldflags"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxgpu2d)"