summaryrefslogtreecommitdiffstats
path: root/meta-fsl-ppc/recipes-bsp
diff options
context:
space:
mode:
authorOtavio Salvador <otavio@ossystems.com.br>2015-07-13 14:00:59 -0300
committerOtavio Salvador <otavio@ossystems.com.br>2015-07-15 15:46:20 +0000
commitc92b415d653afc55f33b6b93fb9248193bfd4fa0 (patch)
treef473cb6d92bff7654ed35decf204041c34579b67 /meta-fsl-ppc/recipes-bsp
parent8800258fd611baf2dc62c8c620a4a2fdb75ef148 (diff)
parent60ecf4f21bb60a1c83a194b6799f56dcaf094f1b (diff)
downloadmeta-freescale-c92b415d653afc55f33b6b93fb9248193bfd4fa0.tar.gz
Merge branch 'master' from multiple repositories
Repositories: meta-fsl-arm meta-fsl-ppc Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
Diffstat (limited to 'meta-fsl-ppc/recipes-bsp')
-rw-r--r--meta-fsl-ppc/recipes-bsp/apptrk/apptrk_git.bb20
-rw-r--r--meta-fsl-ppc/recipes-bsp/boot-format/boot-format/flags.patch21
-rw-r--r--meta-fsl-ppc/recipes-bsp/boot-format/boot-format_git.bb20
-rw-r--r--meta-fsl-ppc/recipes-bsp/ipc/ipc-ust_git.bb50
-rw-r--r--meta-fsl-ppc/recipes-bsp/ipc/ipc.inc7
-rw-r--r--meta-fsl-ppc/recipes-bsp/pkc-firmware/pkc-firmware_git.bb41
-rw-r--r--meta-fsl-ppc/recipes-bsp/qe-ucode/qe-ucode_git.bb35
-rw-r--r--meta-fsl-ppc/recipes-bsp/rcw/rcw_git.bb47
-rw-r--r--meta-fsl-ppc/recipes-bsp/u-boot/files/0001-u-boot-mpc85xx-u-boot-.lds-remove-_GLOBAL_OFFSET_TAB.patch77
-rw-r--r--meta-fsl-ppc/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch38
-rw-r--r--meta-fsl-ppc/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb188
11 files changed, 544 insertions, 0 deletions
diff --git a/meta-fsl-ppc/recipes-bsp/apptrk/apptrk_git.bb b/meta-fsl-ppc/recipes-bsp/apptrk/apptrk_git.bb
new file mode 100644
index 000000000..09d5de59f
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/apptrk/apptrk_git.bb
@@ -0,0 +1,20 @@
1DESCRIPTION = "Userspace debug agent for PA CodeWarrior"
2LICENSE = "Freescale-EULA"
3LIC_FILES_CHKSUM = "file://COPYING;md5=95560debfde180684364319811cc1421"
4
5DEPENDS = "elfutils"
6
7SRC_URI = "git://git.freescale.com/ppc/sdk/apptrk.git;nobranch=1"
8SRCREV = "cbed10997c5e2a4aaa004fb0e1efec858bf1bbe1"
9
10S = "${WORKDIR}/git"
11
12CFLAGS += " -I${STAGING_INCDIR} -ISource/Linux -ISource/Portable \
13 -ISource/Linux_PA -ISource/PA -DPPC \
14"
15CFLAGS_append_powerpc64 = " -DENABLE_64BIT_SUPPORT"
16
17do_install() {
18 install -d ${D}/usr/bin
19 oe_runmake install DESTDIR=${D}
20}
diff --git a/meta-fsl-ppc/recipes-bsp/boot-format/boot-format/flags.patch b/meta-fsl-ppc/recipes-bsp/boot-format/boot-format/flags.patch
new file mode 100644
index 000000000..cddb34cde
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/boot-format/boot-format/flags.patch
@@ -0,0 +1,21 @@
1Index: git/Makefile
2===================================================================
3--- git.orig/Makefile
4+++ git/Makefile
5@@ -3,14 +3,14 @@
6 INSTALL=install
7 PREFIX=/usr
8
9-CFLAGS=-Wall
10+override CFLAGS+=-Wall
11
12 all: boot_format
13
14 boot_format.o: boot_format.c boot_format.h
15
16 boot_format: boot_format.o
17- $(CC) $< -o $@
18+ $(CC) $(CFLAGS) $< -o $@ $(LDFLAGS)
19
20 install: boot_format
21 $(INSTALL) -d $(DESTDIR)$(PREFIX)/bin
diff --git a/meta-fsl-ppc/recipes-bsp/boot-format/boot-format_git.bb b/meta-fsl-ppc/recipes-bsp/boot-format/boot-format_git.bb
new file mode 100644
index 000000000..2d9f9b1db
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/boot-format/boot-format_git.bb
@@ -0,0 +1,20 @@
1DESCRIPTION = "Boot format utility for booting from eSDHC/eSPI"
2LICENSE = "GPLv2"
3PR = "r6"
4LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
5
6SRC_URI = "git://git.freescale.com/ppc/sdk/boot-format.git;nobranch=1 \
7 file://flags.patch"
8SRCREV = "4eb81a6797ef4e58bf7d9b2d58afb37a21c1f550"
9
10S = "${WORKDIR}/git"
11EXTRA_OEMAKE = 'CC="${CC}" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"'
12
13do_install(){
14 oe_runmake DESTDIR=${D} PREFIX=${prefix} install
15}
16
17PACKAGES =+ "${PN}-config"
18FILES_${PN}-config += "${datadir}/*"
19
20BBCLASSEXTEND = "native nativesdk"
diff --git a/meta-fsl-ppc/recipes-bsp/ipc/ipc-ust_git.bb b/meta-fsl-ppc/recipes-bsp/ipc/ipc-ust_git.bb
new file mode 100644
index 000000000..c6b3cfe62
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/ipc/ipc-ust_git.bb
@@ -0,0 +1,50 @@
1SUMMARY = "Linux IPC Userspace Tool"
2DESCRIPTION = "DSP boot application and ipc test application"
3LICENSE = "BSD"
4LIC_FILES_CHKSUM = "file://COPYING;md5=fa38cd73d71527dc6efb546474f64d10"
5
6require ipc.inc
7
8S = "${WORKDIR}/git"
9
10# workaround for issue of parallel build, required a actual fix in ipc source
11PARALLEL_MAKE = ""
12
13EXTRA_OEMAKE = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC}" AR="${AR}"'
14
15do_compile () {
16 case ${MACHINE} in
17 bsc9132qds|bsc9131rdb) SOC=B913x;;
18 b4860qds|b4420qds|b4860qds-64b) SOC=B4860;;
19 esac
20 oe_runmake ${SOC}=1
21}
22
23do_install () {
24 install -d ${D}${bindir}
25 install -d ${D}${includedir}
26 install -d ${D}/ipc
27 install -m 755 ${S}/dsp_boot/dsp_bt ${D}/ipc
28 install -m 755 ${S}/ipc/ipc_test ${D}/ipc
29 install -m 755 ${S}/ipc/ipc_test67 ${D}/ipc
30 install -m 755 ${S}/ipc/l1d_app ${D}/ipc
31 install -m 755 ${S}/fsl_shm/app ${D}${bindir}/lg_shm_test
32 install -d ${D}${base_libdir}
33 install -m 755 ${S}/ipc/libipc.so ${D}${base_libdir}
34 install -m 755 ${S}/ipc/libmem.so ${D}${base_libdir}
35 install -m 755 ${S}/ipc/libdspboot.so ${D}${base_libdir}
36 install -d ${D}${includedir}/ipc
37 install -d ${D}${includedir}/ipc/ipc/include
38 install -d ${D}${includedir}/ipc/fsl_shm/lib
39 install ${S}/ipc/include/*.h ${D}${includedir}/ipc/ipc/include
40 install ${S}/dsp_boot/*.h ${D}${includedir}/ipc/ipc/include
41 install ${S}/kernel/fsl_ipc_types.h ${D}${includedir}/ipc/ipc/include
42 install ${S}/kernel/fsl_heterogeneous_common.h ${D}${includedir}/ipc/ipc/include
43 install ${S}/kernel/fsl_heterogeneous_l1_defense.h ${D}${includedir}/ipc/ipc/include
44 install ${S}/fsl_shm/include/*.h ${D}${includedir}/ipc/ipc/include
45 install ${S}/fsl_shm/lib/*.h ${D}${includedir}/ipc/fsl_shm/lib
46}
47
48FILES_${PN} += "/ipc/*"
49FILES_${PN}-dbg += "/ipc/.debug"
50
diff --git a/meta-fsl-ppc/recipes-bsp/ipc/ipc.inc b/meta-fsl-ppc/recipes-bsp/ipc/ipc.inc
new file mode 100644
index 000000000..547771ae8
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/ipc/ipc.inc
@@ -0,0 +1,7 @@
1DEPENDS = "virtual/kernel"
2
3SRC_URI = "git://git.freescale.com/ppc/sdk/ipc.git;nobranch=1"
4SRCREV = "c9c92ac6a7a31c9d878096eb7d135c22a38f20ff"
5
6COMPATIBLE_MACHINE = "(bsc9132qds|bsc9131rdb|b4860qds|b4420qds)"
7
diff --git a/meta-fsl-ppc/recipes-bsp/pkc-firmware/pkc-firmware_git.bb b/meta-fsl-ppc/recipes-bsp/pkc-firmware/pkc-firmware_git.bb
new file mode 100644
index 000000000..3cc5d4463
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/pkc-firmware/pkc-firmware_git.bb
@@ -0,0 +1,41 @@
1DESCRIPTION = "U-boot firmware for c293pcie support "
2HOMEPAGE = "http://u-boot.sf.net"
3LICENSE = "GPLv2"
4LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb"
5
6INHIBIT_DEFAULT_DEPS = "1"
7DEPENDS = "virtual/${TARGET_PREFIX}gcc libgcc"
8
9inherit deploy
10
11PACKAGE_ARCH = "${MACHINE_ARCH}"
12
13SRC_URI = "git://git.freescale.com/ppc/sdk/pkc-firmware.git;nobranch=1"
14SRCREV = "b891873c1eea7a7d53f9472ea601712897cb17b7"
15
16S = "${WORKDIR}/git"
17
18EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
19
20do_compile () {
21 unset LDFLAGS
22 unset CFLAGS
23 unset CPPFLAGS
24 oe_runmake C293QDS_36BIT_SDCARD
25}
26
27do_install(){
28 install -d ${D}${sysconfdir}/crypto/
29 install ${S}/u-boot.bin ${D}${sysconfdir}/crypto/pkc-firmware.bin
30}
31
32do_deploy(){
33 install -d ${DEPLOYDIR}/pkc-firmware
34 install ${S}/u-boot.bin ${DEPLOYDIR}/pkc-firmware/pkc-firmware.bin
35}
36
37addtask deploy after do_install
38
39FILES_{PN} += "/etc/crypto/pkc-firmware.bin"
40COMPATIBLE_MACHINE = "(c293pcie)"
41
diff --git a/meta-fsl-ppc/recipes-bsp/qe-ucode/qe-ucode_git.bb b/meta-fsl-ppc/recipes-bsp/qe-ucode/qe-ucode_git.bb
new file mode 100644
index 000000000..028d9bcd0
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/qe-ucode/qe-ucode_git.bb
@@ -0,0 +1,35 @@
1DESCRIPTION = "qe microcode binary"
2SECTION = "qe-ucode"
3LICENSE = "Freescale-EULA"
4LIC_FILES_CHKSUM = "file://EULA;md5=60037ccba533a5995e8d1a838d85799c"
5
6python () {
7 if not d.getVar("QE_UCODE", True):
8 machine = d.getVar("MACHINE", True)
9 raise bb.parse.SkipPackage("QE_UCODE not set in \
10 meta-fsl-ppc/conf/machine/%s.conf" % machine)
11}
12
13inherit deploy
14
15SRC_URI = "git://git.freescale.com/ppc/sdk/qe-ucode.git;nobranch=1"
16SRCREV= "49efc94b553de5c2a9bd28093592eff0068e161c"
17
18S = "${WORKDIR}/git"
19
20do_install () {
21 install -d ${D}/boot
22 install -m 644 ${QE_UCODE} ${D}/boot/
23}
24
25do_deploy () {
26 install -d ${DEPLOYDIR}/boot
27 install -m 644 ${QE_UCODE} ${DEPLOYDIR}/boot/
28}
29addtask deploy before do_build after do_install
30
31PACKAGES += "${PN}-image"
32FILES_${PN}-image += "/boot/*"
33ALLOW_EMPTY_${PN} = "1"
34COMPATIBLE_MACHINE = "(p1021rdb|p1025twr|t1)"
35
diff --git a/meta-fsl-ppc/recipes-bsp/rcw/rcw_git.bb b/meta-fsl-ppc/recipes-bsp/rcw/rcw_git.bb
new file mode 100644
index 000000000..5714ed0a3
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/rcw/rcw_git.bb
@@ -0,0 +1,47 @@
1DESCRIPTION = "Reset Control Words (RCW)"
2SECTION = "rcw"
3LICENSE = "BSD"
4PR = "r8"
5
6LIC_FILES_CHKSUM = "file://rcw.py;beginline=8;endline=28;md5=9ba0b28922dd187b06b6c8ebcfdd208e"
7
8# this package is specific to the machine itself
9INHIBIT_DEFAULT_DEPS = "1"
10PACKAGE_ARCH = "${MACHINE_ARCH}"
11
12inherit deploy
13
14SRC_URI = "git://git.freescale.com/ppc/sdk/rcw.git;nobranch=1"
15SRCREV = "3e89f378ed70e9b856756de8c3dbdfccb045fa0c"
16
17S = "${WORKDIR}/git"
18
19export PYTHON
20
21do_install () {
22 make install
23
24 M=`echo ${MACHINE} | sed s/-64b//g`
25 if [ "t1042rdb" = "${M}" ] || [ "t1042rdb-pi" = "${M}" ];then
26 M=t1042rdb_pi
27 fi
28 install -d ${D}/boot/rcw
29 cp -r ${S}/${M}/${M}/* ${D}/boot/rcw
30}
31
32do_deploy () {
33 M=`echo ${MACHINE} | sed s/-64b//g`
34 if [ "t1042rdb" = "${M}" ] || [ "t1042rdb-pi" = "${M}" ];then
35 M=t1042rdb_pi
36 fi
37 install -d ${DEPLOYDIR}/rcw
38 cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/rcw
39}
40addtask deploy after do_install
41
42PACKAGES += "${PN}-image"
43FILES_${PN}-image += "/boot"
44
45COMPATIBLE_HOST_qoriq-ppc = ".*"
46COMPATIBLE_HOST ?= "(none)"
47ALLOW_EMPTY_${PN} = "1"
diff --git a/meta-fsl-ppc/recipes-bsp/u-boot/files/0001-u-boot-mpc85xx-u-boot-.lds-remove-_GLOBAL_OFFSET_TAB.patch b/meta-fsl-ppc/recipes-bsp/u-boot/files/0001-u-boot-mpc85xx-u-boot-.lds-remove-_GLOBAL_OFFSET_TAB.patch
new file mode 100644
index 000000000..e6b8d2e59
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/u-boot/files/0001-u-boot-mpc85xx-u-boot-.lds-remove-_GLOBAL_OFFSET_TAB.patch
@@ -0,0 +1,77 @@
1From 9ba002f1b1afc7af84a352f4ecab32a30d7ba353 Mon Sep 17 00:00:00 2001
2From: Zhenhua Luo <zhenhua.luo@freescale.com>
3Date: Mon, 9 Feb 2015 18:33:56 +0800
4Subject: [PATCH] u-boot/mpc85xx/u-boot*.lds: remove _GLOBAL_OFFSET_TABLE_
5 definition
6
7In binutils-2.25, the _GLOBAL_OFFSET_TABLE_ symbols defined by PROVIDE in
8u-boot.lds overrides the linker built-in symbols
9(https://sourceware.org/git/gitweb.cgi?p=binutils-gdb.git;a=commitdiff;h=b893397a4b1316610f49819344817715e4305de9),
10so the linker is treating _GLOBAL_OFFSET_TABLE_ as a definition into the .reloc section.
11
12To align with the change of binutils-2.25, the _GLOBAL_OFFSET_TABLE_ symbol
13should not be defined in sections, and the symbols in linker generated .got
14section should be used(https://sourceware.org/ml/binutils/2008-09/msg00122.html).
15
16Fixed the following build errors with binutils-2.25:
17| powerpc-poky-linux-gnuspe-ld.bfd: _GLOBAL_OFFSET_TABLE_ not defined in linker created .got
18
19Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
20---
21 arch/powerpc/cpu/mpc85xx/u-boot-nand.lds | 1 -
22 arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds | 1 -
23 arch/powerpc/cpu/mpc85xx/u-boot-spl.lds | 1 -
24 arch/powerpc/cpu/mpc85xx/u-boot.lds | 1 -
25 4 files changed, 4 deletions(-)
26
27diff --git a/arch/powerpc/cpu/mpc85xx/u-boot-nand.lds b/arch/powerpc/cpu/mpc85xx/u-boot-nand.lds
28index f933b21..0399f93 100644
29--- a/arch/powerpc/cpu/mpc85xx/u-boot-nand.lds
30+++ b/arch/powerpc/cpu/mpc85xx/u-boot-nand.lds
31@@ -44,7 +44,6 @@ SECTIONS
32 _GOT2_TABLE_ = .;
33 KEEP(*(.got2))
34 KEEP(*(.got))
35- PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
36 _FIXUP_TABLE_ = .;
37 KEEP(*(.fixup))
38 }
39diff --git a/arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds b/arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds
40index b83c553..f044564 100644
41--- a/arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds
42+++ b/arch/powerpc/cpu/mpc85xx/u-boot-nand_spl.lds
43@@ -22,7 +22,6 @@ SECTIONS
44 _GOT2_TABLE_ = .;
45 KEEP(*(.got2))
46 KEEP(*(.got))
47- PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
48 _FIXUP_TABLE_ = .;
49 KEEP(*(.fixup))
50 }
51diff --git a/arch/powerpc/cpu/mpc85xx/u-boot-spl.lds b/arch/powerpc/cpu/mpc85xx/u-boot-spl.lds
52index 5ae7b3e..889a4c2 100644
53--- a/arch/powerpc/cpu/mpc85xx/u-boot-spl.lds
54+++ b/arch/powerpc/cpu/mpc85xx/u-boot-spl.lds
55@@ -29,7 +29,6 @@ SECTIONS
56 _GOT2_TABLE_ = .;
57 KEEP(*(.got2))
58 KEEP(*(.got))
59- PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
60 _FIXUP_TABLE_ = .;
61 KEEP(*(.fixup))
62 }
63diff --git a/arch/powerpc/cpu/mpc85xx/u-boot.lds b/arch/powerpc/cpu/mpc85xx/u-boot.lds
64index 2cf0b25..f15eaf3 100644
65--- a/arch/powerpc/cpu/mpc85xx/u-boot.lds
66+++ b/arch/powerpc/cpu/mpc85xx/u-boot.lds
67@@ -50,7 +50,6 @@ SECTIONS
68 _GOT2_TABLE_ = .;
69 KEEP(*(.got2))
70 KEEP(*(.got))
71- PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
72 _FIXUP_TABLE_ = .;
73 KEEP(*(.fixup))
74 }
75--
762.1.0
77
diff --git a/meta-fsl-ppc/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch b/meta-fsl-ppc/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch
new file mode 100644
index 000000000..1ddc6675a
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch
@@ -0,0 +1,38 @@
1Upstream-Status: Pending
2
3From 301832414369b749918e0d5db850eed19b81c0fc Mon Sep 17 00:00:00 2001
4From: Zhenhua Luo <zhenhua.luo@freescale.com>
5Date: Tue, 24 Sep 2013 00:54:40 -0500
6Subject: [PATCH] Fix the depend race issue
7
8| make[3]: Entering directory `/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/arch/powerpc/cpu/mpc85xx'
9| /srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/P1022DS_NAND/spl/arch/powerpc/cpu/mpc85xx/.depend:125: *** missing separator. Stop.
10| make[3]: Leaving directory `/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/arch/powerpc/cpu/mpc85xx'
11| make[2]: *** [/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/P1022DS_NAND/spl/arch/powerpc/cpu/mpc85xx/start.o] Error 2
12| make[2]: *** Waiting for unfinished jobs....
13
14Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
15---
16 spl/Makefile | 6 +++++-
17 1 file changed, 5 insertions(+), 1 deletion(-)
18
19diff --git a/spl/Makefile b/spl/Makefile
20index 6dbb105..3156d87 100644
21--- a/spl/Makefile
22+++ b/spl/Makefile
23@@ -185,7 +185,11 @@ $(eval $(call make_u_boot_list, $(obj)u-boot.lst, $(LIBS)))
24 $(obj)u-boot-spl.lds: $(LDSCRIPT) $(obj)u-boot.lst depend
25 $(CPP) $(CPPFLAGS) $(LDPPFLAGS) -I$(obj). -ansi -D__ASSEMBLY__ -P - < $< > $@
26
27-depend: $(obj).depend
28+# Explicitly make _depend in subdirs containing multiple targets to prevent
29+# parallel sub-makes creating .depend files simultaneously.
30+depend dep: $(obj).depend
31+ for dir in $(SUBDIRS) $(CPUDIR) $(LDSCRIPT_MAKEFILE_DIR) ; do \
32+ $(MAKE) -C $(SRCTREE)/$$dir _depend ; done
33 .PHONY: depend
34
35 # defines $(obj).depend target
36--
371.8.2.1
38
diff --git a/meta-fsl-ppc/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb b/meta-fsl-ppc/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb
new file mode 100644
index 000000000..3e519e2fb
--- /dev/null
+++ b/meta-fsl-ppc/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb
@@ -0,0 +1,188 @@
1DESCRIPTION = "U-boot bootloader"
2HOMEPAGE = "http://u-boot.sf.net"
3SECTION = "bootloaders"
4PROVIDES = "virtual/bootloader u-boot"
5LICENSE = "GPLv2 & BSD-3-Clause & BSD-2-Clause & LGPL-2.0 & LGPL-2.1"
6LIC_FILES_CHKSUM = " \
7 file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
8 file://Licenses/bsd-2-clause.txt;md5=6a31f076f5773aabd8ff86191ad6fdd5 \
9 file://Licenses/bsd-3-clause.txt;md5=4a1190eac56a9db675d58ebe86eaf50c \
10 file://Licenses/lgpl-2.0.txt;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
11 file://Licenses/lgpl-2.1.txt;md5=4fbd65380cdd255951079008b364516c \
12"
13
14PV = "2014.07+fslgit"
15INHIBIT_DEFAULT_DEPS = "1"
16DEPENDS = "boot-format-native libgcc ${@base_contains('TCMODE', 'external-fsl', '', 'virtual/${TARGET_PREFIX}gcc', d)}"
17
18inherit deploy
19
20SRC_URI = "git://git.freescale.com/ppc/sdk/u-boot.git;nobranch=1 \
21 file://0001-u-boot-mpc85xx-u-boot-.lds-remove-_GLOBAL_OFFSET_TAB.patch"
22SRCREV = "659b6a23a8b1f3026200bc6352dbacef53f4dcb1"
23
24python () {
25 if d.getVar("TCMODE", True) == "external-fsl":
26 return
27
28 ml = d.getVar("MULTILIB_VARIANTS", True)
29 arch = d.getVar("OVERRIDES", True)
30
31 if "e5500-64b:" in arch or "e6500-64b:" in arch:
32 if not "lib32" in ml:
33 raise bb.parse.SkipPackage("Building the u-boot for this arch requires multilib to be enabled")
34 sys_multilib = 'powerpc' + d.getVar('TARGET_VENDOR') + 'mllib32-' + d.getVar('HOST_OS')
35 d.setVar('DEPENDS_append', ' lib32-gcc-cross-powerpc lib32-libgcc')
36 d.setVar('PATH_append', ':' + d.getVar('STAGING_BINDIR_NATIVE') + '/' + sys_multilib)
37 d.setVar('TOOLCHAIN_OPTIONS_append', '/../lib32-' + d.getVar("MACHINE"))
38 d.setVar("WRAP_TARGET_PREFIX", sys_multilib + '-')
39}
40
41WRAP_TARGET_PREFIX ?= "${TARGET_PREFIX}"
42
43PACKAGE_ARCH = "${MACHINE_ARCH}"
44
45UBOOT_LOCALVERSION = "${@d.getVar('SDK_VERSION', True).partition(' ')[0]}"
46
47USRC ?= ""
48S = '${@base_conditional("USRC", "", "${WORKDIR}/git", "${USRC}", d)}'
49
50EXTRA_OEMAKE = 'CROSS_COMPILE=${WRAP_TARGET_PREFIX} CC="${WRAP_TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
51
52do_compile () {
53 unset LDFLAGS
54 unset CFLAGS
55 unset CPPFLAGS
56
57 if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
58 then
59 head=`git rev-parse --verify --short HEAD 2> /dev/null`
60 printf "%s%s%s" ${UBOOT_LOCALVERSION} +g $head > ${B}/.scmversion
61 printf "%s%s%s" ${UBOOT_LOCALVERSION} +g $head > ${S}/.scmversion
62 fi
63
64 if [ "x${UBOOT_MACHINES}" = "x" ]; then
65 UBOOT_MACHINES=${UBOOT_MACHINE}
66 fi
67
68 for board in ${UBOOT_MACHINES}; do
69 if ! grep -wq $board ${S}/boards.cfg;then
70 echo "WARNING: $board not supported in boards.cfg"
71 continue
72 fi
73
74 oe_runmake O=${board} distclean
75 oe_runmake O=${board} ${board}_config
76 oe_runmake O=${board} all
77
78 case "${board}" in
79 *SDCARD*) UBOOT_TARGET="u-boot-sd";;
80 *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
81 *NAND*) UBOOT_TARGET="u-boot-nand";;
82 *SRIO*) UBOOT_TARGET="u-boot-srio";;
83 *) UBOOT_TARGET="";;
84 esac
85
86 # deal with sd/spi/nand/srio image
87 UBOOT_SOURCE=u-boot.bin
88 if [ "x${UBOOT_TARGET}" != "x" ] && echo $board |egrep -qi "SECBOOT|SECURE"; then
89 cp ${S}/${board}/${UBOOT_SOURCE} ${S}/${board}/${UBOOT_TARGET}.bin
90 elif [ "x${UBOOT_TARGET}" != "x" ]; then
91 # some boards' final binary was not named as u-boot.bin
92 if [ "${UBOOT_TARGET}" = "u-boot-nand" ];then
93 if echo $board |egrep -q "^(BSC|C29|P10|P2020RDB)";then
94 UBOOT_SOURCE=u-boot-with-spl.bin
95 elif echo $board |egrep -q "^(B4|T1|T2|T4)";then
96 UBOOT_SOURCE=u-boot-with-spl-pbl.bin
97 elif echo $board |egrep -q "^(P2041|P3|P4|P5)";then
98 UBOOT_SOURCE=u-boot.pbl
99 fi
100 elif [ "${UBOOT_TARGET}" = "u-boot-spi" ];then
101 if echo $board |egrep -q "^(P10|P2020RDB)";then
102 UBOOT_SOURCE=u-boot-with-spl.bin
103 elif echo $board |egrep -q "^(T1|T2)";then
104 UBOOT_SOURCE=u-boot-with-spl-pbl.bin
105 elif echo $board |egrep -q "^(B4|P2041|P3|P4|P5|T4)";then
106 UBOOT_SOURCE=u-boot.pbl
107 fi
108 elif [ "${UBOOT_TARGET}" = "u-boot-sd" ];then
109 if echo $board |egrep -q "^(P10|P2020RDB)";then
110 UBOOT_SOURCE=u-boot-with-spl.bin
111 elif echo $board |egrep -q "^(B4|T1|T2|T4)";then
112 UBOOT_SOURCE=u-boot-with-spl-pbl.bin
113 elif echo $board |egrep -q "^(P2041|P3|P4|P5)";then
114 UBOOT_SOURCE=u-boot.pbl
115 fi
116 fi
117 cp ${S}/${board}/${UBOOT_SOURCE} ${S}/${board}/${UBOOT_TARGET}.bin
118
119 # use boot-format to regenerate spi image if BOOTFORMAT_CONFIG is not empty
120 if [ "${UBOOT_TARGET}" = "u-boot-spi" ] && [ -n "${BOOTFORMAT_CONFIG}" ];then
121 ${STAGING_BINDIR_NATIVE}/boot_format \
122 ${STAGING_DATADIR_NATIVE}/boot_format/${BOOTFORMAT_CONFIG} \
123 ${S}/${board}/${UBOOT_SOURCE} -spi ${S}/${board}/${UBOOT_TARGET}.bin
124 fi
125 fi
126 done
127}
128
129do_install(){
130 if [ "x${UBOOT_MACHINES}" = "x" ]; then
131 UBOOT_MACHINES=${UBOOT_MACHINE}
132 fi
133
134 for board in ${UBOOT_MACHINES}; do
135 if ! grep -wq $board ${S}/boards.cfg;then
136 continue
137 fi
138
139 case "${board}" in
140 *SDCARD*) UBOOT_TARGET="u-boot-sd";;
141 *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
142 *NAND*) UBOOT_TARGET="u-boot-nand";;
143 *SRIO*) UBOOT_TARGET="u-boot-srio";;
144 *) UBOOT_TARGET="u-boot";;
145 esac
146
147 if [ -f ${S}/${board}/${UBOOT_TARGET}.bin ]; then
148 mkdir -p ${D}/boot/
149 install ${S}/${board}/${UBOOT_TARGET}.bin ${D}/boot/${UBOOT_TARGET}-${board}-${PV}-${PR}.bin
150 ln -sf ${UBOOT_TARGET}-${board}-${PV}-${PR}.bin ${D}/boot/${UBOOT_TARGET}.bin
151 fi
152 done
153}
154
155do_deploy(){
156 if [ "x${UBOOT_MACHINES}" = "x" ]; then
157 UBOOT_MACHINES=${UBOOT_MACHINE}
158 fi
159
160 for board in ${UBOOT_MACHINES}; do
161 if ! grep -wq $board ${S}/boards.cfg;then
162 continue
163 fi
164
165 case "${board}" in
166 *SDCARD*) UBOOT_TARGET="u-boot-sd";;
167 *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
168 *NAND*) UBOOT_TARGET="u-boot-nand";;
169 *SRIO*) UBOOT_TARGET="u-boot-srio";;
170 *) UBOOT_TARGET="u-boot";;
171 esac
172
173 if [ -f ${S}/${board}/${UBOOT_TARGET}.bin ]; then
174 mkdir -p ${DEPLOYDIR}
175 install ${S}/${board}/${UBOOT_TARGET}.bin ${DEPLOYDIR}/${UBOOT_TARGET}-${board}-${PV}-${PR}.bin
176
177 cd ${DEPLOYDIR}
178 rm -f ${UBOOT_TARGET}-${board}.bin
179 ln -sf ${UBOOT_TARGET}-${board}-${PV}-${PR}.bin ${UBOOT_TARGET}-${board}.bin
180 fi
181 done
182}
183addtask deploy after do_install
184
185PACKAGES += "${PN}-images"
186FILES_${PN}-images += "/boot"
187
188ALLOW_EMPTY_${PN} = "1"
generated by cgit v1.2.3-54-g00ecf (git 2.39.0) at 2026-08-14 21:25:33 +0000