2 files changed, 57 insertions, 3 deletions

diff --git a/conf/machine/include/imx-base.inc b/conf/machine/include/imx-base.inc
index 88430fb87..72060648a 100644
--- a/conf/machine/include/imx-base.inc
+++ b/conf/machine/include/imx-base.inc
@@ -329,6 +329,7 @@ MACHINE_SOCARCH_FILTER:append:imxvulkan = " \
     vulkan-headers \
     vulkan-loader \
     vulkan-tools \
+    vulkan-validation-layers \
 "
 MACHINE_SOCARCH_FILTER:append:imxgpu = " \
     virtual/egl \
@@ -534,9 +535,10 @@ PREFERRED_VERSION_libdrm:mx7-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx8-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx9-nxp-bsp ??= "2.4.114.imx"
 
-PREFERRED_VERSION_vulkan-headers:imxvulkan ??= "1.2.182.0.imx"
-PREFERRED_VERSION_vulkan-loader:imxvulkan  ??= "1.2.182.0.imx"
-PREFERRED_VERSION_vulkan-tools:imxvulkan   ??= "1.2.182.0.imx"
+PREFERRED_VERSION_vulkan-headers:imxvulkan           ??= "1.2.182.0.imx"
+PREFERRED_VERSION_vulkan-loader:imxvulkan            ??= "1.2.182.0.imx"
+PREFERRED_VERSION_vulkan-tools:imxvulkan             ??= "1.2.182.0.imx"
+PREFERRED_VERSION_vulkan-validation-layers:imxvulkan ??= "1.2.182.0.imx"
 
 # Use i.MX optee Version
 PREFERRED_VERSION_optee-os:mx8-nxp-bsp     ??= "3.19.0.imx"
diff --git a/recipes-downgrade/vulkan/vulkan-validation-layers_1.2.182.0.imx.bb b/recipes-downgrade/vulkan/vulkan-validation-layers_1.2.182.0.imx.bb
new file mode 100644
index 000000000..da834e625
--- /dev/null
+++ b/recipes-downgrade/vulkan/vulkan-validation-layers_1.2.182.0.imx.bb
@@ -0,0 +1,52 @@
+SUMMARY = "Vulkan Validation layers"
+DESCRIPTION = "Khronos official Vulkan validation layers to assist developers \
+in verifying that their applications correctly use the Vulkan API"
+HOMEPAGE = "https://www.khronos.org/vulkan/"
+BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+SECTION = "libs"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=8df9e8826734226d08cb412babfa599c"
+
+SRC_URI = "git://git@github.com/KhronosGroup/Vulkan-ValidationLayers.git;branch=sdk-1.2.182;protocol=https"
+SRCREV = "91fcffa8eca1a9573c8d736a54a028035ed4e06c"
+
+S = "${WORKDIR}/git"
+
+REQUIRED_DISTRO_FEATURES = "vulkan"
+
+DEPENDS = "vulkan-headers vulkan-loader spirv-headers spirv-tools glslang"
+
+# BUILD_TESTS            - Not required for OE builds
+# BUILD_WERROR           - There are too many compiler warnings/errors due to upgrades in version
+#                          of clang. Requiring a number of patches from upstream. Disable compiler
+#                          -Werror to bypass build issues.
+# USE_ROBIN_HOOD_HASHING - Provides substantial performance improvements on all platforms.
+#                          Yocto project doesn't contain a recipe for package so disabled it.
+EXTRA_OECMAKE = "\
+    -DBUILD_TESTS=OFF \
+    -DBUILD_WERROR=OFF \
+    -DUSE_ROBIN_HOOD_HASHING=OFF \
+    -DGLSLANG_INSTALL_DIR=${STAGING_LIBDIR} \
+    -DVULKAN_HEADERS_INSTALL_DIR=${STAGING_DATADIR} \
+    -DSPIRV_HEADERS_INSTALL_DIR=${STAGING_DATADIR} \
+    "
+
+PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
+PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
+
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11 wayland', d)}"
+
+inherit cmake features_check pkgconfig
+
+FILES:${PN} += "${datadir}/vulkan"
+
+SOLIBS = ".so"
+FILES_SOLIBSDEV = ""
+
+# These recipes need to be updated in lockstep with each other:
+# glslang, vulkan-headers, vulkan-loader, vulkan-tools,
+# vulkan-validation-layers, spirv-headers, spirv-tools
+# The tags versions should always be sdk-x.y.z, as this is what
+# upstream considers a release.
+UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"